WOLFRAM

Wolfram Language & System Documentation Center

CompositeQ[n]

yields True if n is a composite number, and yields False otherwise.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
GaussianIntegers  
Applications  
Basic Applications  
Number Theory  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

CompositeQ

CompositeQ[n]

yields True if n is a composite number, and yields False otherwise.

Details and Options

  • CompositeQ is typically used to test whether an integer is a composite number.
  • A composite number is a positive number that is the product of two integers other than 1.
  • CompositeQ[n] returns False unless n is manifestly a composite number.
  • For negative integer n, CompositeQ[n] is effectively equivalent to CompositeQ[-n].
  • With the setting GaussianIntegers->True, CompositeQ determines whether a number is a composite number over Gaussian integers.
  • CompositeQ[m+In] automatically works over Gaussian integers.

Examples

open all close all

Basic Examples  (2)

Test whether a number is composite:

Wolfram Language code: CompositeQ[4]

The number is not composite:

Wolfram Language code: CompositeQ[13]

Scope  (4)

CompositeQ works over integers:

Wolfram Language code: CompositeQ[4]

Gaussian integers:

Wolfram Language code: CompositeQ[3 + I]
Wolfram Language code: CompositeQ[5, GaussianIntegers -> True]

Test for large integers:

Wolfram Language code: CompositeQ[10 ^ 3000 + 1]

CompositeQ threads over lists:

Wolfram Language code: CompositeQ[{1, 2, 3, 4, 5, 6}]

Options  (1)

GaussianIntegers  (1)

Test whether is composite over integers:

Wolfram Language code: CompositeQ[5]

Gaussian integers:

Wolfram Language code: CompositeQ[5, GaussianIntegers -> True]

Applications  (9)

Basic Applications  (3)

Highlight composite numbers:

Wolfram Language code: Multicolumn[If[CompositeQ[#], Style[#, Red, Bold], #]& /@ Range[100], 10, ...]

Generate the composite number:

Wolfram Language code: composite[n_] := FixedPoint[n + PrimePi[#] + 1&, n];
Wolfram Language code: Table[composite[n], {n, 100}]
Wolfram Language code: AllTrue[%, CompositeQ]

Generate random composite numbers:

Wolfram Language code: randomComposite[n_, m_ : 1] := composite[RandomInteger[{1, n}, m]];
Wolfram Language code: randomComposite[100, 10]
Wolfram Language code: AllTrue[%, CompositeQ]

The distribution of Gaussian composite numbers:

Wolfram Language code: ArrayPlot[Boole[Table[CompositeQ[a + b I, GaussianIntegers -> True], {a, 100}, {b, 100}]]]

Number Theory  (6)

Recognize Sierpiński numbers k where is always composite:

Wolfram Language code: k = 78557; AllTrue[Table[CompositeQ[k * 2 ^ n + 1], {n, 1, 10000}], TrueQ]

Recognize powerful numbers n whose prime factors are all repeated:

Wolfram Language code: powQ[n_] := AllTrue[Part[FactorInteger[n], All, 2], # > 1&];
Wolfram Language code: powQ[2 ^ 2 * 3 ^ 4]

All perfect powers are powerful numbers:

Wolfram Language code: powQ[64]

Recognize base b pseudoprimes, composite numbers n such that :

Wolfram Language code: bprimeQ[b_, n_] := PowerMod[b, n - 1, n] == 1 && CompositeQ[n];

Find all base pseudoprimes below :

Wolfram Language code: Select[Range[1000], bprimeQ[2, #]&]

Find all base pseudoprimes below :

Wolfram Language code: Select[Range[1000], bprimeQ[5, #]&]

Find large composite numbers of the form :

Wolfram Language code: Select[Table[2 ^ 2 ^ n + 1, {n, 10}], CompositeQ]

The distribution of composite numbers over integers:

Wolfram Language code: data = Select[Range[100], CompositeQ];
Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Plot the distribution:

Wolfram Language code: DiscretePlot[Evaluate[CDF[𝒟, x]], {x, 1, 100}, ExtentSize -> Right]

The distribution of composite numbers over the Gaussian integers:

Wolfram Language code: data = {Re[#], Im[#]}& /@ Select[Flatten[Table[a + b I, {a, 500}, {b, 500}]], CompositeQ];
Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Plot the distribution:

Wolfram Language code: DiscretePlot3D[Evaluate[CDF[𝒟, {x, y}]], {x, 1, 5}, {y, 1, 5}, ExtentSize -> Right]

Properties & Relations  (6)

Primes represents the domain of all prime numbers:

Wolfram Language code: Element[8, Primes]

No composite number belongs to Primes:

Wolfram Language code: CompositeQ[8]

PrimeQ gives False for all composite numbers:

Wolfram Language code: CompositeQ[12]
Wolfram Language code: PrimeQ[12]

CompositeQ gives False for all primes:

Wolfram Language code: PrimeQ[67]
Wolfram Language code: CompositeQ[67]

Composite numbers cannot be a MersennePrimeExponent:

Wolfram Language code: CompositeQ[28]
Wolfram Language code: MersennePrimeExponentQ[28]

Composite numbers have at least two prime factors including multiplicities:

Wolfram Language code: CompositeQ[60]
Wolfram Language code: FactorInteger[60]

Composite numbers that are the power of a prime number have exactly divisors:

Wolfram Language code: CompositeQ[5 ^ 11]
Wolfram Language code: Length[Divisors[5 ^ 11]]

Neat Examples  (2)

Plot composite numbers that are the sum of three squares:

Wolfram Language code: ArrayMesh[Boole[Table[CompositeQ[a ^ 2 + b ^ 2 + c ^ 2], {a, 10}, {b, 10}, {c, 10}]]]

Plot the Ulam spiral where numbers are colored based on their compositeness:

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[ulam[101]Boole[CompositeQ[ulam[101]]], ColorFunction -> "Rainbow", ColorRules -> {0 -> White}]
Wolfram Research (2014), CompositeQ, Wolfram Language function, https://reference.wolfram.com/language/ref/CompositeQ.html.

Text

Wolfram Research (2014), CompositeQ, Wolfram Language function, https://reference.wolfram.com/language/ref/CompositeQ.html.

CMS

Wolfram Language. 2014. "CompositeQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CompositeQ.html.

APA

Wolfram Language. (2014). CompositeQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CompositeQ.html

BibTeX

@misc{reference.wolfram_2026_compositeq, author="Wolfram Research", title="{CompositeQ}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/CompositeQ.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_compositeq, organization={Wolfram Research}, title={CompositeQ}, year={2014}, url={https://reference.wolfram.com/language/ref/CompositeQ.html}, note=[Accessed: 12-June-2026]}