WOLFRAM

Wolfram Language & System Documentation Center

ArithmeticGeometricMean[a,b]

gives the arithmetic‐geometric mean of a and b.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

ArithmeticGeometricMean

ArithmeticGeometricMean[a,b]

gives the arithmetic‐geometric mean of a and b.

Details

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: ArithmeticGeometricMean[1.8, 1.2]

Plot over a subset of the reals:

Wolfram Language code: Plot[ArithmeticGeometricMean[1, x], {x, 0, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[ArithmeticGeometricMean[1, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[ArithmeticGeometricMean[1, x], {x, 0, 2}, Assumptions -> x > 0]

Scope  (25)

Numerical Evaluation  (5)

Evaluate numerically:

Wolfram Language code: ArithmeticGeometricMean[1.2, 5]
Wolfram Language code: ArithmeticGeometricMean[-2., -5]

Evaluate to high precision:

Wolfram Language code: N[ArithmeticGeometricMean[52, 5], 30]

The precision of the output tracks the precision of the input:

Wolfram Language code: ArithmeticGeometricMean[2, 3.0000000000000000000000]

Complex number inputs:

Wolfram Language code: N[ArithmeticGeometricMean[1 + I, 3 + I]]

Evaluate efficiently at high precision:

Wolfram Language code: ArithmeticGeometricMean[32, 5`100]//Timing
Wolfram Language code: ArithmeticGeometricMean[32, 5`100];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: ArithmeticGeometricMean[2, Interval[{.8, 1.2}]]
Wolfram Language code: ArithmeticGeometricMean[2, CenteredInterval[8, .2]]
Wolfram Language code: ArithmeticGeometricMean[CenteredInterval[8, .2], 1]

Or compute average-case statistical intervals using Around:

Wolfram Language code: ArithmeticGeometricMean[ 1, Around[2, 0.01]]

Specific Values  (4)

Values at fixed points:

Wolfram Language code: Table[ArithmeticGeometricMean[x, y], {x, {16, 8}}, {y, {4, 10}}]//N

Value at zero:

Wolfram Language code: ArithmeticGeometricMean[0, 0]

Evaluate symbolically:

Wolfram Language code: ArithmeticGeometricMean[a, a]

Find a value of x for which ArithmeticGeometricMean[3,x]=1.5:

Wolfram Language code: xval = x /. FindRoot[ArithmeticGeometricMean[3, x] == 1.5, {x, 0.5}]
Wolfram Language code: Plot[ArithmeticGeometricMean[3, x], {x, 0, 2}, Epilog -> Style[Point[{xval, ArithmeticGeometricMean[3, xval]}], PointSize[Large], Red]]

Visualization  (2)

Plot the ArithmeticGeometricMean function for various orders:

Wolfram Language code: Plot[{ArithmeticGeometricMean[1, x], ArithmeticGeometricMean[2, x], ArithmeticGeometricMean[3, x], ArithmeticGeometricMean[4, x]}, {x, 0, 2}]

Plot the real part of TemplateBox[{2, z}, ArithmeticGeometricMean]:

Wolfram Language code: ComplexContourPlot[Re[ArithmeticGeometricMean[2, z]], {z, -1 - I, 1 + I}, Contours -> 20]

Plot the imaginary part of TemplateBox[{2, z}, ArithmeticGeometricMean]:

Wolfram Language code: ComplexContourPlot[Im[ArithmeticGeometricMean[2, z]], {z, -1 - I, 1 + I}, Contours -> 20]

Function Properties  (10)

Real domain of ArithmeticGeometricMean:

Wolfram Language code: FunctionDomain[ArithmeticGeometricMean[x, y], {x, y}]

Complex domain:

Wolfram Language code: FunctionDomain[ArithmeticGeometricMean[w, z], {w, z}, Complexes]

ArithmeticGeometricMean achieves all real values:

Wolfram Language code: FunctionRange[ArithmeticGeometricMean[x, z], {x, z}, y]//Quiet

ArithmeticGeometricMean threads elementwise over lists:

Wolfram Language code: ArithmeticGeometricMean[{1.0, 2.0, 3.0}, 5]

ArithmeticGeometricMean is not an analytic function:

Wolfram Language code: FunctionAnalytic[ArithmeticGeometricMean[x, 1], x]

It has both singularities and discontinuities:

Wolfram Language code: FunctionSingularities[ArithmeticGeometricMean[x, y], {x, y}]
Wolfram Language code: FunctionDiscontinuities[ArithmeticGeometricMean[x, y], {x, y}]

TemplateBox[{1, x}, ArithmeticGeometricMean] is nondecreasing on its real domain:

Wolfram Language code: FunctionMonotonicity[{ArithmeticGeometricMean[1, x], x ≥ 0}, x]

TemplateBox[{1, x}, ArithmeticGeometricMean] is injective:

Wolfram Language code: FunctionInjective[ArithmeticGeometricMean[1, x], x]
Wolfram Language code: Plot[{ArithmeticGeometricMean[1, x], 1}, {x, 0, 2}]

TemplateBox[{1, x}, ArithmeticGeometricMean] is not surjective:

Wolfram Language code: FunctionSurjective[ArithmeticGeometricMean[1, x], x]
Wolfram Language code: Plot[{ArithmeticGeometricMean[1, x], -2}, {x, -2, 2}]

TemplateBox[{1, x}, ArithmeticGeometricMean] is non-negative on its real domain:

Wolfram Language code: FunctionSign[{ArithmeticGeometricMean[1, x], x ≥ 0}, x]

TemplateBox[{{-, 1}, x}, ArithmeticGeometricMean] is non-positive on its real domain:

Wolfram Language code: FunctionSign[{ArithmeticGeometricMean[-1, x], x <= 0}, x]

TemplateBox[{1, x}, ArithmeticGeometricMean] is concave on its real domain:

Wolfram Language code: FunctionConvexity[{ArithmeticGeometricMean[1, x], x ≥ 0}, x]

TraditionalForm formatting:

Wolfram Language code: ArithmeticGeometricMean[a, b]//TraditionalForm

Differentiation  (2)

First derivative with respect to b:

Wolfram Language code: D[ArithmeticGeometricMean[a, b], b]

Higher derivatives with respect to b:

Wolfram Language code: Table[D[ArithmeticGeometricMean[a, b], {b, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to b when a=3:

Wolfram Language code: Plot[Evaluate[% /. a -> 3], {b, 0, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[ArithmeticGeometricMean[y, x], {x, 0, 2}]//Normal//FullSimplify

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[ArithmeticGeometricMean[2, x], {x, 0, m}], {m, 1, 3}]; Plot[{ArithmeticGeometricMean[2, x], terms}, {x, 0, 10}]

Taylor expansion at a generic point:

Wolfram Language code: Series[ArithmeticGeometricMean[y, x], {x, x0, 2}]//Normal// FullSimplify

Applications  (4)

Explicit form of the iterations yielding the arithmetic‐geometric mean:

Wolfram Language code: a[n_] := (a[n - 1] + b[n - 1]) / 2;b[n_] := Sqrt[a[n - 1] b[n - 1]];a[0] = 1.;b[0] = 2.;
Wolfram Language code: Table[{a[n], b[n]}, {n, 5}]

Compare with ArithmeticGeometricMean:

Wolfram Language code: ArithmeticGeometricMean[1., 2.]

Functional implementation of the previous iterative procedure:

Wolfram Language code: agmIterations[a_ ? InexactNumberQ, b_ ? InexactNumberQ] := FixedPointList[{(#[[1]] + #[[2]]) / 2, Sqrt[#[[1]]#[[2]]]}&, {a, b}]
Wolfram Language code: agmIterations[1., 2.]

Closed form of the iteration steps for calculating the arithmetic‐geometric mean expressed through ArithmeticGeometricMean:

Wolfram Language code: ArithmeticGeometricMeanIteration[n_, a_, b_] := With[{z = EllipticNomeQ[1 - (b / a)^2]}, ArithmeticGeometricMean[a, b]{EllipticTheta[3, 0, z^2^n]^2, EllipticTheta[4, 0, z^2^n]^2}]
Wolfram Language code: Table[ArithmeticGeometricMeanIteration[n, 1., 2.], {n, 0, 4}]

Show convergence speed using arbitrary‐precision arithmetic:

Wolfram Language code: With[{a = N[1, 2000], b = N[2, 2000]}, Table[ArithmeticGeometricMeanIteration[n, a, b], {n, 0, 10}] - ArithmeticGeometricMean[a, b]]//SetPrecision[#, 3]&

Compute a thousand digits of :

Wolfram Language code: With[{a = 1``1010, b = 1 / Sqrt[2], o = 9}, 2ArithmeticGeometricMeanIteration[o + 1, a, b][[1]] ^ 2 / (1 - Sum[2 ^ n ({1, -1}.(ArithmeticGeometricMeanIteration[n, a, b] ^ 2)), {n, 0, o}])]
Wolfram Language code: % - Pi

Compute Gauss's constant:

Wolfram Language code: N[1 / ArithmeticGeometricMean[1, Sqrt[2]], 50]

Compare to its expression in terms of beta function:

Wolfram Language code: % == (1/2π)Beta[(1/4), (1/2)]

Plot the absolute value in the parameter plane:

Wolfram Language code: Plot3D[Abs[ArithmeticGeometricMean[a, b]], {a, -2, 2}, {b, -2, 2}]//Quiet

Properties & Relations  (3)

Derivatives of ArithmeticGeometricMean:

Wolfram Language code: D[ArithmeticGeometricMean[a, b], a]//Simplify
Wolfram Language code: D[ArithmeticGeometricMean[a, b], b]//Simplify

Use FunctionExpand to expand ArithmeticGeometricMean to other functions:

Wolfram Language code: FunctionExpand[ArithmeticGeometricMean[a, b], a > 0 && b > 0]

Show that ArithmeticGeometricMean obeys a hypergeometric‐type differential equation:

Wolfram Language code: w[a_] := ArithmeticGeometricMean[a, b]
Wolfram Language code: FullSimplify[2 a (b ^ 2 - a ^ 2) w'[a] ^ 2 + w[a] ((3 a ^ 2 - b ^ 2) w'[a] + a (a ^ 2 - b ^ 2) w''[a]) - a w[a] ^ 2 == 0, a > 0 && b > 0]

Proof that iterations lie between the arithmetic and the geometric means:

Wolfram Language code: a[n_] := (a[n - 1] + b[n - 1]) / 2;b[n_] := Sqrt[a[n - 1] b[n - 1]];a[0] = a0;b[0] = b0;
Wolfram Language code: Reduce[ForAll[{a0, b0}, {a0, b0}∈ Reals && a0 > 0 && b0 > 0, (a0 + b0) / 2 >= a[3] >= b[3] >= Sqrt[a0 b0]]]
Wolfram Research (1988), ArithmeticGeometricMean, Wolfram Language function, https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html (updated 2022).

Text

Wolfram Research (1988), ArithmeticGeometricMean, Wolfram Language function, https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html (updated 2022).

CMS

Wolfram Language. 1988. "ArithmeticGeometricMean." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html.

APA

Wolfram Language. (1988). ArithmeticGeometricMean. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html

BibTeX

@misc{reference.wolfram_2026_arithmeticgeometricmean, author="Wolfram Research", title="{ArithmeticGeometricMean}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_arithmeticgeometricmean, organization={Wolfram Research}, title={ArithmeticGeometricMean}, year={2022}, url={https://reference.wolfram.com/language/ref/ArithmeticGeometricMean.html}, note=[Accessed: 12-June-2026]}