WOLFRAM

Wolfram Language & System Documentation Center

BoundedRegionQ[reg]

gives True if reg is a bounded region and False otherwise.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Special Regions  
Formula Regions  
Mesh Regions  
Show More Show More
Derived Regions  
Geographic Regions  
CSG Regions  
Subdivision Regions  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

BoundedRegionQ

BoundedRegionQ[reg]

gives True if reg is a bounded region and False otherwise.

Details

  • A region is bounded if it can be included in a box with finite ranges.

Examples

open all close all

Basic Examples  (2)

A bounded region:

Wolfram Language code: BoundedRegionQ[Disk[]]
Wolfram Language code: Region[Disk[]]

An unbounded region:

Wolfram Language code: BoundedRegionQ[HalfPlane[{{0, 0, 0}, {-1, 1, 1}}, {1, 1, 1}]]
Wolfram Language code: Region[HalfPlane[{{0, 0, 0}, {-1, 1, 1}}, {1, 1, 1}], Boxed -> True]

Scope  (20)

Special Regions  (4)

Regions in including Point:

Wolfram Language code: BoundedRegionQ[Point[{1}]]

Interval:

Wolfram Language code: ℛ = Interval[{1, 2}]; NumberLinePlot[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

A HalfLine is unbounded:

Wolfram Language code: BoundedRegionQ[HalfLine[{{1}, {2}}]]

Regions in including Point:

Wolfram Language code: ℛ = Point[Tuples[Range[5], 2]]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Line:

Wolfram Language code: ℛ = Line[{{1, 2}, {4, 3}}]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Polygon:

Wolfram Language code: ℛ = Polygon[{{0, 0}, {2, -1}, {1, 0}, {2, 1}}]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Circle:

Wolfram Language code: ℛ = Circle[{1, 2}, 3]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Disk:

Wolfram Language code: ℛ = Disk[{1, 2}, {4, 3}]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

An InfiniteLine is unbounded:

Wolfram Language code: ℛ = InfiniteLine[{0, 0}, {3, 1}]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Regions in including Point:

Wolfram Language code: ℛ = Point[Tuples[Range[5], 3]]; Region[ℛ, Boxed -> True]
Wolfram Language code: BoundedRegionQ[ℛ]

Line:

Wolfram Language code: ℛ = Line[{{1, 2, 3}, {6, 5, 4}}]; Region[ℛ, Boxed -> True]
Wolfram Language code: BoundedRegionQ[ℛ]

Cylinder:

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2]; Region[ℛ, Boxed -> True]
Wolfram Language code: BoundedRegionQ[ℛ]

A HalfPlane is unbounded:

Wolfram Language code: ℛ = HalfPlane[{{0, 0, 0}, {1, 0, 0}}, {0, 1, 1}]; Region[ℛ, Boxed -> True]
Wolfram Language code: BoundedRegionQ[ℛ]

Regions in including Simplex in :

Wolfram Language code: BoundedRegionQ[Simplex[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}]]

Cuboid in :

Wolfram Language code: BoundedRegionQ[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}]]

Ball in :

Wolfram Language code: BoundedRegionQ[Ball[{1, 2, 3, 4, 5, 6, 7}, 8]]

Formula Regions  (3)

A parabolic region as an ImplicitRegion:

Wolfram Language code: ℛ = ImplicitRegion[x^2 - y^2 ≤ 1, {x, y}];
Wolfram Language code: DiscretizeRegion[ℛ, {{-2, 2}, {-2, 2}}]
Wolfram Language code: BoundedRegionQ[ℛ]

A cylinder:

Wolfram Language code: BoundedRegionQ[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}]]

A parabola represented as a ParametricRegion:

Wolfram Language code: ℛ = ParametricRegion[{t, t^2}, {t}];
Wolfram Language code: Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Using a rational parametrization of the disk:

Wolfram Language code: ℛ = ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2)}, {t, {r, 0, 1}}];

The region is bounded, but the parameter is unbounded:

Wolfram Language code: BoundedRegionQ[ℛ]

ImplicitRegion can have several components of different dimension:

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 1∨(x + 1)^2 + y^2 == 1, {x, y}];
Wolfram Language code: Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Mesh Regions  (4)

MeshRegion in 1D:

Wolfram Language code: DelaunayMesh[RandomReal[1, {10, 1}]]
Wolfram Language code: BoundedRegionQ[%]

2D:

Wolfram Language code: DelaunayMesh[RandomReal[1, {50, 2}]]
Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: DelaunayMesh[RandomReal[1, {100, 3}]]
Wolfram Language code: BoundedRegionQ[%]

BoundaryMeshRegion in 1D:

Wolfram Language code: ConvexHullMesh[RandomReal[1, {10, 1}]]
Wolfram Language code: RegionQ[%]

2D:

Wolfram Language code: ConvexHullMesh[RandomReal[1, {50, 2}]]
Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: ConvexHullMesh[RandomReal[1, {100, 3}]]
Wolfram Language code: BoundedRegionQ[%]

MeshRegion that represents a curve in 2D:

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2, 3, 4, 2}}]}]
Wolfram Language code: BoundedRegionQ[ℛ]

A MeshRegion can have components of different dimension:

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2}}], Polygon[{{2, 3, 4}}]}]
Wolfram Language code: BoundedRegionQ[ℛ]

Derived Regions  (4)

RegionIntersection of two regions:

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

RegionUnion of mixed-dimensional regions:

Wolfram Language code: ℛ = RegionUnion[Circle[{1, 0}, 1], Disk[{0, 0}, 1]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

TransformedRegion:

Wolfram Language code: ℛ = TransformedRegion[Disk[{0, 0}, 1], ScalingTransform[{3, 2}]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

RegionBoundary:

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = RegionBoundary[Subscript[ℛ, 1]]
Wolfram Language code: {Region[Subscript[ℛ, 1]], Region[Subscript[ℛ, 2]]}
Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 1]], BoundedRegionQ[Subscript[ℛ, 2]]}

Geographic Regions  (3)

A polygon with GeoPosition:

Wolfram Language code: ℛ = Polygon[GeoPosition[{{{40.083441, -88.235716}, {40.083607, -88.257488}, {40.082603, -88.257149}, {40.076136999999996, -88.25740499999999}, {40.076178, -88.270888}, {40.076516, -88.271558}, {40.083686, -88.271512}, {40.083659999999995, -88.267046}, ... 33323}, {40.098112, -88.228687}, {40.095216, -88.228627}, {40.095179, -88.238547}, {40.094480999999995, -88.238546}, {40.094508999999995, -88.23267}, {40.094106, -88.232556}, {40.090666999999996, -88.232477}, {40.090741, -88.235745}}}]];
Wolfram Language code: BoundedRegionQ[ℛ]

Polygons with GeoPositionXYZ:

Wolfram Language code: ℛ = Polygon[GeoPositionXYZ[{{{150451.6968462432, -4.884430486484052*^6, 4.085078564164219*^6}, {148595.27532671497, -4.884475441490381*^6, 4.085092666620835*^6}, {148626.35829777512, -4.884546311005128*^6, 4.0850073717259285*^6}, {148618.5908634042 ... 7*^6, 4.0860187668081024*^6}, {150697.56410771207, -4.8836599487428395*^6, 4.085984535480795*^6}, {150711.88303095422, -4.883905546449982*^6, 4.0856924143435075*^6}, {150433.15479548014, -4.883908845676418*^6, 4.0856987003255524*^6}}}]];
Wolfram Language code: BoundedRegionQ[ℛ]

Polygons with GeoPositionENU:

Wolfram Language code: ℛ = Polygon[GeoPositionENU[{{{3378.2547059731055, -3369.2234780923936, -0.7440009205072329}, {1521.3211635380246, -3351.391253626573, -0.022340134218666208}, {1550.2571145363192, -3462.8657556618973, -0.08899812728964207}, {1528.5672303494055, -418 ... 63383291193, -0.37494203351275246}, {3654.121991908476, -2566.7472331234085, -0.5214977847472255}, {3375.420726854886, -2558.6597093173914, -0.3648706331350695}}}, GeoPosition[{40.11379115639895, -88.2753251202516, -1.0415787873318691}]]];
Wolfram Language code: BoundedRegionQ[ℛ]

A polygon with GeoGridPosition:

Wolfram Language code: ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015}, {-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167}, {-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449}, {-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654}, {-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825}, {-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];
Wolfram Language code: BoundedRegionQ[ℛ]

BoundedRegionQ works on polygons with geographic entities:

Wolfram Language code: ℛ = Polygon[["france"]];
Wolfram Language code: BoundedRegionQ[ℛ]

CSG Regions  (1)

CSGRegion in 2D:

Wolfram Language code: CSGRegion["Difference", {Disk[], Disk[{1 / 2, 1 / 2}]}]
Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: CSGRegion["Difference", {Cube[2], Cylinder[{{1, 1, 1}, {1, -1, 1}}]}]
Wolfram Language code: BoundedRegionQ[%]

Subdivision Regions  (1)

SubdivisionRegion in 2D:

Wolfram Language code: SubdivisionRegion[Rectangle[]]
Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: SubdivisionRegion[Tetrahedron[]]
Wolfram Language code: BoundedRegionQ[%]

Applications  (2)

Create a definition that only applies to bounded regions:

Wolfram Language code: f[br_ ? BoundedRegionQ] := RegionBounds[br]
Wolfram Language code: f /@ {Disk[], InfiniteLine[{0, 0}, {1, 1}]}

Find an enclosing Sphere for a region:

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {0, 0, 3}}, 1];

Compute bounds:

Wolfram Language code: bounds = RegionBounds[ℛ];
Wolfram Language code: {min, max} = Transpose[bounds];
Wolfram Language code: c = Mean /@ bounds;
Wolfram Language code: r = EuclideanDistance[min, max] / 2;

Compute enclosing sphere:

Wolfram Language code: enclosingSphere = Sphere[c, r];

Visualize it:

Wolfram Language code: Show[Graphics3D[{ℛ, Opacity[0.2, Yellow], enclosingSphere}], Boxed -> False]

Properties & Relations  (5)

RegionIntersection is bounded if at least one region is BoundedRegionQ:

Wolfram Language code: r1 = HalfPlane[{{0, 0}, {1, 0}}, {0, 1}]; r2 = Circle[{0, 0}, 1]; ℛ = RegionIntersection[r1, r2];
Wolfram Language code: {Graphics[{LightBlue, r1, Orange, r2}], DiscretizeRegion[ℛ]}

Since there is one bounded region, the intersection is bounded:

Wolfram Language code: BoundedRegionQ /@ {r1, r2, ℛ}

TransformedRegion will be bounded if the regions and transformation are bounded:

Wolfram Language code: ℛ = Rectangle[]; 𝒯 = TransformedRegion[ℛ, RotationTransform[-π / 3]];

Since the transformation is bounded, the resulting region is bounded:

Wolfram Language code: {BoundedRegionQ[ℛ], BoundedRegionQ[𝒯]}
Wolfram Language code: {Region[ℛ], Region[𝒯]}

RegionBounds finds a bounding box that includes the region:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = InfiniteLine[{{0, 0}, {1, 1}}];
Wolfram Language code: {Region[Subscript[ℛ, 1]], Region[Subscript[ℛ, 2]]}

The bounds are finite for a bounded region:

Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 1]], RegionBounds[Subscript[ℛ, 1]]}

The bounds are infinite for an unbounded region:

Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 2]], RegionBounds[Subscript[ℛ, 2]]}

The RegionMeasure of a bounded region is finite:

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1];
Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 1]], RegionMeasure[Subscript[ℛ, 1]]}

The RegionMeasure of an unbounded region is infinite:

Wolfram Language code: Subscript[ℛ, 2] = HalfPlane[{{0, 0}, {1, 0}}, {0, 1}];
Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 2]], RegionMeasure[Subscript[ℛ, 2]]}

The RegionCentroid of a bounded region is finite:

Wolfram Language code: Subscript[ℛ, 1] = Line[{{0, 0}, {1, 1}}];
Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 1]], RegionCentroid[Subscript[ℛ, 1]]}

The RegionCentroid of an unbounded region is Indeterminate:

Wolfram Language code: Subscript[ℛ, 2] = InfiniteLine[{{0, 0}, {1, 1}}];
Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 2]], RegionCentroid[Subscript[ℛ, 2]]}
Wolfram Research (2014), BoundedRegionQ, Wolfram Language function, https://reference.wolfram.com/language/ref/BoundedRegionQ.html.

Text

Wolfram Research (2014), BoundedRegionQ, Wolfram Language function, https://reference.wolfram.com/language/ref/BoundedRegionQ.html.

CMS

Wolfram Language. 2014. "BoundedRegionQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BoundedRegionQ.html.

APA

Wolfram Language. (2014). BoundedRegionQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BoundedRegionQ.html

BibTeX

@misc{reference.wolfram_2026_boundedregionq, author="Wolfram Research", title="{BoundedRegionQ}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/BoundedRegionQ.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_boundedregionq, organization={Wolfram Research}, title={BoundedRegionQ}, year={2014}, url={https://reference.wolfram.com/language/ref/BoundedRegionQ.html}, note=[Accessed: 13-June-2026]}