WOLFRAM

Wolfram Language & System Documentation Center

PyramidElement[{{i11,i12,i13,i14,i15},…,{in1,in2,in3,in4,in5}}]

represents n linear pyramid elements ek with incidents {ik1,ik2,ik3,ik4,ik5}.

PyramidElement[{{i11,…,i113},…,{in1,…,in13}}]

represents n quadratic pyramid elements ek with incidents {ik1,…,ik13}.

PyramidElement[{e1,…,en},{m1,…,mn}]

represents n pyramid elements ek and n integer markers mk.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Generalizations & Extensions  
Applications  
Possible Issues  
See Also
Related Guides
Cite this Page
NDSolve`FEM`
NDSolve`FEM`

PyramidElement

PyramidElement[{{i11,i12,i13,i14,i15},…,{in1,in2,in3,in4,in5}}]

represents n linear pyramid elements ek with incidents {ik1,ik2,ik3,ik4,ik5}.

PyramidElement[{{i11,…,i113},…,{in1,…,in13}}]

represents n quadratic pyramid elements ek with incidents {ik1,…,ik13}.

PyramidElement[{e1,…,en},{m1,…,mn}]

represents n pyramid elements ek and n integer markers mk.

Details and Options

  • PyramidElement is used to represent pyramid mesh elements in ElementMesh.
  • PyramidElement can be used as an input to ToElementMesh.
  • Incidents ik,j are integers that index an array of spatial coordinates. The coordinates referenced by ek={ik1,…} are the nodes of the k^(th) pyramid.
  • The first five incidents ik1, ik2, ik3, ik4 and ik5 are always vertices.
  • For quadratic pyramid elements, the next eight incidents are mid-side nodes of possibly curved edges.
  • Linear elements are order-1 elements and quadratic elements are order-2 elements.
  • In PyramidElement[{e1,…,en}], all elements ek need to be of the same order.
  • The pyramid in PyramidElement[{e1,…,en}] will share common nodes, edges and faces, but these cannot intersect with each other, or for second-order pyramids, with themselves.
  • The nodes for a linear and a quadratic pyramid are shown:
  • For a PyramidElement, the face incidents must be counterclockwise. An element {i1,i2,i3,i4,i5} has the face incidents {i1,i2,i3,i4}, {i1,i5,i2,0}, {i2,i5,i3,0}, {i3,i5,i4,0} and {i4,i5,i1,0} for the five faces.
  • The pyramid element is known in the finite element method as a serendipity element.
  • Pyramid elements can connect tetrahedron and hexahedron elements in the same mesh.
  • The pyramid element is implemented as a truncated hexahedron element, where the top nodes are collapsed into a single node.

Examples

open all close all

Basic Examples  (1)

Load the package:

Wolfram Language code: <<NDSolve`FEM`

Create a mesh with one pyramid element:

Wolfram Language code: ToElementMesh["Coordinates" -> {{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}, {0, 0, 1}}, "MeshElements" -> {PyramidElement[{{1, 2, 3, 4, 5}}]}]

Generalizations & Extensions  (4)

The base coordinates of the linear element:

Wolfram Language code: c = MeshElementBaseCoordinates[PyramidElement, 1]

The base incidents of the linear element:

Wolfram Language code: e = PyramidElement[{MeshElementBaseIncidents[PyramidElement, 1]}]

A mesh with a linear unit element:

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]

Visualization of the linear unit element:

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

The base coordinates of the quadratic element:

Wolfram Language code: c = MeshElementBaseCoordinates[PyramidElement, 2]

The base incidents of the quadratic element:

Wolfram Language code: e = PyramidElement[{MeshElementBaseIncidents[PyramidElement, 2]}]

Create a mesh based on the base coordinates and the base incidents:

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]

Visualize the mesh:

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

Note that the second-order nodes are those of a hexahedron element.

The base face incidents of the linear element:

Wolfram Language code: e = MeshElementBaseFaceIncidents[PyramidElement, 1]

The base face incidents of the quadratic element:

Wolfram Language code: e = MeshElementBaseFaceIncidents[PyramidElement, 2]

Applications  (1)

Combine hexahedron and tetrahedron elements with a pyramid element:

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> {{0., 1., 0.}, {0., 0., 0.}, {1., 1., 0.}, {1., 0., 0.}, {0., 0., 1.}, {1., 0., 1.}, {1., 1., 1.}, {0., 1., 1.}, {2., 0., 0.}, {2., 0., 1.}, {2., 1., 0.}, {2., 1., 1.}, {1.5, 0.5, 0.}, {1.5, 0.5, 1.}, {1.5, 0., 0.5}, {1.5, 1., 0.5}, {1.5, 0.5, 0.5}}, "MeshElements" -> {TetrahedronElement[{{17, 13, 9, 4}, {4, 17, 13, 3}, {17, 12, 7, 14}, {14, 10, 6, 17}, {15, 4, 17, 9}, {6, 7, 14, 17}, {12, 16, 11, 17}, {16, 17, 3, 11}, {10, 12, 9, 17}, {6, 17, 15, 4}, {10, 6, 17, 15}, {15, 9, 17, 10}, {17, 13, 3, 11}, {16, 17, 12, 7}, {14, 17, 12, 10}, {11, 17, 9, 12}, {13, 17, 9, 11}, {7, 17, 3, 16}}, 1], PyramidElement[{{7, 6, 4, 3, 17}}, 2], HexahedronElement[{{2, 4, 3, 1, 5, 6, 7, 8}}, 4]}]

Visualize the mesh with the elements' markers:

Wolfram Language code: Show[ mesh["Wireframe"["MeshElement" -> "MeshElements"]], mesh["Wireframe"[ElementMarker == 2, "MeshElement" -> "MeshElements", "MeshElementStyle" -> Directive[Opacity[0.3], FaceForm[LightGreen], EdgeForm[Black]]]] ]

Possible Issues  (6)

The incidents must be of the appropriate length:

Wolfram Language code: PyramidElement[{{3, 4, 7}, {4, 8, 7}, {7, 9, 12}, {7, 8, 9}}]

The incident order cannot be mixed:

Wolfram Language code: PyramidElement[{{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18}}]

The incidents must be lists of integers:

Wolfram Language code: PyramidElement[{{a, 2, 3, 4, 5}}]

The number of markers must match the number of incidents:

Wolfram Language code: PyramidElement[{{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}}, {1, 1, 2}]

Markers must be a vector of integers:

Wolfram Language code: PyramidElement[{{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}}, {1, a}]

When possible, noninteger markers will be converted to integers:

Wolfram Language code: PyramidElement[{{1., 2, 3, 4, 5}, {6, 7, 8, 9, 10}}, {1, 2.}]
Wolfram Research (2026), PyramidElement, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html.

Text

Wolfram Research (2026), PyramidElement, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html.

CMS

Wolfram Language. 2026. "PyramidElement." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html.

APA

Wolfram Language. (2026). PyramidElement. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html

BibTeX

@misc{reference.wolfram_2026_pyramidelement, author="Wolfram Research", title="{PyramidElement}", year="2026", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_pyramidelement, organization={Wolfram Research}, title={PyramidElement}, year={2026}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html}, note=[Accessed: 12-June-2026]}