WOLFRAM

Wolfram Language & System Documentation Center

ConvectionPDETerm[vars,β]

represents a convection term with convection coefficient and model variables vars.

ConvectionPDETerm[vars,β,pars]

uses model parameters pars.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Possible Issues  
See Also
Related Guides
History
Cite this Page

ConvectionPDETerm

ConvectionPDETerm[vars,β]

represents a convection term with convection coefficient and model variables vars.

ConvectionPDETerm[vars,β,pars]

uses model parameters pars.

Details

  • Convection terms are used in a number of domains such as thermodynamics, acoustics, structural mechanics and fluid dynamics.
  • Convection is also known as advection.
  • Convection with a convection coefficient is the process of transport of the dependent variable due to a bulk movement:
  • ConvectionPDETerm returns a differential operators term to be used as a part of partial differential equations:
  • ConvectionPDETerm can be used to model convection equations with dependent variable , independent variables and time variable .
  • Stationary model variables vars are vars={u[x1,…,xn],{x1,…,xn}}.
  • Time-dependent model variables vars are vars={u[t,x1,…,xn],{x1,…,xn}} or vars={u[t,x1,…,xn],t,{x1,…,xn}}.
  • The convection term in context with other PDE terms is given by:
  • During convection, the medium in which the convection happens is the transport mechanism, in contrast to diffusion where the medium remains stationary.
  • The convection coefficient has the following form:
  • {β1,…,βn}(beta_(1),...,beta_(n))vector
  • For a system of PDEs with dependent variables {u1,…,um}, the convection represents:
  • The convection term in context systems of PDE terms:
  • The convection coefficient is a tensor of rank 3 of the form where each submatrix is a vector of length that is specified in the same way as for a single dependent variable.
  • A symbolic convection coefficient can be specified through a VectorSymbol. »
  • The conservative convection coefficient can depend on time, space, parameters and the dependent variables.
  • The following parameters pars can be given:
  • parameterdefaultsymbol
    "CoordinateChart""Cartesian"
  • The coefficient does not affect the meaning of NeumannValue.
  • All quantities that do not explicitly depend on the independent variables given are taken to have zero partial derivative.
  • The ConservativeConvectionPDETerm is closely related.

Examples

open all close all

Basic Examples  (4)

Define a time-independent convection term:

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, {2}]

Define a time-dependent convection term:

Wolfram Language code: ConvectionPDETerm[{u[t, x], t, {x}}, {2}]

Define a 2D stationary convection term:

Wolfram Language code: ConvectionPDETerm[{u[x, y], {x, y}}, {1, 0}]

Solve a convection diffusion equation build with basic terms:

Wolfram Language code: vars = {u[x, y], {x, y}}; NDSolveValue[{DiffusionPDETerm[vars, 1] + ConvectionPDETerm[vars, {2, 0}] == SourcePDETerm[vars, -1], DirichletCondition[u[x, y] == 0, x == 0 || y == 0]}, u[x, y], {x, y}∈Rectangle[]]

Visualize the result:

Wolfram Language code: ContourPlot[%, {x, y}∈Rectangle[]]

Scope  (10)

Define a symbolic convection term:

Wolfram Language code: ConvectionPDETerm[{u[t, x], t, {x}}, {a}]

Define a stationary dependent convection term with a symbolic vector convection coefficient:

Wolfram Language code: β = VectorSymbol["β", {1}]; ConvectionPDETerm[{u[x], {x}}, β]

Activate the term:

Wolfram Language code: %//Activate

Define a stationary dependent convection term with a symbolic vector convection coefficient replaced:

Wolfram Language code: β = VectorSymbol["β", {1}]; ConvectionPDETerm[{u[x], {x}}, β, <|β -> {1}|>]

Define a time-dependent convection term with a symbolic vector convection coefficient replaced:

Wolfram Language code: β = VectorSymbol["β", {1}]; ConvectionPDETerm[{u[t, x], t, {x}}, β, <|β -> {1}|>]

Define a 1D axisymmetric time-independent convection term:

Wolfram Language code: ConvectionPDETerm[{u[r], {r}}, {2}, <|"RegionSymmetry" -> "Axisymmetric"|>]

Apply Activate to the term:

Wolfram Language code: Activate[%]

Define a time-independent 2D convection term:

Wolfram Language code: ConvectionPDETerm[{u[x, y], {x, y}}, {2, 1}]

Define a nonlinear time-independent 2D convection term:

Wolfram Language code: ConvectionPDETerm[{u[x, y], {x, y}}, {2, u[x, y] ^ 2}]

Define a nonlinear time-dependent 2D convection term:

Wolfram Language code: ConvectionPDETerm[{u[t, x, y], t, {x, y}}, {2, u[x, y] ^ 2}]

Define a convection term with multiple dependent variables:

Wolfram Language code: ConvectionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, {{{1, 0}, {0, 2}}, {{0, 0}, {0, 1}}}]

Define a Stokes-flow model:

Wolfram Language code: stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

Set up a symbolic equation:

Wolfram Language code: stokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, μ] == {0, 0, 0}

Applications  (3)

Use DiffusionPDETerm to model species diffusion under a dam. Set up the region:

Wolfram Language code: Subscript[Ω, dam] = Rectangle[{6, 3}, {12, 18}]; Subscript[Ω, sediment] = RegionDifference[Rectangle[{0, 0}, {18, 6}], Subscript[Ω, dam]];

Set up the model:

Wolfram Language code: model = DiffusionPDETerm[{u[x, y], {x, y}}, 10 ^ -4]

Solve the equation:

Wolfram Language code: solution = NDSolveValue[{model == 0, DirichletCondition[u[x, y] == 16, x ≤ 6 && y == 6], DirichletCondition[u[x, y] == 8, x ≥ 12 && y == 6]}, u, {x, y}∈Subscript[Ω, sediment]]

Compute the flux:

Wolfram Language code: flux = model /. Inactive[Div][flux_, _] :> Activate[flux]

Visualize the result:

Wolfram Language code: Show[ ..., VectorPlot[Evaluate[flux /. u -> solution], {x, 0, 18}, {y, 0, 6}, Rule[...]] ]//Quiet

Find the concentration of species under the dam. Construct the model:

Wolfram Language code: op = DiffusionPDETerm[{c[x, y], {x, y}}, 1] + ConvectionPDETerm[{c[x, y], {x, y}}, flux /. u -> solution] + 2 * 10 ^ -5c[x, y];

Solve the equation:

Wolfram Language code: concentration = NDSolveValue[{op == 0, DirichletCondition[c[x, y] == 100, x ≤ 6 && y == 6], DirichletCondition[c[x, y] == 50, x ≥ 12 && y == 6] }, c, {x, y}∈Subscript[Ω, sediment]]

Visualize the species concentration:

Wolfram Language code: Show[ ..., ContourPlot[concentration[x, y], {x, y}∈concentration["ElementMesh"], ...], VectorPlot[Evaluate[flux /. u -> solution], {x, 0, 18}, {y, 0, 6}, Rule[...]] ]//Quiet

Define a Stokes-flow model:

Wolfram Language code: stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

Set up the equation:

Wolfram Language code: eqn = stokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, 1] == {0, 0, 0}

Define a narrowing region:

Wolfram Language code: Ω = RegionUnion[Rectangle[{0, 0}, {1, 1 / 2}], Rectangle[{1, 1 / 10}, {2, 2 / 5}]];

Set up a boundary condition:

Wolfram Language code: bcs = {DirichletCondition[ {u[x, y] == 4 * 0.3 * y * (0.5 - y) / (0.41) ^ 2, v[x, y] == 0.}, x == 0.], DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, 0 < x < 2], DirichletCondition[p[x, y] == 0., x == 2]};

Solve the equation:

Wolfram Language code: {xVel, yVel, pressure} = NDSolveValue[{eqn, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.0005}}];

Visualize the solution:

Wolfram Language code: VectorPlot[{xVel[x, y], yVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamPoints -> 6, StreamColorFunction -> "TemperatureMap", StreamColorFunctionScaling -> False]//Quiet

Extend a Stokes-flow model to a Navier–Stokes flow model. Define a Stokes-flow model:

Wolfram Language code: stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

Define a Navier–Stokes flow model:

Wolfram Language code: navierStokesModel[vars_, μ_, ρ_] := stokesModel[vars, μ] + ConvectionPDETerm[vars, {{ρ vars[[1, {1, 2}]], 0, 0}, {0, ρ vars[[1, {1, 2}]], 0}, {0, 0, 0}}]

Set up the equation:

Wolfram Language code: eqn = navierStokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, 1, 10 ^ -3] == {0, 0, 0}

Define a region:

Wolfram Language code: Ω = Rectangle[{0, 0}, {1, 1}];

Set up a boundary condition:

Wolfram Language code: bcs = {DirichletCondition[ {u[x, y] == 1, v[x, y] == 0}, y == 1], DirichletCondition[{u[x, y] == 0, v[x, y] == 0}, y < 1], DirichletCondition[p[x, y] == 0, x == 0 && y == 1]};

Solve the equation:

Wolfram Language code: {xVel, yVel, pressure} = NDSolveValue[{eqn, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.0005}}];

Visualize the solution:

Wolfram Language code: VectorPlot[{xVel[x, y], yVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamPoints -> 6, StreamColorFunction -> "TemperatureMap", StreamColorFunctionScaling -> False]

Possible Issues  (2)

A convection term with a 0-flow velocity field evaluates to 0:

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, 0]
Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, {0}]

A symbolic convection coefficient needs to be of sufficient length:

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, v]

The way to specify the symbolic vector convection coefficient is through a VectorSymbol:

Wolfram Language code: vs = VectorSymbol["v", {1}]; ConvectionPDETerm[{u[x], {x}}, vs]

Activate the term:

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, vs]//Activate

Substitute a VectorSymbol with an actual value:

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, vs, <|vs -> {1}|>]

An alternative is to specify the symbolic convection coefficient as a vector:

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, {v}, <|v -> 1|>]
Wolfram Research (2020), ConvectionPDETerm, Wolfram Language function, https://reference.wolfram.com/language/ref/ConvectionPDETerm.html (updated 2026).

Text

Wolfram Research (2020), ConvectionPDETerm, Wolfram Language function, https://reference.wolfram.com/language/ref/ConvectionPDETerm.html (updated 2026).

CMS

Wolfram Language. 2020. "ConvectionPDETerm." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/ConvectionPDETerm.html.

APA

Wolfram Language. (2020). ConvectionPDETerm. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ConvectionPDETerm.html

BibTeX

@misc{reference.wolfram_2026_convectionpdeterm, author="Wolfram Research", title="{ConvectionPDETerm}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/ConvectionPDETerm.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_convectionpdeterm, organization={Wolfram Research}, title={ConvectionPDETerm}, year={2026}, url={https://reference.wolfram.com/language/ref/ConvectionPDETerm.html}, note=[Accessed: 13-June-2026]}