WOLFRAM

Wolfram Language & System Documentation Center

MeshRegionQ[reg]

yields True if the region reg is a valid MeshRegion object and False otherwise.

Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

MeshRegionQ

MeshRegionQ[reg]

yields True if the region reg is a valid MeshRegion object and False otherwise.

Examples

open all close all

Basic Examples  (2)

A valid MeshRegion in 2D:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {50, 2}]]
Wolfram Language code: MeshRegionQ[ℛ]

A valid MeshRegion in 3D:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {50, 3}]]
Wolfram Language code: MeshRegionQ[ℛ]

Scope  (7)

Use MeshRegionQ to check for valid MeshRegion constructions:

Wolfram Language code: invalid = MeshRegion[{{0, 0}, {1, 1}}, garbage]

Even though the expression Head is MeshRegion, it is not a valid object to use:

Wolfram Language code: {Head[invalid], MeshRegionQ[invalid]}

A directly constructed valid MeshRegion:

Wolfram Language code: valid = MeshRegion[{{0, 0}, {1, 1}}, Line[{1, 2}]]
Wolfram Language code: MeshRegionQ[valid]

MeshRegion from a set of points:

Wolfram Language code: pl = RandomReal[1, {10, 2}];
Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {DelaunayMesh[pl], VoronoiMesh[pl]}
Wolfram Language code: {MeshRegionQ[Subscript[ℛ, 1]], MeshRegionQ[Subscript[ℛ, 2]]}

A BoundaryMeshRegion is not a MeshRegion, but can be converted using TriangulateMesh:

Wolfram Language code: br = ConvexHullMesh[RandomReal[1, {10, 3}]]
Wolfram Language code: tm = TriangulateMesh[br]
Wolfram Language code: {MeshRegionQ[br], MeshRegionQ[tm]}

Special regions are not MeshRegion, but can be converted using DiscretizeRegion:

Wolfram Language code: sr = Disk[{0, 0}, 2]; dr = DiscretizeRegion[sr]
Wolfram Language code: {MeshRegionQ[sr], MeshRegionQ[dr]}

Graphics are not MeshRegion, but can be converted using DiscretizeGraphics:

Wolfram Language code: g = Graphics[{Orange, Disk[{2, 2}], Brown, Rectangle[{0, 0}, {2, 2}]}]
Wolfram Language code: dg = DiscretizeGraphics[g]
Wolfram Language code: {MeshRegionQ[g], MeshRegionQ[dg]}

Mesh regions in dimension :

Wolfram Language code: rl = Table[DelaunayMesh[RandomReal[1, {10, d}]], {d, 3}]
Wolfram Language code: MeshRegionQ /@ rl

Applications  (2)

Create a definition that only applies to mesh regions:

Wolfram Language code: rl = Flatten@Table[{DiscretizeRegion[r], BoundaryDiscretizeRegion[r]}, {r, {Disk[], Parallelogram[]}}]
Wolfram Language code: f[mr_ ? MeshRegionQ] := BoundaryMesh[mr]
Wolfram Language code: f /@ rl

Select the MeshRegion from a list of regions:

Wolfram Language code: rl = Table[RandomChoice[{ConvexHullMesh, VoronoiMesh}][RandomReal[1, {9, 2}]], {4}]
Wolfram Language code: Select[rl, MeshRegionQ]

Properties & Relations  (3)

MeshRegionQ is a special case of RegionQ:

Wolfram Language code: Subscript[ℛ, 1] = DelaunayMesh[RandomReal[1, {10, 2}]]; Subscript[ℛ, 2] = ConvexHullMesh[RandomReal[1, {10, 2}]];
Wolfram Language code: MeshRegionQ /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}
Wolfram Language code: RegionQ /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}

A MeshRegion is always BoundedRegionQ:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {10, 2}]];
Wolfram Language code: {MeshRegionQ[ℛ], BoundedRegionQ[ℛ]}

A MeshRegion is always ConstantRegionQ:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {10, 2}]];
Wolfram Language code: {MeshRegionQ[ℛ], ConstantRegionQ[ℛ]}
Wolfram Research (2014), MeshRegionQ, Wolfram Language function, https://reference.wolfram.com/language/ref/MeshRegionQ.html.

Text

Wolfram Research (2014), MeshRegionQ, Wolfram Language function, https://reference.wolfram.com/language/ref/MeshRegionQ.html.

CMS

Wolfram Language. 2014. "MeshRegionQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MeshRegionQ.html.

APA

Wolfram Language. (2014). MeshRegionQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MeshRegionQ.html

BibTeX

@misc{reference.wolfram_2026_meshregionq, author="Wolfram Research", title="{MeshRegionQ}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/MeshRegionQ.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_meshregionq, organization={Wolfram Research}, title={MeshRegionQ}, year={2014}, url={https://reference.wolfram.com/language/ref/MeshRegionQ.html}, note=[Accessed: 12-June-2026]}