QuadElement
QuadElement[{{i11,i12,i13,i14},…,{in1,in2,in3,in4}}]
represents n linear quad elements ek with incidents {ik1,ik2,ik3,ik4}.
QuadElement[{{i11,…,i18},…,{in1,…,in8}}]
represents n quadratic quad elements ek with incidents {ik1,…,ik8}.
QuadElement[{e1,…,en},{m1,…,mn}]
represents n quad elements ek and n integer markers mk.
Details and Options
- QuadElement is used to represent quad mesh elements in ElementMesh.
- QuadElement can be used as an input to ToElementMesh or ToBoundaryMesh.
- Incidents ik,j are integers that index an array of spatial coordinates. The coordinates referenced by ek={ik1,…} are the nodes of the k
quad. - The first four incidents ik1, ik2, ik3, and ik4 are always vertices.
- For quadratic quad elements, the next four incidents are mid-side nodes of possibly curved edges.
- Linear elements are order 1 elements and quadratic elements are order 2 elements.
- In QuadElement[{e1,…,en}], all elements ek need to be of the same order.
- The quads in QuadElement[{e1,…,en}] will share common nodes and edges but cannot intersect with each other or with themselves.
- The nodes for a linear and a quadratic quad are shown:
- The incidents {i1,i2,i3,i4} must be ordered so that going from the coordinates referenced by i1 to i2 to i3 to i4 is in the counterclockwise direction.
- Typically, QuadElement is used for two-dimensional regions, but may be embedded in three dimensions, for example, as a part of a boundary mesh.
- The quad element is known in the finite element method as a Serendipity element.
Examples
open all close allBasic Examples (1)
Scope (1)
A boundary mesh with quad elements:
bmesh = ToBoundaryMesh["Coordinates" -> {{0., 0., 0.}, {2., -1., 0.}, {2., 2., 0.}, {0., 1., 0.}, {0., 0., 1.}, {2., -1, 1.}, {2., 2., 1.}, {0., 1., 1.}}, "BoundaryElements" -> {QuadElement[{{1, 2, 3, 4}, {5, 6, 7, 8}, {1, 4, 8, 5}, {2, 1, 5, 6}, {3, 2, 6, 7}, {4, 3, 7, 8}}]}]bmesh["Wireframe"[Boxed -> False]]Generalizations & Extensions (4)
The base coordinates of the linear element:
c = MeshElementBaseCoordinates[QuadElement, 1]The base incidents of the linear element:
e = QuadElement[{MeshElementBaseIncidents[QuadElement, 1]}]A mesh with a linear unit element:
mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]Visualization of the linear unit element:
Show[mesh["Wireframe"],
mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]The base coordinates of the quadratic element:
c = MeshElementBaseCoordinates[QuadElement, 2]The base incidents of the quadratic element:
e = QuadElement[{MeshElementBaseIncidents[QuadElement, 2]}]mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]Show[mesh["Wireframe"],
mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]The base face incidents of the linear element:
e = MeshElementBaseFaceIncidents[QuadElement, 1]The base face incidents of the quadratic element:
e = MeshElementBaseFaceIncidents[QuadElement, 2]Applications (3)
Linear quad elements in a mesh:
mesh = ToElementMesh["Coordinates" -> {{1., 0.}, {0.94, 0.342}, {1.293, 0.}, {1.215, 0.442}, {2., 0.}, {1.879, 0.684}, {0.97, 0.171}, {1.254, 0.221}, {1.9395, 0.342}}, "MeshElements" -> {QuadElement[{{1, 3, 8, 7}, {7, 8, 4, 2}, {3, 5, 9, 8}, {8, 9, 6, 4}}]}]Visualize the mesh with the elements vertices.
Show[mesh["Wireframe"],
mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]Quadratic quad elements in a mesh:
coordinates = {{1., 0.}, {0.94, 0.342}, {1.293, 0.}, {1.215, 0.442}, {2., 0.}, {1.879, 0.684}, {0.97, 0.171}, {1.254, 0.221}, {1.9395, 0.342}, {0.955, 0.2565}, {0.985, 0.0855}, {1.0775, 0.392}, {1.112, 0.196}, {1.1465, 0.}, {1.2345, 0.3315}, {1.2735, 0.1105}, {1.547, 0.563}, {1.59675, 0.2815}, {1.6465, 0.}, {1.90925, 0.513}, {1.96975, 0.171}};mesh = ToElementMesh["Coordinates" -> coordinates, "MeshElements" -> {QuadElement[{{1, 3, 8, 7, 14, 16, 13, 11}, {7, 8, 4, 2, 13, 15, 12, 10}, {3, 5, 9, 8, 19, 21, 18, 16}, {8, 9, 6, 4, 18, 20, 17, 15}}]}]Visualize the mesh with the elements' vertices:
Show[mesh["Wireframe"],
mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]A mixed quad and triangle element mesh with markers:
coordinates = {{0., 0.}, {1., 0.}, {2., 0.}, {2.5, 0.5}, {0., 1.}, {1., 1.}, {2., 1.}, {3., 1.}, {2.5, 1.5}, {0., 2.}, {1., 2.}, {2., 2.}};mesh = ToElementMesh["Coordinates" -> coordinates, "MeshElements" -> {QuadElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}, {1, 1, 2, 2}], TriangleElement[{{3, 4, 7}, {4, 8, 7}, {7, 9, 12}, {7, 8, 9}}, {1, 1, 2, 2}]}]Visualize the mesh with the elements' markers:
mesh["Wireframe"["MeshElementMarkerStyle" -> Red]]Possible Issues (6)
The incidents must be of the appropriate length:
QuadElement[{{3, 4, 7}, {4, 8, 7}, {7, 9, 12}, {7, 8, 9}}]
The incidents' order cannot be mixed:
QuadElement[{{1, 2, 6, 5}, {2, 3, 7, 6, 5, 1, 8, 9}}]
The incidents must be lists of integers:
QuadElement[{{a, 2, 6, 5}, {2, 3, 7, 8}, {5, 6, 11, 12}}]
The number of markers must match the number of incidents:
QuadElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}, {1, 1, 2}]
Markers must be a vector of integers:
QuadElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}, {1, 1, 2, a}]
When possible, noninteger markers will be converted to integers:
QuadElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}, {1, 1, 2, 2.}]Text
Wolfram Research (2014), QuadElement, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/QuadElement.html.
CMS
Wolfram Language. 2014. "QuadElement." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/QuadElement.html.
APA
Wolfram Language. (2014). QuadElement. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/QuadElement.html