WOLFRAM

Wolfram Language & System Documentation Center

BoundaryMeshRegionQ[reg]

yields True if the region reg is a valid BoundaryMeshRegion object and False otherwise.

Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

BoundaryMeshRegionQ

BoundaryMeshRegionQ[reg]

yields True if the region reg is a valid BoundaryMeshRegion object and False otherwise.

Examples

open all close all

Basic Examples  (2)

A valid BoundaryMeshRegion in 2D:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {50, 2}]]
Wolfram Language code: BoundaryMeshRegionQ[ℛ]

A valid BoundaryMeshRegion in 3D:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {100, 3}]]
Wolfram Language code: BoundaryMeshRegionQ[ℛ]

Scope  (7)

Use BoundaryMeshRegionQ to check for valid BoundaryMeshRegion constructions:

Wolfram Language code: invalid = BoundaryMeshRegion[{{0, 0}, {1, 0}, {0, 1}}, garbage]

Even though the expression Head is BoundaryMeshRegion, it is not a valid object to use:

Wolfram Language code: {Head[invalid], BoundaryMeshRegionQ[invalid]}

A directly constructed valid BoundaryMeshRegion:

Wolfram Language code: valid = BoundaryMeshRegion[{{0, 0}, {1, 0}, {0, 1}}, Line[{1, 2, 3, 1}]]
Wolfram Language code: BoundaryMeshRegionQ[valid]

BoundaryMeshRegion from a set of points:

Wolfram Language code: pl = RandomReal[1, {10, 2}];
Wolfram Language code: ℛ = ConvexHullMesh[pl]
Wolfram Language code: BoundaryMeshRegionQ[ℛ]

A MeshRegion is not a BoundaryMeshRegion:

Wolfram Language code: mr = DelaunayMesh[RandomReal[1, {10, 3}]]
Wolfram Language code: BoundaryMeshRegionQ[mr]

The full-dimensional component can be converted using BoundaryMesh:

Wolfram Language code: bm = BoundaryMesh[mr]
Wolfram Language code: BoundaryMeshRegionQ[bm]

A special region is not a BoundaryMeshRegion:

Wolfram Language code: sr = Disk[{0, 0}, 2];
Wolfram Language code: BoundaryMeshRegionQ[sr]

Full-dimensional regions can be converted using BoundaryDiscretizeRegion:

Wolfram Language code: bdr = BoundaryDiscretizeRegion[sr]
Wolfram Language code: BoundaryMeshRegionQ[bdr]

A graphic is not a BoundaryMeshRegion:

Wolfram Language code: g = Graphics[{Orange, Disk[{2, 2}], Brown, Rectangle[{0, 0}, {2, 2}]}]

Full-dimensional regions can be converted using BoundaryDiscretizeGraphics:

Wolfram Language code: bdg = BoundaryDiscretizeGraphics[g]
Wolfram Language code: {BoundaryMeshRegionQ[mr], BoundaryMeshRegionQ[bdg]}

BoundaryMeshRegion in dimension :

Wolfram Language code: rl = Table[ConvexHullMesh[RandomReal[1, {10, d}]], {d, 3}]
Wolfram Language code: BoundaryMeshRegionQ /@ rl

Applications  (2)

Create a definition that only applies to boundary mesh regions:

Wolfram Language code: rl = Flatten@Table[{DiscretizeRegion[r], BoundaryDiscretizeRegion[r]}, {r, {Disk[], Parallelogram[]}}]
Wolfram Language code: f[br_ ? BoundaryMeshRegionQ] := TriangulateMesh[br]
Wolfram Language code: f /@ rl

Select the BoundaryMeshRegion from a list of regions:

Wolfram Language code: rl = Table[RandomChoice[{ConvexHullMesh, VoronoiMesh}][RandomReal[1, {9, 2}]], {4}]
Wolfram Language code: Select[rl, BoundaryMeshRegionQ]

Properties & Relations  (3)

A BoundaryMeshRegion is always RegionQ:

Wolfram Language code: Subscript[ℛ, 1] = ConvexHullMesh[RandomReal[1, {10, 2}]]; Subscript[ℛ, 2] = DelaunayMesh[RandomReal[1, {10, 2}]];
Wolfram Language code: BoundaryMeshRegionQ /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}
Wolfram Language code: RegionQ /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}

A BoundaryMeshRegion is always BoundedRegionQ:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {10, 2}]];
Wolfram Language code: {BoundaryMeshRegionQ[ℛ], BoundedRegionQ[ℛ]}

A BoundaryMeshRegion is always ConstantRegionQ:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {10, 2}]];
Wolfram Language code: {BoundaryMeshRegionQ[ℛ], ConstantRegionQ[ℛ]}
Wolfram Research (2014), BoundaryMeshRegionQ, Wolfram Language function, https://reference.wolfram.com/language/ref/BoundaryMeshRegionQ.html.

Text

Wolfram Research (2014), BoundaryMeshRegionQ, Wolfram Language function, https://reference.wolfram.com/language/ref/BoundaryMeshRegionQ.html.

CMS

Wolfram Language. 2014. "BoundaryMeshRegionQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BoundaryMeshRegionQ.html.

APA

Wolfram Language. (2014). BoundaryMeshRegionQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BoundaryMeshRegionQ.html

BibTeX

@misc{reference.wolfram_2026_boundarymeshregionq, author="Wolfram Research", title="{BoundaryMeshRegionQ}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/BoundaryMeshRegionQ.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_boundarymeshregionq, organization={Wolfram Research}, title={BoundaryMeshRegionQ}, year={2014}, url={https://reference.wolfram.com/language/ref/BoundaryMeshRegionQ.html}, note=[Accessed: 13-June-2026]}