WOLFRAM

Wolfram Language & System Documentation Center

CoplanarPoints[{p1,p2,p3,p4,…,pn}]

tests whether the points p1,p2,p3,p4,…,pn are coplanar.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Basic Applications  
Geometry  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

CoplanarPoints

CoplanarPoints[{p1,p2,p3,p4,…,pn}]

tests whether the points p1,p2,p3,p4,…,pn are coplanar.

Details

  • CoplanarPoints is also known as linearly dependent.
  • Typically used to test whether a set of points lie on the same plane.
  • CoplanarPoints[{p1,p2,p3,p4,…,pn}] gives True if the points p4,…,pn are on the plane passing through the points p1, p2 and p3.
  • For coplanar points p1, p2, p3 and p4, the rank of the matrix {p2-p1,p3-p1,p4-p1} is less than or equal to 2.

Examples

open all close all

Basic Examples  (2)

The points {0,0,0}, {1,1,-2}, {-1,2,-1}, {3,-4,1} are coplanar:

Wolfram Language code: pts = {{0, 0, 0}, {1, 1, -2}, {-1, 2, -1}, {3, -4, 1}};
Wolfram Language code: CoplanarPoints[pts]

Plot the points:

Wolfram Language code: Graphics3D[{InfinitePlane[pts[[1 ;; 3]]], Red, Point[pts]}]

Find the equation of the plane containing the points {0,0,0}, {1,1,-2} and {-1,2,-1}:

Wolfram Language code: CoplanarPoints[{{0, 0, 0}, {1, 1, -2}, {-1, 2, -1}, {x, y, z}}]

Scope  (4)

CoplanarPoints works with two-dimensional points:

Wolfram Language code: CoplanarPoints[{{1, 2}, {3, 4}, {5, 6}}]

Three-dimensional points:

Wolfram Language code: CoplanarPoints[{{1, 2, 1}, {3, 4, 1}, {5, 6, 1}, {7, 8, 1}}]

n-dimensional points:

Wolfram Language code: CoplanarPoints[{{0, 0, 1, 1}, {1, 0, 1, 0}, {0, 1, 0, 1}, {0, 1, 1, 1}, {0, 0, 0, 1}}]

CoplanarPoints works with numerical coordinates:

Wolfram Language code: CoplanarPoints[{{1, 2}, {3, 4}, {5, 6}}]

Symbolic coordinates:

Wolfram Language code: CoplanarPoints[{{1, a, 1}, {a, 2, 1}, {1, 2, 1}, {a, b, c}}]

CoplanarPoints over a set of coordinates:

Wolfram Language code: CoplanarPoints[{{1, 2, 1}, {3, 4, 1}, {5, 6, 1}, {7, 8, 1}}]

List of points:

Wolfram Language code: CoplanarPoints[{Point[{b, 0, 1}], Point[{a, 1, 1}], Point[{a, 3, 1}], Point[{a, b, c}]}]

Multi-points:

Wolfram Language code: CoplanarPoints[Point[{{b, 0, 1}, {a, 1, 1}, {a, 3, 1}, {a, b, c}}]]

CoplanarPoints works for large sets:

Wolfram Language code: pts = RandomPoint[Polygon[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}}], 10 ^ 6];
Wolfram Language code: CoplanarPoints[pts]//AbsoluteTiming

Applications  (5)

Basic Applications  (4)

Find conditions for which two points lie on a plane passing through the origin:

Wolfram Language code: CoplanarPoints[{{0, 0, 0}, {0, 1, 0}, {a, 2, b}, {c, 3, d}}]

Explicit instances:

Wolfram Language code: {{a, 2, b}, {c, 3, d}} /. FindInstance[% && a ≠ 0, {a, b, c, d}, Reals, 3]

2D points lie on the same plane:

Wolfram Language code: CoplanarPoints[{{1, 2}, {3, 4}, {5, 6}}]
Wolfram Language code: CoplanarPoints[RandomPoint[Disk[], 5000]]
Wolfram Language code: CoplanarPoints[RandomReal[1, {5000, 2}]]

Find the equation of a plane containing a set of points:

Wolfram Language code: pts = {{0, 0, 0}, {1, 1, -2}, {-1, 2, -1}};
Wolfram Language code: CoplanarPoints[Append[pts, {x, y, z}]]

Draw coplanar points:

Wolfram Language code: pts = {{0, 0, 0}, {1, 0, 0}, {1, 1, 1}};
Wolfram Language code: CoplanarPoints[pts]
Wolfram Language code: Graphics3D[{InfinitePlane[pts], Red, PointSize[Large], Point[pts]}]

Geometry  (1)

A face of a polyhedron lies on a plane:

Wolfram Language code: poly = OuterPolyhedron[Polyhedron[{{-1/2, -1/2, -1/2}, {-1/2, -1/2, 1/2}, {-1/2, 1/2, -1/2}, {-1/2, 1/2, 1/2}, {1/2, -1/2, -1/2}, {1/2, -1/2, 1/2}, {1/2, 1/2, -1/2}, {1/2, 1/2, 1/2}}, {{8, 4, 2, 6}, {8, 6, 5, 7}, {8, 7, 3, 4}, {4, 3, 1, 2}, {1, 3, 7, 5}, {2, 1, 5, 6}}]];
Wolfram Language code: faces = poly[[2]]
Wolfram Language code: CoplanarPoints[PolyhedronCoordinates[poly][[#]]]& /@ faces

Properties & Relations  (5)

PositivelyOrientedPoints returns False for coplanar points:

Wolfram Language code: pts = {{0, 0, 0}, {1, 1, -2}, {-1, 2, -1}, {3, -4, 1}};
Wolfram Language code: {CoplanarPoints[pts], PositivelyOrientedPoints[pts]}

NegativelyOrientedPoints returns False for coplanar points:

Wolfram Language code: pts = {{0, 0, 0}, {1, 1, -2}, {-1, 2, -1}, {3, -4, 1}};
Wolfram Language code: {CoplanarPoints[pts], NegativelyOrientedPoints[pts]}

Collinear points are coplanar:

Wolfram Language code: pts = RandomPoint[Line[{{0, 0, 0}, {1, 1, 1}}], 5];
Wolfram Language code: {CollinearPoints[pts], CoplanarPoints[pts]}

Use RegionMember to test whether points are coplanar:

Wolfram Language code: RegionMember[Line[{{0, 0, 1}, {1, 1, 1}}], {2, 2, 1}]
Wolfram Language code: CoplanarPoints[{{0, 0, 1}, {1, 1, 1}, {2, 2, 1}}]

Use InfinitePlane to draw a graphics image:

Wolfram Language code: pts = {{0, 0, 0}, {1, 0, 0}, {1, 1, 1}};
Wolfram Language code: Graphics3D[{InfinitePlane[pts], Red, PointSize[Large], Point[pts]}]
Wolfram Research (2020), CoplanarPoints, Wolfram Language function, https://reference.wolfram.com/language/ref/CoplanarPoints.html.

Text

Wolfram Research (2020), CoplanarPoints, Wolfram Language function, https://reference.wolfram.com/language/ref/CoplanarPoints.html.

CMS

Wolfram Language. 2020. "CoplanarPoints." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CoplanarPoints.html.

APA

Wolfram Language. (2020). CoplanarPoints. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoplanarPoints.html

BibTeX

@misc{reference.wolfram_2026_coplanarpoints, author="Wolfram Research", title="{CoplanarPoints}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CoplanarPoints.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_coplanarpoints, organization={Wolfram Research}, title={CoplanarPoints}, year={2020}, url={https://reference.wolfram.com/language/ref/CoplanarPoints.html}, note=[Accessed: 12-June-2026]}