WOLFRAM

Wolfram Language & System Documentation Center

CarlsonRE[x,y]

gives the Carlson's elliptic integral TemplateBox[{x, y}, CarlsonRE].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Differentiation and Integration  
Functional Representation  
Function Identities and Simplifications  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

CarlsonRE

CarlsonRE[x,y]

gives the Carlson's elliptic integral TemplateBox[{x, y}, CarlsonRE].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For non-negative arguments, TemplateBox[{x, y}, CarlsonRE]=1/piint_0^infty(t+x)^(-1/2)(t+y)^(-1/2)sqrt(t)( x/(t+x)+y/(t+y))dt.
  • CarlsonRE[x,y] has a branch cut discontinuity at .
  • For certain arguments, CarlsonRE automatically evaluates to exact values.
  • CarlsonRE can be evaluated to arbitrary numerical precision.
  • CarlsonRE automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: CarlsonRE[3., 5.]

Plot the function:

Wolfram Language code: Plot3D[CarlsonRE[x, y], {x, 0, 3}, {y, 0, 3}]

CarlsonRE is related to Legendre's complete elliptic integral of the second kind:

Wolfram Language code: (Pi/2)CarlsonRE[1, 1 - m] /. m -> 0.75
Wolfram Language code: EllipticE[0.75]

Scope  (12)

Numerical Evaluation  (5)

Evaluate numerically:

Wolfram Language code: CarlsonRE[1.0, 1 / GoldenRatio]

Evaluate to high precision:

Wolfram Language code: N[CarlsonRE[2, 7], 50]

Precision of the output tracks the precision of the input:

Wolfram Language code: CarlsonRE[2, 7.67890123456789012345]
Wolfram Language code: CarlsonRE[2, 7.678901234567890123456789012345]

Evaluate for complex arguments:

Wolfram Language code: CarlsonRE[2. + 0.5 I, 2. - 0.5I]

Evaluate efficiently at high precision:

Wolfram Language code: Timing[CarlsonRE[11, 3`500]]
Wolfram Language code: Timing[Precision[CarlsonRE[11, 3`100000]]]

CarlsonRE threads elementwise over lists:

Wolfram Language code: CarlsonRE[{1, 2, 3, 4, 5}, {5., 4., 3., 2., 1.}]

Specific Values  (1)

Simple exact values are generated automatically:

Wolfram Language code: CarlsonRE[x, x]
Wolfram Language code: CarlsonRE[x, 0]

Differentiation and Integration  (2)

Derivative with respect to :

Wolfram Language code: D[CarlsonRE[x, y], x]

Derivative with respect to :

Wolfram Language code: D[CarlsonRE[x, y], y]

Indefinite integral with respect to :

Wolfram Language code: Integrate[CarlsonRE[x, y], x]

Indefinite integral with respect to :

Wolfram Language code: Integrate[CarlsonRE[x, y], y]

Functional Representation  (1)

TraditionalForm formatting:

Wolfram Language code: CarlsonRE[x, y]//TraditionalForm

Function Identities and Simplifications  (3)

CarlsonRE satisfies the Euler–Poisson partial differential equation:

Wolfram Language code: (x - y)Subscript[∂, x⁣y]CarlsonRE[x, y] + (1/2) Subscript[∂, y]CarlsonRE[x, y] - (1/2)Subscript[∂, x]CarlsonRE[x, y] == 0//FunctionExpand//FullSimplify

CarlsonRE satisfies Euler's homogeneity relation:

Wolfram Language code: x Subscript[∂, x]CarlsonRE[x, y] + y Subscript[∂, y]CarlsonRE[x, y] == (1/2) CarlsonRE[x, y]//FunctionExpand//FullSimplify

A partial differential equation satisfied by CarlsonRE:

Wolfram Language code: Subscript[∂, x]CarlsonRE[x, y] + Subscript[∂, y]CarlsonRE[x, y] == (1/2) CarlsonRK[x, y]//FunctionExpand//FullSimplify

Applications  (3)

Total arc length of an ellipse:

Wolfram Language code: With[{a = Sqrt[2], b = 1}, N[2π CarlsonRE[a^2, b^2], 20]]

Compare with the result of ArcLength:

Wolfram Language code: With[{a = Sqrt[2], b = 1}, ArcLength[{a Cos[t], b Sin[t]}, {t, 0, 2π}, WorkingPrecision -> 20]]

Expectation value of the square root of a quadratic form, relative to a normal distribution:

Wolfram Language code: MatrixForm[mat = HilbertMatrix[2]]
Wolfram Language code: NExpectation[Sqrt[{u, v}.mat.{u, v} / 2], {u, v}BinormalDistribution[0]]//Quiet

Compare with the closed-form result in terms of CarlsonRE:

Wolfram Language code: N[Gamma[(3/2)](CarlsonRE@@Eigenvalues[mat]), 25]

Visualize the intersection of a cylinder and a ball:

Wolfram Language code: R = 1 / 6;r = 5 / 9;b = 5 / 11; cyl = Cylinder[{{0, 0, 0}, {0, 0, 2r}}, R]; ball = Ball[{b, 0, r}, r];
Wolfram Language code: Show@{ Graphics3D[{Opacity[1 / 2], cyl, ball}], Region[RegionIntersection[cyl, ball], PlotTheme -> "Web"]}

Volume of cylinder-ball intersection expressed in terms of Carlson integrals:

Wolfram Language code: N[(2π/9 )(2R(3 R (2 r^2 - R^2) - b (b^2 - 4 r^2 + 5 b R + 7 R^2) + (3 r^4/b - R))CarlsonRK[(b - r + R) (b + r + R), 4b R] + (b^2 - 4 r^2 + 7 R^2)CarlsonRE[(b - r + R) (b + r + R), 4b R] + 6b R r^4(b + r - R) (b + R) (b - r - R)CarlsonRM[(b - R)^2 (b - r + R) (b + r + R), 4 b R(b - R)^2, 4 b R r^2]), 20]

Compare with the result of Volume:

Wolfram Language code: Volume[RegionIntersection[cyl, ball], WorkingPrecision -> 20]

Properties & Relations  (2)

CarlsonRE is invariant under a permutation of its arguments:

Wolfram Language code: CarlsonRE[x, y] == CarlsonRE[y, x]

CarlsonRE and CarlsonRK satisfy Legendre's relation:

Wolfram Language code: CarlsonRE[y - x, y]CarlsonRK[x, y] + CarlsonRE[x, y]CarlsonRK[y - x, y] - y CarlsonRK[x, y]CarlsonRK[y - x, y] == (2/π) /. {{x -> 5`50, y -> 7`50}, {x -> 5`50, y -> 3`50}}
Wolfram Research (2021), CarlsonRE, Wolfram Language function, https://reference.wolfram.com/language/ref/CarlsonRE.html.

Text

Wolfram Research (2021), CarlsonRE, Wolfram Language function, https://reference.wolfram.com/language/ref/CarlsonRE.html.

CMS

Wolfram Language. 2021. "CarlsonRE." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CarlsonRE.html.

APA

Wolfram Language. (2021). CarlsonRE. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarlsonRE.html

BibTeX

@misc{reference.wolfram_2026_carlsonre, author="Wolfram Research", title="{CarlsonRE}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRE.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonre, organization={Wolfram Research}, title={CarlsonRE}, year={2021}, url={https://reference.wolfram.com/language/ref/CarlsonRE.html}, note=[Accessed: 12-June-2026]}