Wolfram Language & System Documentation Center

Hypergeometric2F1

Hypergeometric2F1[a,b,c,z]

is the hypergeometric function .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
The function has the series expansion $TemplateBox[{a, b, c, z}, Hypergeometric2F1]=sum_(k=0)^(infty)TemplateBox[{a, k}, Pochhammer]TemplateBox[{b, k}, Pochhammer]/TemplateBox[{c, k}, Pochhammer] z^k/k!$ , where is the Pochhammer symbol.
For certain special arguments, Hypergeometric2F1 automatically evaluates to exact values.
Hypergeometric2F1 can be evaluated to arbitrary numerical precision.
Hypergeometric2F1 automatically threads over lists.
Hypergeometric2F1[a,b,c,z] has a branch cut discontinuity in the complex plane running from to .
FullSimplify and FunctionExpand include transformation rules for Hypergeometric2F1.
Hypergeometric2F1 can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (7)

Evaluate numerically:

Wolfram Language code: Hypergeometric2F1[2., 3., 4., 5.0]

Evaluate symbolically:

Wolfram Language code: Hypergeometric2F1[2, 3, 4, x]

Plot over a subset of the reals:

Wolfram Language code: Plot[Hypergeometric2F1[1 / 3, 1 / 3, 2 / 3, x], {x, -1, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[Hypergeometric2F1[2, 3, 4, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Expand Hypergeometric2F1 in a Taylor series at the origin:

Wolfram Language code: Series[Hypergeometric2F1[a, b, c, x], {x, 0, 3}]

Series expansion at Infinity:

Wolfram Language code: Series[Hypergeometric2F1[2, 3, 4, x], {x, ∞, 5}]//Normal

Series expansion at a singular point:

Wolfram Language code: Series[Hypergeometric2F1[2, 3, 4, x], {x, 1, 3}] // FullSimplify

Scope (44)

Numerical Evaluation (5)

Evaluate to high precision:

Wolfram Language code: N[Hypergeometric2F1[1 / 2, 1 / 3, 2, 1], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: Hypergeometric2F1[1 / 2, 1 / 3, 2, 1.000000000000000000000000000000000]

Evaluate for complex arguments:

Wolfram Language code: Hypergeometric2F1[2 + I, -I, 3 / 4, 0.5 - 0.5 I]

Evaluate Hypergeometric2F1 efficiently at high precision:

Wolfram Language code: Hypergeometric2F1[1 / 2, 1 / 3, 2, 1`500]//Timing

Wolfram Language code: Hypergeometric2F1[1 / 2, 1 / 3, 2, 1`2000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: Hypergeometric2F1[1 / 2, 1 / 3, 1 / 4, Interval[{0.21, 0.22}]]

Wolfram Language code: Hypergeometric2F1[1 / 2, 1 / 3, 1 / 4, CenteredInterval[1 / 2, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: Hypergeometric2F1[1 / 2, 1, 1, Around[1 / 2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: Hypergeometric2F1[1 / 2, 1, 1, {{1 / 2, 0}, {0, 1 / 2}}]

Or compute the matrix Hypergeometric2F1 function using MatrixFunction:

Wolfram Language code: MatrixFunction[Hypergeometric2F1[1 / 2, 1, 1, #]&, {{1 / 2, 0}, {0, 1 / 2}}]

Specific Values (6)

Hypergeometric2F1 automatically evaluates to simpler functions for certain parameters:

Wolfram Language code: Hypergeometric2F1[(3/2), 2, 3, x]

Wolfram Language code: Hypergeometric2F1[1 / 2, 1 / 2, 1, z]

Wolfram Language code: Hypergeometric2F1[1, 1 / 2, 3 / 2, y ^ 2]

Exact value of Hypergeometric2F1 at unity:

Wolfram Language code: Hypergeometric2F1[n, m, n + m + 2, 1]

Hypergeometric series terminates if either of the first two parameters is a negative integer:

Wolfram Language code: Hypergeometric2F1[-3, 3, 2, x]

Find a value of satisfying the equation :

Wolfram Language code:

f[x_] := Hypergeometric2F1[1 / 3, 1 / 3, 2 / 3, x] - 2 / 3;
xzero = Solve[f[x] == 0 && -9 < x < -6, x][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[f[x], {x, -10, 3}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

Permutation symmetry:

Wolfram Language code: Hypergeometric2F1[a, b, c, z] == Hypergeometric2F1[b, a, c, z]

Heun functions can simplify to hypergeometric functions:

Wolfram Language code: Hypergeometric2F1[a, b, c, z] == HeunG[1, a * b, a, b, c, delta, z]

Wolfram Language code: Hypergeometric2F1[a, b, c, z] == HeunG[A, A * a * b, a, b, c, 1 + a + b - c, z]

Wolfram Language code:

HeunC[q, 0, γ, δ, 0, z] == Hypergeometric2F1[(1/2) (-1 + γ + δ - Sqrt[4 q + (-1 + γ + δ)^2]), (1/2) (-1 + γ + δ + Sqrt[4 q + (-1 + γ + δ)^2]), γ, z]

Visualization (3)

Plot the Hypergeometric2F1 function:

Wolfram Language code:

Plot[{Hypergeometric2F1[1, 1 / 2, Sqrt[2], x], Hypergeometric2F1[1, 1 / 2, Sqrt[3], x], Hypergeometric2F1[1, 1 / 2, Sqrt[5], x]}, {x, -2, 1}]

Plot Hypergeometric2F1 as a function of its third parameter :

Wolfram Language code:

Plot[{Hypergeometric2F1[1 / 2, Sqrt[2], c, 1], Hypergeometric2F1[1 / 2, Sqrt[5], c, 1], Hypergeometric2F1[1 / 2, Sqrt[7], c, 1]}, {c, 0, 10}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[Hypergeometric2F1[1, 1 / 2, Sqrt[2], z]], {z, -5 - 5I, 5 + 5I}, Contours -> 24]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[Hypergeometric2F1[1, 1 / 2, Sqrt[2], z]], {z, -5 - 5I, 5 + 5I}, Contours -> 24]

Function Properties (9)

Real domain of Hypergeometric2F1:

Wolfram Language code: FunctionDomain[Hypergeometric2F1[a, b, c, z], z]

Complex domain of Hypergeometric2F1:

Wolfram Language code: FunctionDomain[Hypergeometric2F1[a, b, c, z], z, Complexes]

is an analytic function on its real domain:

Wolfram Language code: FunctionAnalytic[{Hypergeometric2F1[2 / 3, 3Sqrt[2], 3, z], z < 1}, z]

It is neither analytic nor meromorphic in the complex plane:

Wolfram Language code: FunctionAnalytic[Hypergeometric2F1[2 / 3, 1 / π, 3, z], z, ℂ]

Wolfram Language code: FunctionMeromorphic[Hypergeometric2F1[2 / 3, 1 / π, 3, z], z]

is non-decreasing on its real domain:

Wolfram Language code: FunctionMonotonicity[{Hypergeometric2F1[2 / 3, 3Sqrt[2], 3, z], z < 1}, z]

is injective:

Wolfram Language code: FunctionInjective[{Hypergeometric2F1[1, 1 / 2, 1, z]}, z]

Wolfram Language code: Plot[{Hypergeometric2F1[1, 1 / 2, 1, z], 2}, {z, -1, 1}]

is not surjective:

Wolfram Language code: FunctionSurjective[{Hypergeometric2F1[1, 1 / 2, 1, z]}, z]

Wolfram Language code: Plot[{Hypergeometric2F1[1, 1 / 2, 1, z], -2}, {z, -1, 1}]

is non-negative on its real domain:

Wolfram Language code: FunctionSign[{Hypergeometric2F1[2 / 3, 3Sqrt[2], 3, z], z < 1}, z]

Wolfram Language code: Plot[Hypergeometric2F1[2 / 3, 3Sqrt[2], 3, z], {z, -3, 1}, AxesOrigin -> {0, 0}]

has both singularity and discontinuity for :

Wolfram Language code: Table[FunctionSingularities[Hypergeometric2F1[a, 1 / 2, 1, z], z], {a, 4}]

Wolfram Language code: Table[FunctionDiscontinuities[Hypergeometric2F1[a, 1 / 2, 1, z], z], {a, 4}]

is convex on its real domain:

Wolfram Language code: FunctionConvexity[{Hypergeometric2F1[1, 1 / 2, 1, z], z < 1}, z]

TraditionalForm formatting:

Wolfram Language code: Hypergeometric2F1[a, b, c, z]//TraditionalForm

Differentiation (3)

First derivative:

Wolfram Language code: D[Hypergeometric2F1[a, b, c, x], x]

Higher derivatives:

Wolfram Language code: derivs = Table[D[Hypergeometric2F1[a, b, c, x], {x, n}], {n, 1, 3}]//FullSimplify

Plot higher derivatives for , and :

Wolfram Language code:

Plot[Evaluate[derivs /. {a -> 1 / 3, b -> 1 / 3, c -> 2 / 3}], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the derivative:

Wolfram Language code: D[Hypergeometric2F1[a, b, c, x], {x, n}]

Integration (3)

Indefinite integral of Hypergeometric2F1:

Wolfram Language code: Integrate[Hypergeometric2F1[a, b, c, x], x]//FullSimplify

Definite integral of Hypergeometric2F1:

Wolfram Language code: Integrate[Hypergeometric2F1[1 / 3, 1 / 3, 2 / 3, x], {x, 0, 1}]

Integral involving a power function:

Wolfram Language code: Integrate[x ^ (α - 1)Hypergeometric2F1[a, b, c, α x], x]//FullSimplify

Series Expansions (6)

Taylor expansion for Hypergeometric2F1:

Wolfram Language code: Series[Hypergeometric2F1[a, b, c, x], {x, 0, 3}]

Plot the first three approximations for around :

Wolfram Language code:

terms = Normal@Table[Series[Hypergeometric2F1[1 / 3, 1 / 3, 2 / 3, x], {x, 0, m}], {m, 1, 3}];
Plot[{Hypergeometric2F1[1 / 3, 1 / 3, 2 / 3, x], terms}, {x, -2, 2}]

General term in the series expansion of Hypergeometric2F1:

Wolfram Language code: SeriesCoefficient[Hypergeometric2F1[a, b, c, x], {x, 0, n}]

Expand Hypergeometric2F1 in a series near :

Wolfram Language code: Series[Hypergeometric2F1[(1/3), (1/3), (2/3), z], {z, 1, 1}]

Expand Hypergeometric2F1 in a series around :

Wolfram Language code: Series[Hypergeometric2F1[1 / 3, 1 / 3, 2 / 3, z], {z, Infinity, 1}]

Give the result for an arbitrary symbolic direction :

Wolfram Language code: Series[Hypergeometric2F1[1 / 3, 1, 4 / 3, x], {x, DirectedInfinity[z], 2}]

Apply Hypergeometric2F1 to a power series:

Wolfram Language code: Hypergeometric2F1[1, 1 / 7, 3 / 7, Log[1 + z] + O[z] ^ 5]

Integral Transforms (2)

Compute the Laplace transform using LaplaceTransform:

Wolfram Language code: LaplaceTransform[Hypergeometric2F1[a, b, c, -t], t, z]

HankelTransform:

Wolfram Language code: HankelTransform[Hypergeometric2F1[a, b, c, -r], r, s ]//FullSimplify

Function Identities and Simplifications (2)

Argument simplification:

Wolfram Language code: (1 - z)^a + b - cHypergeometric2F1[a, b, c, z]//FullSimplify

Recurrence identities:

Wolfram Language code:

Hypergeometric2F1[a, b, c, z] == (2 - c + 2 b + (a - b - 1) z/b - c + 1) Hypergeometric2F1[a, b + 1, c, z] + ((b + 1) (z - 1)/b - c + 1) Hypergeometric2F1[a, b + 2, c, z]//FullSimplify

Wolfram Language code:

(a - c) Hypergeometric2F1[a - 1, b, c, z] + (c - 2 a + (a - b) z)Hypergeometric2F1[a, b, c, z] == a (z - 1) Hypergeometric2F1[a + 1, b, c, z]//FullSimplify

Function Representations (5)

Basic definition:

Wolfram Language code: Underoverscript[∑, k = 0, ∞](Pochhammer[a, k] Pochhammer[b, k]z^k/ Pochhammer[c, k]k!)

Relation to the JacobiP polynomial:

Wolfram Language code: (Gamma[1 - a] Gamma[c]/Gamma[c - a])JacobiP[-a, c - 1, b + a - c, 1 - 2z]//FullSimplify

Hypergeometric2F1 can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[Hypergeometric2F1[a, b, c, x], x]

Hypergeometric2F1 can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[Hypergeometric2F1[a, b, c, x], x]

Wolfram Language code: Activate[%]//FullSimplify

TraditionalForm formatting:

Wolfram Language code: Hypergeometric2F1[a, b, c, x]//TraditionalForm

Applications (3)

An expression for the force acting on an electric point charge outside a neutral dielectric sphere of radius :

Wolfram Language code: ℱ = -(2 q^2 ϵ/3 + ϵ) (R^3/r^5)Hypergeometric2F1[3, (ϵ + 3/ϵ + 2), 1 + (ϵ + 3/ϵ + 2), ((R/r))^2];

The limit of infinite dielectric constant, corresponding to an uncharged insulated conducting sphere:

Wolfram Language code: Limit[ℱ, ϵ -> ∞]

An approximation for the force at a large distance from the sphere:

Wolfram Language code: Series[ℱ, {r, ∞, 5}]

Two players roll dice. If the total of both numbers is less than 10, the second player is paid 4 cents; otherwise, the first player is paid 9 cents. Is the game fair? Compute the probability that the first player gets paid:

Wolfram Language code: p = With[{𝒟 = DiscreteUniformDistribution[{1, 6}]}, Probability[k1 + k2 >= 10, k1𝒟 && k2𝒟]]

The game is not fair, since mean scores per game are not equal:

Wolfram Language code:

{pay1, pay2} = {9, 4};
{pay1 p, pay2(1 - p)}//N

Find the probability that after n games the player at the disadvantage scores more:

Wolfram Language code: f = FunctionExpand[Probability[pay1 * k > pay2 * (n - k), kBinomialDistribution[n, p]], n∈Integers && n ≥ 1]

The probability exhibits oscillations:

Wolfram Language code: DiscretePlot[f, {n, 50}, PlotRange -> All]

The maximum probability is attained at :

Wolfram Language code: Maximize[{f, 1 < n < 50}, n, Integers]

Riemann's differential equation with three regular singularities at and exponent parameters , subject to the constraint :

Wolfram Language code:

riemannODE = w''[z] + ((1 - Subscript[a, 1] - Subscript[a, 2]/z - α) + (1 - Subscript[b, 1] - Subscript[b, 2]/z - β) + (1 - Subscript[c, 1] - Subscript[c, 2]/z - γ))w'[z] + (((α - β)(α - γ)Subscript[a, 1]Subscript[a, 2]/z - α) + ((β - α)(β - γ)Subscript[b, 1]Subscript[b, 2]/z - β) + ((γ - α)(γ - β)Subscript[c, 1]Subscript[c, 2]/z - γ))(w[z]/(z - α)(z - β)(z - γ));

Construct two linearly independent solutions in terms of Hypergeometric2F1:

Wolfram Language code:

sol1[z_] := ((z - α/z - γ))^Subscript[a, 1]((z - β/z - γ))^Subscript[b, 1]Hypergeometric2F1[Subscript[a, 1] + Subscript[b, 1] + Subscript[c, 1], Subscript[a, 1] + Subscript[b, 1] + Subscript[c, 2], 1 + Subscript[a, 1] - Subscript[a, 2], (z - α/z - γ)(β - γ/β - α)]

Wolfram Language code:

sol2[z_] := ((z - α/z - γ))^Subscript[a, 2]((z - β/z - γ))^Subscript[b, 1]Hypergeometric2F1[Subscript[a, 2] + Subscript[b, 1] + Subscript[c, 1], Subscript[a, 2] + Subscript[b, 1] + Subscript[c, 2], 1 - Subscript[a, 1] + Subscript[a, 2], (z - α/z - γ)(β - γ/β - α)]

Verify that the solutions satisfy Riemann's equation:

Wolfram Language code:

(riemannODE /. w -> sol1) /. (Subscript[c, 2] -> 1 - (Subscript[a, 1] + Subscript[a, 2]  + Subscript[b, 1] + Subscript[b, 2] + Subscript[c, 1]))//FullSimplify

Wolfram Language code:

(riemannODE /. w -> sol2) /. (Subscript[c, 2] -> 1 - (Subscript[a, 1] + Subscript[a, 2]  + Subscript[b, 1] + Subscript[b, 2] + Subscript[c, 1]))//FullSimplify