WOLFRAM

Wolfram Language & System Documentation Center

TetrahedronElement[{{i11,i12,i13,i14},…,{in1,in2,in3,in4}}]

represents n linear tetrahedron elements ek with incidents {ik1,ik2,ik3,ik4}.

TetrahedronElement[{{i11,…,i110},…,{in1,…,in10}}]

represents n quadratic tetrahedron elements ek with incidents {ik1,…,ik10}.

TetrahedronElement[{e1,…,en},{m1,…,mn}]

represents n tetrahedron elements ek and n integer markers mk.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Generalizations & Extensions  
Applications  
Possible Issues  
See Also
Tech Notes
Related Guides
Cite this Page
NDSolve`FEM`
NDSolve`FEM`

TetrahedronElement

TetrahedronElement[{{i11,i12,i13,i14},…,{in1,in2,in3,in4}}]

represents n linear tetrahedron elements ek with incidents {ik1,ik2,ik3,ik4}.

TetrahedronElement[{{i11,…,i110},…,{in1,…,in10}}]

represents n quadratic tetrahedron elements ek with incidents {ik1,…,ik10}.

TetrahedronElement[{e1,…,en},{m1,…,mn}]

represents n tetrahedron elements ek and n integer markers mk.

Details and Options

  • TetrahedronElement is used to represent tetrahedron mesh elements in ElementMesh.
  • TetrahedronElement can be used as an input to ToElementMesh.
  • Incidents ik,j are integers that index an array of spatial coordinates. The coordinates referenced by ek={ik1,…} are the nodes of the k^(th) tetrahedron.
  • The first four incidents ik1, ik2, ik3, and ik4 are always vertices.
  • For quadratic tetrahedron elements, the next six incidents are mid-side nodes of possibly curved edges.
  • Linear elements are order 1 elements and quadratic elements are order 2 elements.
  • In TetrahedronElement[{e1,…,en}], all elements ek need to be of the same order.
  • The tetrahedra in TetrahedronElement[{e1,…,en}] will share common nodes, edges, and faces but cannot intersect with each other, or for second-order tetrahedra, with themselves.
  • The nodes for a linear and a quadratic tetrahedra are shown:
  • For a TetrahedronElement, the face incidents opposite a vertex ij must be counterclockwise. An element {i1,i2,i3,i4} has the face incidents {i4,i3,i2}, {i4,i1,i3}, {i4,i2,i1}, and {i1,i2,i3} for the four faces.
  • The tetrahedron element is known in the finite element method as a Serendipity element.

Examples

open all close all

Basic Examples  (1)

Load the package:

Wolfram Language code: <<NDSolve`FEM`

Create a mesh with one tetrahedron element:

Wolfram Language code: ToElementMesh["Coordinates" -> {{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 2}}, "MeshElements" -> {TetrahedronElement[{{1, 2, 3, 4}}]}]

Generalizations & Extensions  (4)

The base coordinates of the linear element:

Wolfram Language code: c = MeshElementBaseCoordinates[TetrahedronElement, 1]

The base incidents of the linear element:

Wolfram Language code: e = TetrahedronElement[{MeshElementBaseIncidents[TetrahedronElement, 1]}]

A mesh with a linear unit element:

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]

Visualization of the linear unit element:

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

The base coordinates of the quadratic element:

Wolfram Language code: c = MeshElementBaseCoordinates[TetrahedronElement, 2]

The base incidents of the quadratic element:

Wolfram Language code: e = TetrahedronElement[{MeshElementBaseIncidents[TetrahedronElement, 2]}]
Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]
Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

The base face incidents of the linear element:

Wolfram Language code: e = MeshElementBaseFaceIncidents[TetrahedronElement, 1]

The base face incidents of the quadratic element:

Wolfram Language code: e = MeshElementBaseFaceIncidents[TetrahedronElement, 2]

Applications  (1)

A set of linear tetrahedron elements mesh with markers:

Wolfram Language code: coordinates = N[Join[{{0, 0, 1}, {0, 0, 0}}, Table[{Sin[i], Cos[i], 0}, {i, 0, 2π - π / 4, π / 4}]]];

Visualizing the index of the coordinates at their respective positions:

Wolfram Language code: Graphics3D[MapIndexed[Text[ToString[#2[[1]]], #1]&, coordinates]]

Create the mesh:

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> coordinates, "MeshElements" -> { TetrahedronElement[{{1, 2, 3, 4}, {1, 2, 4, 5}, {1, 2, 5, 6}, {1, 2, 6, 7}, {1, 2, 7, 8}, {1, 2, 8, 9}, {1, 2, 9, 10}, {1, 2, 10, 3}}, {1, 1, 1, 1, 2, 2, 2, 2}] }]

Visualize the mesh with the elements' markers:

Wolfram Language code: mesh["Wireframe"["MeshElement" -> "MeshElements", "MeshElementMarkerStyle" -> Red, Boxed -> False]]

Possible Issues  (6)

The incidents must be of the appropriate length:

Wolfram Language code: TetrahedronElement[{{3, 4, 7}, {4, 8, 7}, {7, 9, 12}, {7, 8, 9}}]

The incident order cannot be mixed:

Wolfram Language code: TetrahedronElement[{{1, 2, 6, 5}, {2, 3, 7, 6, 5, 1, 8, 9, 11, 12}}]

The incidents must be lists of integers:

Wolfram Language code: TetrahedronElement[{{a, 2, 6, 5}, {2, 3, 7, 8}, {5, 6, 11, 12}}]

The number of markers must match the number of incidents:

Wolfram Language code: TetrahedronElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}, {1, 1, 2}]

Markers must be a vector of integers:

Wolfram Language code: TetrahedronElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}, {1, 1, 2, a}]

When possible, noninteger markers will be converted to integers:

Wolfram Language code: TetrahedronElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}, {1, 1, 2, 2.}]
Wolfram Research (2014), TetrahedronElement, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html.

Text

Wolfram Research (2014), TetrahedronElement, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html.

CMS

Wolfram Language. 2014. "TetrahedronElement." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html.

APA

Wolfram Language. (2014). TetrahedronElement. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html

BibTeX

@misc{reference.wolfram_2026_tetrahedronelement, author="Wolfram Research", title="{TetrahedronElement}", year="2014", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_tetrahedronelement, organization={Wolfram Research}, title={TetrahedronElement}, year={2014}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html}, note=[Accessed: 13-June-2026]}