Wolfram Language & System Documentation Center

EllipticK

EllipticK[m]

gives the complete elliptic integral of the first kind .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
EllipticK is given in terms of the incomplete elliptic integral of the first kind by .
EllipticK[m] has a branch cut discontinuity in the complex m plane running from to .
For certain special arguments, EllipticK automatically evaluates to exact values.
EllipticK can be evaluated to arbitrary numerical precision.
EllipticK automatically threads over lists.
EllipticK can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (5)

Evaluate numerically:

Wolfram Language code: EllipticK[0.5]

Plot over a subset of the reals:

Wolfram Language code: Plot[EllipticK[x], {x, -1, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[EllipticK[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[EllipticK[x], {x, 0, 5}]

Series expansion at Infinity:

Wolfram Language code: Series[EllipticK[x], {x, ∞, 2}]//Normal

Scope (38)

Numerical Evaluation (5)

Evaluate to high precision:

Wolfram Language code: N[EllipticK[8 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: EllipticK[0.999999999999999990000000000000000]

Evaluate numerically for complex arguments:

Wolfram Language code: EllipticK[2.5 + I]

Evaluate EllipticK efficiently at high precision:

Wolfram Language code: EllipticK[0.4`500]//Timing

Wolfram Language code: EllipticK[0.4`100000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: EllipticK[Interval[{0.4, 0.5}]]

Wolfram Language code: EllipticK[CenteredInterval[4, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: EllipticK[ Around[1 / 2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: EllipticK[{{-1, 0}, {1 / 2, -1}}]//FunctionExpand

Or compute the matrix EllipticK function using MatrixFunction:

Wolfram Language code: MatrixFunction[EllipticK, {{-1, 0}, {1 / 2, -1}}]//FunctionExpand

Specific Values (5)

Simple exact values are generated automatically:

Wolfram Language code: {EllipticK[0], EllipticK[1]}

Some exact values in terms of Gamma after applying FunctionExpand:

Wolfram Language code: {EllipticK[-1], EllipticK[1 / 2]}//FunctionExpand

Find directional limiting values at branch cuts:

Wolfram Language code: Limit[EllipticK[2 + ε I], ε -> 0, Direction -> 1]

Wolfram Language code: Limit[EllipticK[2 + ε I], ε -> 0, Direction -> -1]

Value at infinity:

Wolfram Language code: EllipticK[Infinity]

Find the root of the equation :

Wolfram Language code:

f[m_] := EllipticK[m] - 2;
xzero = Solve[f[m] == 0 && 0.5 < m < 1, m][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[f[m], {m, -1, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

Visualization (2)

Plot EllipticK:

Wolfram Language code: Plot[{EllipticK[m]}, {m, -2, 1}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[EllipticK[z]], {z, -5 - 5I, 5 + 5I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[EllipticK[z]], {z, -5 - 5I, 5 + 5I}, IconizedObject[«PlotOptions»]]

Function Properties (9)

EllipticK is defined for all real values less than 1:

Wolfram Language code: FunctionDomain[EllipticK[m], m]

EllipticK takes all real positive values:

Wolfram Language code: FunctionRange[EllipticK[m], m, y]//Quiet

EllipticK is not an analytic function:

Wolfram Language code: FunctionAnalytic[EllipticK[m], m]

Has both singularities and discontinuities:

Wolfram Language code: FunctionSingularities[EllipticK[m], m]//Quiet

Wolfram Language code: FunctionDiscontinuities[EllipticK[m], m]//Quiet

EllipticK is not a meromorphic function:

Wolfram Language code: FunctionMeromorphic[EllipticK[m], m]

EllipticK is nondecreasing on its domain:

Wolfram Language code: FunctionMonotonicity[{EllipticK[m], m < 1}, m]

EllipticK is injective:

Wolfram Language code: FunctionInjective[EllipticK[m], m]

Wolfram Language code: Plot[{EllipticK[m], 2}, {m, -2, 2}]

EllipticK is not surjective:

Wolfram Language code: FunctionSurjective[EllipticK[m], m]

Wolfram Language code: Plot[{EllipticK[m], -2}, {m, -2, 2}]

EllipticK is non-negative on its domain:

Wolfram Language code: FunctionSign[{EllipticK[m], m < 1}, m]

EllipticK is convex on its domain:

Wolfram Language code: FunctionConvexity[{EllipticK[m], m < 1}, m]

Differentiation (3)

First derivative:

Wolfram Language code: D[EllipticK[m], m]

Higher derivatives:

Wolfram Language code: Table[D[EllipticK[m], {m, n}], {n, 1, 3}]//FullSimplify

Wolfram Language code: Plot[Evaluate[%], {m, -1, 1}, PlotLegends -> Table[Inactive[D][EllipticK[m], {m, k}], {k, Length[%]}]]

Formula for the derivative:

Wolfram Language code: D[EllipticK[m], {m, n}]

Integration (3)

Indefinite integral of EllipticK:

Wolfram Language code: Integrate[EllipticK[m], m]

Definite integral over an interval lying on the branch cut:

Wolfram Language code: Integrate[EllipticK[m], {m, 1, 2}]

More integrals:

Wolfram Language code: Integrate[z^αEllipticK[z], z]

Wolfram Language code: Integrate[(z EllipticK[z^2]/(1 - z^2)^3 / 2), z]

Series Expansions (3)

Taylor expansion for EllipticK:

Wolfram Language code: Series[EllipticK[m], {m, 0, 3}]

Plot the first three approximations for EllipticK around :

Wolfram Language code:

terms = Normal@Table[Series[EllipticK[m], {m, 0, n}], {n, 1, 3}];
Plot[{EllipticK[m], terms}, {m, -2, 2}]

Series expansions at branch points:

Wolfram Language code: Series[EllipticK[x], {x, 1, 1}]

EllipticK can be applied to power series:

Wolfram Language code: EllipticK[Exp[x] - 1 + O[x] ^ 4]

Integral Transforms (3)

Compute the Laplace transform using LaplaceTransform:

Wolfram Language code: LaplaceTransform[EllipticK[-t], t, s]

MellinTransform:

Wolfram Language code: MellinTransform[EllipticK[-t], t, s ]

HankelTransform:

Wolfram Language code: HankelTransform[EllipticK[-r], r, s ]

Function Representations (5)

Relation to other elliptic integrals:

Wolfram Language code: EllipticPi[0, m]

Wolfram Language code: EllipticF[(π/2), m]

Relation to the LegendreP:

Wolfram Language code: (π/2)LegendreP[-(1/2), 1 - 2 m]//FullSimplify

Represent in terms of MeijerG using MeijerGReduce:

Wolfram Language code: MeijerGReduce[EllipticK[x], x]

Wolfram Language code: Activate[%]

EllipticK can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[EllipticK[m], m]

TraditionalForm formatting:

Wolfram Language code: EllipticK[m]//TraditionalForm

Applications (7)

Small-angle approximation to the period of a pendulum:

Wolfram Language code: Series[4Sqrt[(d/g)]EllipticK[Sin[(α/2)]^2], {α, 0, 2}]

Plot the period versus the initial angle:

Wolfram Language code: Plot[EllipticK[Sin[(α/2)] ^ 2], {α, 0, Pi}, AxesOrigin -> {0, EllipticK[0]}]

Vector potential due to a circular current flow, in cylindrical coordinates:

Wolfram Language code:

A = -2(((r + R)^2 + z^2) EllipticE[(4 r R/(r + R)^2 + z^2)] - (r^2 + R^2 + z^2) EllipticK[(4 r R/(r + R)^2 + z^2)]) / (r R Sqrt[(r + R)^2 + z^2]);

The components of the magnetic field:

Wolfram Language code: Bz = D[r A, r] / r//FullSimplify

Wolfram Language code: Br = -D[A, z]//FullSimplify

Plot the magnitude of the magnetic field:

Wolfram Language code: Plot3D[Sqrt[Br^2 + Bz^2] /. R -> 1, {r, 0.001, 3 / 2}, {z, -1, 1}]

Resistance between the origin and the point in an infinite 3D lattice of unit resistors:

Wolfram Language code: ρ[n_] := (1/π^2)NIntegrate[EllipticK[((2/3 - Cos[x]))^2](2 - Cos[n x]/3 - Cos[x]), {x, 0, Pi}]

Wolfram Language code: DiscretePlot[ρ[n], {n, 50}, PlotRange -> All]

Energy for the Onsager solution of the Ising model:

Wolfram Language code:

ℰ = With[{β = (1/Subscript[k, B]T)}, -2 n J Tanh[2 β J] - n J (Sinh[2 β J]^2 - 1/Sinh[2β J]Cosh[2β J])((2/π)EllipticK[(2 (Sinh[2β J]/Cosh[2β J]^2))^2] - 1)];

Plot of the specific heat:

Wolfram Language code: Plot[Evaluate[D[ℰ, T] /. {n -> 1, J -> 1, Subscript[k, B] -> 1}], {T, 0.1, 4}, AxesOrigin -> {0, 0}]

Find the critical temperature:

Wolfram Language code: Select[Solve[1 / D[ℰ, T] == 0, T], (Subscript[k, B]T / J /. #) > 0&]//Quiet

Calculate a singular value:

Wolfram Language code: FindRoot[Re[(EllipticK[1 - z^2]/EllipticK[z^2])] == Sqrt[2], {z, 1 / 2}, WorkingPrecision -> 50]

Wolfram Language code: (z /. %) - (Sqrt[2] - 1)

Current flow in a rectangular conducting sheet with voltage applied at a pair of opposite corners:

Wolfram Language code:

flow[m_] = (NevilleThetaD[x, m] NevilleThetaD[y, 1 - m] NevilleThetaS[x, m] NevilleThetaS[y, 1 - m]) / (NevilleThetaC[x, m] NevilleThetaC[y, 1 - m] NevilleThetaN[x, m] NevilleThetaN[y, 1 - m]);

Plot the flow lines with bounds defined via EllipticK:

Wolfram Language code:

With[{m = 0.4}, ContourPlot[flow[m], {x, 0, EllipticK[m]}, {y, 0, EllipticK[1 - m]}, ContourShading -> False, MaxRecursion -> 1, Contours -> {0.02, 0.13, 0.3, 0.54, 0.9, 1.46, 2.53, 5.17, 28.4}]]

Construct lowpass elliptic filter for analog signal:

Wolfram Language code: 𝒩 = 5;ωPass = 4.8;ℊPass = 0.92;ℊStop = 0.08;

Compute filter ripple parameters and associate elliptic function parameter:

Wolfram Language code:

ϵp = Sqrt[ℊPass^-2 - 1];ϵs = Sqrt[ℊStop^-2 - 1];
m1 = (ϵp / ϵs)^2;
K1 = EllipticK[m1];
K1p = EllipticK[1 - m1];

Use elliptic degree equation to find the ratio of the pass and the stop frequencies:

Wolfram Language code:

us = Range[1, 2⌊(𝒩/2)⌋ - 1, 2] / 𝒩;
m = 1 - (1 - m1) ^ 𝒩 Apply[Times, JacobiSN[us K1p, 1 - m1] ^ 8]

Compute corresponding stop frequency and elliptic parameters:

Wolfram Language code:

K = EllipticK[m];Kp = EllipticK[1 - m];
ωStop = ωPass / Sqrt[m]

Compute ripple locations and poles and zeros of the transfer function:

Wolfram Language code:

ζs = JacobiCD[us K, m];
zeros = I ωStop / ζs;

Compute poles of the transfer function:

Wolfram Language code:

Subscript[ν, 0] = (1/𝒩 K1)InverseJacobiSC[(1/ϵp), 1 - m1];
poles = ωPass I JacobiCD[(us - I Subscript[ν, 0])K, m];

Assemble the transfer function:

Wolfram Language code:

H[ω_] = Piecewise[{{ℊPass, Mod[𝒩, 2] == 0}, {(1/1 + I ω / ωPass JacobiCS[Subscript[ν, 0] K, 1 - m]), Mod[𝒩, 2] == 1}}] Apply[Times, ((1 - I ω / zeros)(1 - I ω / Conjugate[zeros])/(1 - I ω / poles)(1 - I ω / Conjugate[poles]))];

Wolfram Language code:

Plot[Abs[H[ω]], {ω, 0, 8}, PlotRange -> All, Epilog -> {Pink, Dashed, Line[{{0, ℊPass}, {ωPass, ℊPass}, {ωPass, ℊStop}}], Line[{{ωStop, ℊPass}, {ωStop, ℊStop}, {10, ℊStop}}]}]

Compare with the result of EllipticFilterModel:

Wolfram Language code: tf = EllipticFilterModel[{"Lowpass", {ωPass, ωStop}, -20Log10[{ℊPass, ℊStop}]}];

Wolfram Language code: Plot[Abs[tf[I ω]], {ω, 0, 8}]

Properties & Relations (4)

This shows the branch cuts of the EllipticK function:

Wolfram Language code: Plot3D[Im[EllipticK[x + I y]], {x, -2, 2}, {y, -2, 2}]

Numerically find a root of a transcendental equation:

Wolfram Language code: FindRoot[EllipticK[z]^2 - 5 EllipticK[z + 2] + z == 6, {z, 10}]

Solve a differential equation:

Wolfram Language code: DSolve[z (1 - z) w''[z] + (1 - 2 z) w'[z] - w[z] / 4 == 0, w[z], z]//Simplify

EllipticK is a particular case of various mathematical functions:

Wolfram Language code:

{LegendreP[-(1/2), 1 - 2 z], AppellF1[(1/2), (1/2), (1/2), (3/2), 1, z ], EllipticF[(π/2), z], EllipticPi[0, (π/2), z], MeijerG[{{(1/2), (1/2)}, {}}, {{0}, {0}}, -z]}

Possible Issues (3)

Machine-precision evaluation can result in numerically inaccurate answers near branch cuts:

Wolfram Language code: EllipticK[ 2 - I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])] // N

Wolfram Language code: EllipticK[2 - I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])] //N[#, 100]& // N

The defining integral converges only under additional conditions:

Wolfram Language code: Integrate[1 / Sqrt[1 - m Sin[t] ^ 2], {t, 0, Pi / 2}]

Different argument conventions exist that result in modified results:

Wolfram Language code: Integrate[1 / Sqrt[1 - k ^ 2 Sin[t] ^ 2], {t, 0, Pi / 2}, Assumptions -> k ^ 2 < 1]

Neat Examples (2)

Probability that a random walker in a 3D cubic lattice returns to the origin:

Wolfram Language code: p = 1 - (π^2/72)(6 + 2 Sqrt[3] + Sqrt[6]) EllipticK[35 + 24 Sqrt[2] - 20 Sqrt[3] - 14 Sqrt[6]]^-2 //N

Carry out a modeling run of 1000 walks and count how many it returns to the origin:

Wolfram Language code:

maxSteps = 500;
BlockRandom[SeedRandom[2021];
	start = {0, 0, 0};Count[Table[walkerPosition = start;steps = 0;While[steps == 0 || (steps < maxSteps && walkerPosition =!= start), steps++;walkerPosition = walkerPosition + {{1, 0, 0}, {-1, 0, 0}, {0, 1, 0}, {0, -1, 0}, {0, 0, 1}, {0, 0, -1}}[[RandomInteger[{1, 6}]]]];steps, {1000}], _ ? (# < maxSteps&)]]

Compare with the expected count at :

Wolfram Language code:

With[{countDist = BinomialDistribution[1000, p]}, Around[Mean[countDist], 2StandardDeviation[countDist]]
	]

Riemann surface of :

Wolfram Language code:

Show[Plot3D[Evaluate[Table[Im[EllipticK[x + I y] - j 2 I EllipticK[1 - (x + I y)]], {j, -2, 2}]], {x, -9, 9}, {y, ##}, ClippingStyle -> None, PlotStyle -> Opacity[0.6], Mesh -> False, BoxRatios -> {1, 1, 1}, MaxRecursion -> 5, PlotRange -> {All, All, {-9, 9}}]&@@@{{-9, -10 ^ -6}, {10 ^ -6, 9}}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

EllipticK

Details

Examples

Basic Examples (5)

Scope (38)

Numerical Evaluation (5)

Specific Values (5)

Visualization (2)

Function Properties (9)

Differentiation (3)

Integration (3)

Series Expansions (3)

Integral Transforms (3)

Function Representations (5)

Applications (7)

Properties & Relations (4)

Possible Issues (3)

Neat Examples (2)

Text

CMS

APA

BibTeX

BibLaTeX

EllipticK

Details

Examples

Basic Examples (5)

Scope (38)

Numerical Evaluation (5)

Specific Values (5)

Visualization (2)

Function Properties (9)

Differentiation (3)

Integration (3)

Series Expansions (3)

Integral Transforms (3)

Function Representations (5)

Applications (7)

Properties & Relations (4)

Possible Issues (3)

Neat Examples (2)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX