WOLFRAM

Wolfram Language & System Documentation Center

ControllabilityMatrix[ssm]

gives the controllability matrix of the state-space model ssm.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

ControllabilityMatrix

ControllabilityMatrix[ssm]

gives the controllability matrix of the state-space model ssm.

Details

  • For a standard state-space model with state equations:
  • continuous-time system
    discrete-time system
  • The controllability matrix is computed as , where is the dimension of .
  • For a descriptor state-space model with state equations:
  • continuous-time system
    discrete-time system
  • The slow and fast subsystems can be decoupled as described in KroneckerModelDecomposition:
  • slow subsystem
    fast subsystem
  • ControllabilityMatrix returns a pair of matrices {q1,q2}, based on the decoupled slow and fast subsystems. The matrices q1 and q2 are defined as follows, where is the dimension of , and is the nilpotency index of .
  • slow subsystem
    fast subsystem
  • The controllability matrices only exist for descriptor systems in which Det[λ e-a]≠0 for some λ.

Examples

open all close all

Basic Examples  (2)

The controllability matrix of a state-space model:

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}, {Subscript[b, 3]}}, {{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}}, {{Subscript[d, 1]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

The controllability multi-input state-space model:

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{-1, 1, 0}, {0, -1, 1}, {0, 0, -1}}, {{1, 0}, {1, 0}, {0, 1}}, {{1, 0, 0}}, {{0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

Scope  (5)

The controllability matrix of a symbolic single-input system:

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{Subscript[a, 1], Subscript[a, 2]}, {Subscript[a, 3], Subscript[a, 4]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}}, {{Subscript[c, 1], Subscript[c, 2]}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

The controllability matrix of a two-input system has twice as many columns:

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{Subscript[a, 1], Subscript[a, 2]}, {Subscript[a, 3], Subscript[a, 4]}}, {{Subscript[b, 1], 0}, {0, Subscript[b, 2]}}, {{Subscript[c, 1], Subscript[c, 2]}}, {{0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

The controllability matrix of an uncontrollable single-input system:

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{Subscript[λ, 1], 0, 0}, {0, Subscript[λ, 2], 0}, {0, 0, Subscript[λ, 3]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

The controllability matrix of a diagonal multiple-input system:

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{Subscript[λ, 1], 0, 0}, {0, Subscript[λ, 2], 0}, {0, 0, Subscript[λ, 3]}}, {{Subscript[b, 1], 0, 0}, {0, Subscript[b, 2], 0}, {0, 0, Subscript[b, 3]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

The controllability matrix of a third-order system:

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{1, 1, 1}, {-2, 1, 1}, {0, 1, 2}}, {{0}, {1}, {1}}, {{1, 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

A singular descriptor system returns two matrices:

Wolfram Language code: cm = ControllabilityMatrix[StateSpaceModel[{{{1, 0, 0, 0, 0}, {0, 1, 0, 0, 0}, {0, 0, 1, 0, 0}, {0, 0, 0, 1, 0}, {0, 0, 0, 0, -5}}, {{0}, {0}, {0}, {1}, {1}}, {{-1, 17, -139, 803, 4096}}, {{0}}, {{0, 1, 0, 0, 0}, {0, 0, 1, 0, 0}, {0, 0, 0, 1, 0}, {0, 0, 0, 0, 0}, {0, 0, 0, 0, 1}}}, SamplingPeriod -> None, SystemsModelLabels -> None]];
Wolfram Language code: MatrixForm /@ cm

Properties & Relations  (8)

The computation depends only on the state and input matrices:

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{a[1, 1], a[1, 2]}, {a[2, 1], a[2, 2]}}, {{b[1, 1]}, {b[2, 1]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

A system is controllable if and only if its controllability matrix has full rank:

Wolfram Language code: ssm = StateSpaceModel[{{{1, -1, 1}, {-2, 1, 3}, {0, 2, 1}}, {{1}, {-1}, {1}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: MatrixRank[ControllabilityMatrix[ssm]] ControllableModelQ[ssm]

This system is not controllable, but is output-controllable:

Wolfram Language code: ssm = StateSpaceModel[{{{-3, 1, 0}, {-5, 0, 1}, {-3, 0, 0}}, {{1}, {2}, {3}}, {{1, 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]
Wolfram Language code: MatrixRank[ControllabilityMatrix[ssm]] ControllableModelQ[ssm]
Wolfram Language code: OutputControllableModelQ[ssm]

This system is controllable, but is not output-controllable:

Wolfram Language code: ssm = StateSpaceModel[{{{-2.5, -1, -0.5}, {-0.5, -2., 0.5}, {0.5, 1., -1.5}}, {{1.}, {1.}, {-3.}}, {{1, 0, -1}, {-1, 1, 0}, {3, -2, -1}}, {{0}, {0}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: MatrixRank[ControllabilityMatrix[ssm]] ControllableModelQ[ssm]
Wolfram Language code: OutputControllableModelQ[ssm]

The controllability matrix of a discrete-time system does not depend on the sampling period:

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{1, 1, 1}, {-2, 1, 1}, {0, 1, 2}}, {{0}, {1}, {1}}, {{1, 0, 0}}, {{0}}}, SamplingPeriod -> τ, SystemsModelLabels -> None]]//MatrixForm

For descriptor systems, the slow and fast system matrices need to be full rank for controllability:

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1}, {2}, {0}}, {{1, 1, 1}}, {{0}}, {{1, 0, 0}, {0, 0, 1}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]
Wolfram Language code: {qs, qf} = ControllabilityMatrix[ssm]
Wolfram Language code: ControllableModelQ[ssm]

Controllability of the slow subsystem is determined by the first matrix:

Wolfram Language code: ControllableModelQ[{ssm, "Slow"}] MatrixRank[qs] === Length[qs]

For nonsingular descriptor systems, the fast system matrix is empty:

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}, {{e}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

Each matrix is associated with a subsystem from the Kronecker decomposition:

Wolfram Language code: ssm = StateSpaceModel[{{{0, -1, 0, 0}, {-1, 0, 0, 0}, {10, 0, 0, -1}, {0, 1, 1, 1}}, {{0}, {0}, {0}, {-1}}, {{0, 0, 1, 0}}, {{0}}, {{-1, 0, 0, 0}, {0, 0, -1, 0}, {0, 0, 0, 0}, {0, 0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]; kssm = Last[KroneckerModelDecomposition[ssm]]

The controllability matrices match those for the original system:

Wolfram Language code: slowssm = SystemsModelExtract[kssm, All, All, {1, 2}]; fastssm = SystemsModelExtract[kssm, All, All, {3, 4}];
Wolfram Language code: Simplify[ControllabilityMatrix /@ {slowssm, fastssm}] Simplify[ControllabilityMatrix[ssm]]
Wolfram Research (2010), ControllabilityMatrix, Wolfram Language function, https://reference.wolfram.com/language/ref/ControllabilityMatrix.html (updated 2012).

Text

Wolfram Research (2010), ControllabilityMatrix, Wolfram Language function, https://reference.wolfram.com/language/ref/ControllabilityMatrix.html (updated 2012).

CMS

Wolfram Language. 2010. "ControllabilityMatrix." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2012. https://reference.wolfram.com/language/ref/ControllabilityMatrix.html.

APA

Wolfram Language. (2010). ControllabilityMatrix. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ControllabilityMatrix.html

BibTeX

@misc{reference.wolfram_2026_controllabilitymatrix, author="Wolfram Research", title="{ControllabilityMatrix}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/ControllabilityMatrix.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_controllabilitymatrix, organization={Wolfram Research}, title={ControllabilityMatrix}, year={2012}, url={https://reference.wolfram.com/language/ref/ControllabilityMatrix.html}, note=[Accessed: 13-June-2026]}