ArcSin
ArcSin[z]
gives the arc sine 
of the complex number 
.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- All results are given in radians.
- For real
between 
and 
, the results are always in the range 
to 
. - For certain special arguments, ArcSin automatically evaluates to exact values.
- ArcSin can be evaluated to arbitrary numerical precision.
- ArcSin automatically threads over lists. »
- ArcSin[z] has branch cut discontinuities in the complex
plane running from 
to 
and 
to 
. - ArcSin can be used with Interval and CenteredInterval objects. »
Background & Context
- ArcSin is the inverse sine function. For a real number
, ArcSin[x] represents the radian angle measure 
such that 
. - ArcSin automatically threads over lists. For certain special arguments, ArcSin automatically evaluates to exact values. When given exact numeric expressions as arguments, ArcSin may be evaluated to arbitrary numeric precision. Operations useful for manipulation of symbolic expressions involving ArcSin include FunctionExpand, TrigToExp, TrigExpand, Simplify, and FullSimplify.
- ArcSin is defined for complex argument
via ![sin^(-1)(z)=-ⅈ log(sqrt(TemplateBox[{{1, -, {z, ^, 2}}}, Abs]) ⅇ^(1/2 ⅈ arg(1-z^2))+ⅈ z)](Files/ArcSin.en/17.png "sin^(-1)(z)=-ⅈ log(sqrt(TemplateBox[{{1, -, {z, ^, 2}}}, Abs]) ⅇ^(1/2 ⅈ arg(1-z^2))+ⅈ z)")
. ArcSin[z] has branch cut discontinuities in the complex 
plane. - Related mathematical functions include Sin, ArcCos, InverseHaversine, and ArcSinh.
Examples
open all close allBasic Examples (6)
ArcSin[1]Divide by Degree to get results in degrees:
ArcSin[1] / Degree//FullSimplifyPlot over a subset of the reals:
Plot[ArcSin[x], {x, -1, 1}]Plot over a subset of the complexes:
ComplexPlot3D[ArcSin[z], {z, -4 - 2I, 4 + 2I}, PlotLegends -> Automatic]Series[ArcSin[x], {x, 0, 10}]Asymptotic expansion at Infinity:
Series[ArcSin[x], {x, ∞, 5}]Asymptotic expansion at a singular point:
Series[ArcSin[x], {x, -1, 5}]Scope (42)
Numerical Evaluation (6)
ArcSin[0.4]ArcSin[1.5]N[ArcSin[1 / 3], 50]The precision of the output tracks the precision of the input:
ArcSin[0.33333333333333333333333333333333333333333333]ArcSin can take complex number inputs:
ArcSin[2.5 + I]Evaluate ArcSin efficiently at high precision:
ArcSin[0.4`500]//TimingArcSin[0.4`100000];//TimingCompute the elementwise values of an array using automatic threading:
ArcSin[{{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]Or compute the matrix ArcSin function using MatrixFunction:
MatrixFunction[ArcSin[#]&, {{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:
ArcSin[Interval[{-1 / 3, 1 / 2}]]ArcSin[CenteredInterval[1 / 2, 1 / 100]]ArcSin[CenteredInterval[2 + 3I, (1 + I) / 100]]Or compute average-case statistical intervals using Around:
ArcSin[Around[.9, 0.1]]Specific Values (4)
Values of ArcSin at fixed points:
Table[ArcSin[(n /2)], {n, -2, 2}]ArcSin[Infinity]ArcSin[ComplexInfinity]Zero of ArcSin:
ArcSin[0]Find the value of 
satisfying equation 
:
f[x_] := ArcSin[x] - (π/3);sol = Solve[f[x] == 0, x]xzero = x /. First[sol]Plot[f[x], {x, -1, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]Visualization (3)
Plot the ArcSin function:
Plot[ArcSin[x], {x, -1, 1}]
ComplexContourPlot[Re[ArcSin[z]], {z, -3π - 3I, 3π + 3I}, IconizedObject[«PlotOptions»]]
ComplexContourPlot[Im[ArcSin[z]], {z, -π - 3I, π + 3I}, Contours -> 24]
Table[PolarPlot[ArcSin[k ϕ], {ϕ, -π, π}, Sequence[Frame -> True, FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> All]], {k, 1, 4}]Function Properties (11)
ArcSin is defined for all real values from the interval 
:
FunctionDomain[ArcSin[x], x]Complex domain is the whole plane:
FunctionDomain[ArcSin[z], z, Complexes]ArcSin achieves all real values from the interval 
:
FunctionRange[ArcSin[x], x, y]Function range for arguments from the complex domain:
FunctionRange[ArcSin[z], z, y, Complexes]ArcSin is an odd function:
ArcSin[-x]ArcSin is not an analytic function:
FunctionAnalytic[ArcSin[x], x]FunctionMeromorphic[ArcSin[x], x]ArcSin is neither non-decreasing nor non-increasing:
FunctionMonotonicity[ArcSin[x], x]It is monotonic over its real domain:
FunctionMonotonicity[{ArcSin[x], -1 ≤ x ≤ 1}, x]ArcSin is injective:
FunctionInjective[ArcSin[x], x]Plot[{ArcSin[x], 1 / 2}, {x, -2π, 2π}]ArcSin is not surjective:
FunctionSurjective[ArcSin[x], x]Plot[{ArcSin[x], 2}, {x, -2π, 2π}]ArcSin is neither non-negative nor non-positive:
FunctionSign[ArcSin[x], x]ArcSin has both singularity and discontinuity in (-∞,-1] and [1,∞):
FunctionSingularities[ArcSin[x], x]FunctionDiscontinuities[ArcSin[x], x]ArcSin is neither convex nor concave:
FunctionConvexity[ArcSin[x], x]TraditionalForm formatting:
ArcSin[z]//TraditionalFormDifferentiation (3)
D[ArcSin[x], x]Table[D[ArcSin[x], {x, n}], {n, 1, 4}]Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]
derivative:D[ArcSin[x], {x, n}]Integration (3)
Indefinite integral of ArcSin:
Integrate[ArcSin[x], x]Definite integral of ArcSin over an interval centered at the origin is 0:
Integrate[ArcSin[x], {x, -1, 1}]Integrate[ArcCos[x] ArcSin[x], x]Integrate[ArcSin[z]^a, z]Series Expansions (4)
Find the Taylor expansion using Series:
Series[ArcSin[x], {x, 0, 7}]Plot the first three approximations for ArcSin around 
:
terms = Normal@Table[Series[ArcSin[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ArcSin[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]General term in the series expansion of ArcSin:
SeriesCoefficient[ArcSin[x], {x, 0, n}]Find series expansions at branch points and branch cuts:
Series[ArcSin[x], {x, 1, 1}]Series[ArcSin[x], {x, -2, 1}]ArcSin can be applied to power series:
ArcSin[x + (x^2/2) + (x^3/3) + O[x]^4]Function Identities and Simplifications (3)
Simplify expressions involving ArcSin:
FullSimplify[ArcSin[Sqrt[1 - x^2]], 0 ≤ x ≤ 1]Use TrigToExp to express through logarithms and square roots:
TrigToExp@ArcSin[z]ExpToTrig[%]Expand assuming real variables 
and 
:
ComplexExpand[ArcSin[x + I y]]Function Representations (5)
Represent using ArcCsc:
ArcCsc[1 / x]//FullSimplifyRepresentation through inverse Jacobi functions:
(π/2) - InverseJacobiCN[z, 0]//FullSimplifyInverseJacobiDS[(1/z), 0]//FullSimplifyRepresent using Hypergeometric2F1:
(π/2) - z HypergeometricPFQ[{(1/2), (1/2)}, {(3/2)}, z^2]//FullSimplifyRepresentation in terms of MeijerG:
MeijerGReduce[ArcSin[x], x]Activate[%]ArcSin can be represented as a DifferentialRoot:
DifferentialRootReduce[ArcSin[x], x]Applications (6)
Plot the real and imaginary parts of ArcSin:
Plot[{Re[ArcSin[x]], Im[ArcSin[x]]}, {x, -2, 2}, PlotStyle -> Thick]Plot the Riemann surface of ArcSin:
ParametricPlot3D[Evaluate[{Re[Sin[u + I v]], Im[Sin[u + I v]], u}], {u, 0, 4π}, {v, -2, 2}]Find the angle between two 3D vectors:
With[{v = Normalize[{1, 1, -2}], u = Normalize[{1, 1, 1}]}, ArcSin[Norm[Cross[v, u]]]]Modeling Lévy's second arc sine law:
{With[{n = 1000}, ListPlot[MapIndexed[{#1, #2[[1]] / n}&, Sort[Table[Position[FoldList[Plus, 0, RandomChoice[{-1, 1}, n]], 0][[-1, 1]] / n, {n}]]]]], Plot[2 / Pi ArcSin[Sqrt[x]], {x, 0, 1}]}Solve the ArcSin differential equation:
DSolve[Sqrt[1 - z^2]w'[z] == 1, w[z], z]Conformal map from an ellipse to the unit disk:
w[z_, {a_, b_}] := With[{q = (a - b) ^ 2 / (a + b) ^ 2, e = Sqrt[a ^ 2 - b ^ 2]}, EllipticTheta[1, ArcSin[z / e], q] / EllipticTheta[4, ArcSin[z / e], q]]ParametricPlot[{Re[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]], Im[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]]}, {ρ, 0, 1}, {φ, 0, 2Pi}, Mesh -> 15]Properties & Relations (9)
Compose with the inverse function:
{Sin[ArcSin[z]], ArcSin[Sin[z]]}Use PowerExpand to disregard multivaluedness of the ArcSin:
PowerExpand[%]Alternatively, evaluate under additional assumptions:
Refine[ArcSin[Sin[z]], 0 < z < Pi / 2]Use TrigToExp to express through logarithms and square roots:
ArcSin[z]//TrigToExpExpToTrig[%]This shows the branch cuts of the ArcSin function:
Plot3D[Im[ArcSin[x + I y]], {x, -2, 2}, {y, -2, 2}]ArcSin gives the angle in radians, while ArcSinDegrees gives the same angle in degrees:
ArcSin[1]ArcSinDegrees[1]Expand assuming real variables:
ComplexExpand[ArcSin[x + I y]]Solve an inverse trigonometric equation:
Reduce[ArcSin[z]^2 + 3 ArcSin[z] == 2, z]Reduce[ArcSin[Sin[z]] == w, z]Reduce[ArcSin[α x + β] == 0, x]LaplaceTransform[ArcSin[t], t, s]ArcSin is a special case of various mathematical functions:
{(π/2) - InverseJacobiCD[z, 0], InverseJacobiCS[(I/z), 1], -(Sqrt[π]/2) MeijerG[{{1, 1, 1}, {}}, {{1}, {0, (1/2)}}, I z, (1/2)]}//FullSimplifyPossible Issues (4)
ArcSin[Sin[30.]]Sin[ArcSin[30.]]On branch cuts, machine-precision inputs can give numerically wrong answers:
ArcSin[-2 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//NArcSin[-2 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N[#, 30]&The precision of the output can be much lower than the precision of the input:
ArcSin[0.99999999999999999999999999999999999999999999]In traditional form, parentheses are needed around the argument:
sin^-1xsin^-1(x)Neat Examples (3)
NestList[Integrate[#, x]&, ArcSin[x], 4]Calculate numerical values by iteration:
arcSin[x_ ? (InexactNumberQ[#] && 0 < # < 1&)] := FixedPoint[Function[ξ, ξ + 1 / Cos[ξ](x - Sin[ξ])], x]{arcSin[N[7 / 11, 20]], ArcSin[N[7 / 11, 20]]}Plot ArcSin at integer points:
ArrayPlot[Table[FractionalPart[Abs[ArcSin[x y]]], {x, -20, 20}, {y, -20, 20}]]Related Links
MathWorld
The Wolfram Functions Site
NKS|OnlineText
Wolfram Research (1988), ArcSin, Wolfram Language function, https://reference.wolfram.com/language/ref/ArcSin.html (updated 2021).
CMS
Wolfram Language. 1988. "ArcSin." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ArcSin.html.
APA
Wolfram Language. (1988). ArcSin. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcSin.html