WOLFRAM

Wolfram Language & System Documentation Center

HexahedronElement[{{i11,…,i18},…,{in1,…,in8}}]

represents n linear hexahedron elements ek with incidents {ik1,…ik8}.

HexahedronElement[{{i11,…,i120},…,{in1,…,in20}}]

represents n quadratic hexahedron elements ek with incidents {ik1,…,ik20}.

HexahedronElement[{e1,…,en},{m1,…,mn}]

represents n hexahedron elements ek and n integer markers mk.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Generalizations & Extensions  
Applications  
Possible Issues  
See Also
Tech Notes
Related Guides
Cite this Page
NDSolve`FEM`
NDSolve`FEM`

HexahedronElement

HexahedronElement[{{i11,…,i18},…,{in1,…,in8}}]

represents n linear hexahedron elements ek with incidents {ik1,…ik8}.

HexahedronElement[{{i11,…,i120},…,{in1,…,in20}}]

represents n quadratic hexahedron elements ek with incidents {ik1,…,ik20}.

HexahedronElement[{e1,…,en},{m1,…,mn}]

represents n hexahedron elements ek and n integer markers mk.

Details and Options

  • HexahedronElement is used to represent hexahedron mesh elements in ElementMesh.
  • HexahedronElement can be used as an input to ToElementMesh or ToBoundaryMesh.
  • Incidents ik,j are integers that index an array of spatial coordinates. The coordinates referenced by ek={ik1,…} are the nodes of the k^(th) triangle.
  • The first three incidents ik1 until ik8 are always vertices.
  • For quadratic triangle elements, the next 12 incidents are mid-side nodes of possibly curved edges.
  • Linear elements are order 1 elements and quadratic elements are order 2 elements.
  • In HexahedronElement[{e1,…,en}], all elements ek need to be of the same order.
  • The hexahedra in HexahedronElement[{e1,…,en}] will share common nodes, edges, and faces, but cannot intersect with each other or with themselves.
  • The nodes for a linear and a quadratic hexahedron are shown:
  • For a HexahedronElement, the incidents on the faces must be counterclockwise when viewed from inside the element. An element {i1,…,i8} has face incidents {i1,i2,i3,i4}, {i8,i7,i6,i5}, {i1,i5,i6,i2}, {i2,i6,i7,i3}, {i3,i7,i8,i4}, and {i4,i8,i5,i1} for the six faces.
  • The hexahedron element is known in the finite element method as a Serendipity element.

Examples

open all close all

Basic Examples  (1)

Load the package:

Wolfram Language code: <<NDSolve`FEM`

Create a mesh with one quad element:

Wolfram Language code: ToElementMesh["Coordinates" -> {{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {0, 0, 1}, {2, 0, 1}, {2, 2, 1}, {0, 2, 1}}, "MeshElements" -> {HexahedronElement[{{1, 2, 3, 4, 5, 6, 7, 8}}]}]

Generalizations & Extensions  (4)

The base coordinates of the linear element:

Wolfram Language code: c = MeshElementBaseCoordinates[HexahedronElement, 1]

The base incidents of the linear element:

Wolfram Language code: e = HexahedronElement[{MeshElementBaseIncidents[HexahedronElement, 1]}]

A mesh with a linear unit element:

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]

Visualization of the linear unit element:

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

The base coordinates of the quadratic element:

Wolfram Language code: c = MeshElementBaseCoordinates[HexahedronElement, 2]

The base incidents of the quadratic element:

Wolfram Language code: e = HexahedronElement[{MeshElementBaseIncidents[HexahedronElement, 2]}]
Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]
Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

The base face incidents of the linear element:

Wolfram Language code: e = MeshElementBaseFaceIncidents[HexahedronElement, 1]

The base face incidents of the quadratic element:

Wolfram Language code: e = MeshElementBaseFaceIncidents[HexahedronElement, 2]

Applications  (1)

A linear hexahedron element mesh with markers:

Wolfram Language code: coordinates = {{0., 0., 1.}, {1., 0., 1.}, {2., 0., 1.}, {0., 1., 1.}, {1., 1., 1.}, {2., 1., 1.}, {0., 2., 1.}, {1., 2., 1.}, {2., 2., 1.}, {0., 0., 0.}, {1., 0., 0.}, {2., 0., 0.}, {0., 1., 0.}, {1., 1., 0.}, {2., 1., 0.}, {0., 2., 0.}, {1., 2., 0.}, {2., 2., 0.} };

Visualizing the index of the coordinates at their respective positions:

Wolfram Language code: Graphics3D[MapIndexed[Text[ToString[#2[[1]]], #1]&, coordinates]]

Create the mesh:

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> coordinates, "MeshElements" -> {HexahedronElement[{{10, 11, 14, 13, 1, 2, 5, 4}, {11, 12, 15, 14, 2, 3, 6, 5}, {13, 14, 17, 16, 4, 5, 8, 7}, {14, 15, 18, 17, 5, 6, 9, 8}}, {1, 1, 2, 2}]}]

Visualize the mesh with the element markers:

Wolfram Language code: mesh["Wireframe"["MeshElement" -> "MeshElements", "MeshElementMarkerStyle" -> Red, Boxed -> False]]

Possible Issues  (6)

The incidents must be of the appropriate length:

Wolfram Language code: HexahedronElement[{{3, 4, 7}, {4, 8, 7}, {7, 9, 12}, {7, 8, 9}}]

The incidents order cannot be mixed:

Wolfram Language code: HexahedronElement[{{1, 2, 3, 4, 5, 6, 7, 8}, {9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28}}]

The incidents must be lists of integers:

Wolfram Language code: HexahedronElement[{{a, 2, 3, 4, 5, 6, 7, 8}}]

The number of markers must match the number of incidents:

Wolfram Language code: HexahedronElement[{{1, 2, 5, 4, 10, 11, 14, 13}, {2, 3, 6, 5, 11, 12, 15, 14}, {4, 5, 8, 7, 13, 14, 17, 16}, {5, 6, 9, 8, 14, 15, 18, 17}}, {1, 1, 2}]

Markers must be a vector of integers:

Wolfram Language code: HexahedronElement[{{1, 2, 5, 4, 10, 11, 14, 13}, {2, 3, 6, 5, 11, 12, 15, 14}, {4, 5, 8, 7, 13, 14, 17, 16}, {5, 6, 9, 8, 14, 15, 18, 17}}, {1, 1, 2, a}]

When possible, noninteger markers will be converted to integers:

Wolfram Language code: HexahedronElement[{{1, 2, 5, 4, 10, 11, 14, 13}, {2, 3, 6, 5, 11, 12, 15, 14}, {4, 5, 8, 7, 13, 14, 17, 16}, {5, 6, 9, 8, 14, 15, 18, 17}}, {1, 1, 2, 2.}]
Wolfram Research (2014), HexahedronElement, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html.

Text

Wolfram Research (2014), HexahedronElement, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html.

CMS

Wolfram Language. 2014. "HexahedronElement." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html.

APA

Wolfram Language. (2014). HexahedronElement. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html

BibTeX

@misc{reference.wolfram_2026_hexahedronelement, author="Wolfram Research", title="{HexahedronElement}", year="2014", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_hexahedronelement, organization={Wolfram Research}, title={HexahedronElement}, year={2014}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html}, note=[Accessed: 13-June-2026]}