WOLFRAM

Wolfram Language & System Documentation Center

CosIntegral[z]

gives the cosine integral function TemplateBox[{z}, CosIntegral].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Function Identities and Simplifications  
Function Representations  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

CosIntegral

CosIntegral[z]

gives the cosine integral function TemplateBox[{z}, CosIntegral].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • TemplateBox[{z}, CosIntegral]=-int_z^inftycos(t)/tdt.
  • CosIntegral[z] has a branch cut discontinuity in the complex z plane running from -∞ to 0.
  • For certain special arguments, CosIntegral automatically evaluates to exact values.
  • CosIntegral can be evaluated to arbitrary numerical precision.
  • CosIntegral automatically threads over lists.
  • CosIntegral can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (6)

Evaluate numerically:

Wolfram Language code: CosIntegral[2.8]

Plot over a subset of the reals:

Wolfram Language code: Plot[CosIntegral[x], {x, 0, 20}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[CosIntegral[z ^ 2], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[CosIntegral[x], {x, 0, 10}]

Asymptotic expansion at Infinity:

Wolfram Language code: Series[CosIntegral[x], {x, ∞, 3}]//Normal

Asymptotic expansion at a singular point:

Wolfram Language code: Series[CosIntegral[x], {x, -1, 3}, Assumptions -> z > 0]//Normal

Scope  (37)

Numerical Evaluation  (6)

Evaluate numerically to high precision:

Wolfram Language code: N[CosIntegral[2], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: CosIntegral[2.0000000000000000000000000000000000000]

Evaluate for complex arguments:

Wolfram Language code: CosIntegral[2.5 + I]

Evaluate CosIntegral efficiently at high precision:

Wolfram Language code: CosIntegral[2`500]//Timing
Wolfram Language code: CosIntegral[2`10000];//Timing

CosIntegral threads elementwise over lists and matrices:

Wolfram Language code: CosIntegral[{1.2, 1.5, 1.8}]
Wolfram Language code: CosIntegral[(| | | | :- | :- | | 0 | u | | v | ∞ |) ]//MatrixForm

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: CosIntegral[Interval[{1.9, 2.1}]]
Wolfram Language code: CosIntegral[CenteredInterval[2, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: CosIntegral[Around[2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: CosIntegral[{{.2, 0}, {0, .2 }}]

Or compute the matrix CosIntegral function using MatrixFunction:

Wolfram Language code: MatrixFunction[CosIntegral, {{.2, 0}, {0, .2 }}]

Specific Values  (3)

Value at a fixed point:

Wolfram Language code: CosIntegral[0]

Values at infinity:

Wolfram Language code: CosIntegral[{-Infinity, Infinity, -I Infinity, I Infinity}]
Wolfram Language code: CosIntegral[ComplexInfinity]

Find a local maximum as a root of (dTemplateBox[{x}, CosIntegral])/(dx)=0:

Wolfram Language code: xmax = Solve[D[CosIntegral[x], x] == 0 && 0 < x < 2, x][[1, 1]]
Wolfram Language code: Plot[CosIntegral[x], {x, 0, 3π}, Epilog -> Style[Point[{xmax[[2]], CosIntegral[xmax[[2]]]}], PointSize[Large], Red]]

Visualization  (2)

Plot the CosIntegral function:

Wolfram Language code: Plot[CosIntegral[x], {x, 0, 4π}]

Plot the real part of TemplateBox[{z}, CosIntegral]:

Wolfram Language code: ComplexContourPlot[Re[CosIntegral[z]], {z, -3π - π I, 3π + π I}, Contours -> 24]

Plot the imaginary part of TemplateBox[{z}, CosIntegral]:

Wolfram Language code: ComplexContourPlot[Im[CosIntegral[z]], {z, -3π - π I, 3π + π I}, Contours -> 24]

Function Properties  (8)

CosIntegral is defined for all positive real values:

Wolfram Language code: FunctionDomain[CosIntegral[x], x]

Complex domain:

Wolfram Language code: FunctionDomain[CosIntegral[z], z, Complexes]

CosIntegral is not an analytic function:

Wolfram Language code: FunctionAnalytic[CosIntegral[x], x]

Nor is it meromorphic:

Wolfram Language code: FunctionMeromorphic[CosIntegral[x], x]

CosIntegral is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[CosIntegral[x], x, PositiveReals]

CosIntegral is not injective:

Wolfram Language code: FunctionInjective[CosIntegral[x], x]
Wolfram Language code: Plot[{CosIntegral[x], .3}, {x, 0, 10}]

CosIntegral is not surjective:

Wolfram Language code: FunctionSurjective[CosIntegral[x], x]
Wolfram Language code: Plot[{CosIntegral[x], 1}, {x, 0, 10}]

CosIntegral is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[{CosIntegral[x], x > 0}, x]

It has both singularity and discontinuity in (-∞,0]:

Wolfram Language code: FunctionSingularities[CosIntegral[x], x]
Wolfram Language code: FunctionDiscontinuities[CosIntegral[x], x]

CosIntegral is neither convex nor concave:

Wolfram Language code: FunctionConvexity[{CosIntegral[x], x > 0}, x]

Differentiation  (3)

First derivative:

Wolfram Language code: D[CosIntegral[x], x]

Higher derivatives:

Wolfram Language code: Table[D[CosIntegral[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, 0, 4π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Formula for the ^(th) derivative:

Wolfram Language code: D[CosIntegral[x], {x, n}]

Integration  (3)

Indefinite integral of CosIntegral:

Wolfram Language code: Integrate[CosIntegral[x], x]

Definite integral of CosIntegral over its entire real domain:

Wolfram Language code: Integrate[CosIntegral[x], {x, 0, Infinity}]

More integrals:

Wolfram Language code: Integrate[x CosIntegral[Sqrt[x]], x]
Wolfram Language code: Integrate[CosIntegral[x]Cos[x], x]
Wolfram Language code: Integrate[CosIntegral[x^a], x]

Series Expansions  (3)

Taylor expansion for CosIntegral around :

Wolfram Language code: Series[CosIntegral[x], {x, π, 5}]

Plots of the first three approximations for CosIntegral around :

Wolfram Language code: terms = Normal@Table[Series[CosIntegral[x], {x, π, m}], {m, 1, 3}]; Plot[{CosIntegral[x], terms}, {x, 1, 5}]

Find series expansion at infinity:

Wolfram Language code: Series[CosIntegral[x], {x, Infinity, 4}]//Normal

CosIntegral can be applied to power series:

Wolfram Language code: CosIntegral[1 + x + (x^2/2) + (x^3/9) + O[x]^4]

Function Identities and Simplifications  (4)

Use FullSimplify to simplify expressions containing the cosine integral:

Wolfram Language code: FullSimplify[MeijerG[{{}, {1}}, {{0, 0}, {(1/ 2)}}, (z^2/4)] - CosIntegral[z], z > 0]

Use FunctionExpand to express CosIntegral through other functions:

Wolfram Language code: FunctionExpand[CosIntegral[z] - CosIntegral[-z]]

Simplify expressions to CosIntegral:

Wolfram Language code: Log[z] - (1/2)(Gamma[0, -I z] + Gamma[0, I z] + Log[-I z] + Log[I z])//FullSimplify

Argument simplifications:

Wolfram Language code: CosIntegral[-z]//FunctionExpand
Wolfram Language code: CosIntegral[I z]//FunctionExpand
Wolfram Language code: CosIntegral[Sqrt[z^2]]//FunctionExpand

Function Representations  (5)

Primary definition of CosIntegral:

Wolfram Language code: Integrate[(Cos[t] - 1/t), {t, 0, z}] + Log[z] + EulerGamma

Series representation of CosIntegral:

Wolfram Language code: Log[z] + EulerGamma + (1/2)Sum[((-1)^k z^2k/k (2k)!), {k, 1, Infinity}]//FullSimplify

CosIntegral can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[CosIntegral[x], x]
Wolfram Language code: Activate[%]//FullSimplify

CosIntegral can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[CosIntegral[x], x]

TraditionalForm formatting:

Wolfram Language code: CosIntegral[z]//TraditionalForm

Generalizations & Extensions  (1)

Find series expansions at infinity:

Wolfram Language code: Series[CosIntegral[x], {x, Infinity, 4}]

Applications  (6)

Average radiated power for a thin linear half-wave antenna:

Wolfram Language code: Integrate[(Cos[Pi Cos[θ]] - Cos[Pi]) ^ 2 / Sin[θ], {θ, 0, Pi}]

Plot the imaginary part in the complex plane:

Wolfram Language code: Plot3D[Im[CosIntegral[x + I y]], {x, -20, 20}, {y, -3, 3}]

Plot the logarithm of the absolute value in the complex plane:

Wolfram Language code: ContourPlot[Log[Abs[CosIntegral[x + I y]]], {x, -10, 10}, {y, -10, 10}]

Solve a differential equation:

Wolfram Language code: DSolve[x (y[x] + Derivative[2][y][x]) == Cos[x], y[x], x]

Real part of the Euler–Heisenberg effective action:

Wolfram Language code: action[k_, {m_, e_}, {a_, b_}] := With[{x = k π (m^2/e a), y = k π (m^2/e b)}, -(e^2a b/4 π^3k)(Coth[k π (b/a)](CosIntegral[x] Cos[x] + (SinIntegral[x] - π / 2)Sin[x]) - Coth[k π (a/b)](ExpIntegralEi[y] Exp[-y] + ExpIntegralEi[-y] Exp[y]) / 2)]

Find the leading term in :

Wolfram Language code: Assuming[{q > 0 && a > 0 && b > 0 && m > 0 && k > 0}, Series[action[k, {m, q}, {a, b}], {q, 0, 4}]//Normal//FullSimplify]

Plot Nielsen's spiral:

Wolfram Language code: nielsen[t_] := {CosIntegral[t], SinIntegral[t]}
Wolfram Language code: ParametricPlot[nielsen[t], {t, 1 / 25, 25}, PlotRange -> All]

The curvature is a simple function of the parameter:

Wolfram Language code: FullSimplify[FrenetSerretSystem[nielsen[t], t][[1, 1]], t∈Reals]

Properties & Relations  (7)

Use FullSimplify to simplify expressions containing the cosine integral:

Wolfram Language code: FullSimplify[MeijerG[{{}, {1}}, {{0, 0}, {(1/ 2)}}, (z^2/4)] - CosIntegral[z], z > 0]

Use FunctionExpand to express CosIntegral through other functions:

Wolfram Language code: FunctionExpand[CosIntegral[z] - CosIntegral[-z]]

Find a numerical root:

Wolfram Language code: FindRoot[CosIntegral[z] == 1 / 4, {z, 1}]

Obtain CosIntegral from integrals and sums:

Wolfram Language code: Integrate[(Cos[t]/t), {t, z, Infinity}]
Wolfram Language code: Underoverscript[∑, k = 1, ∞]((-1)^k z^2 k/k (2 k)!)

Obtain CosIntegral from a differential equation:

Wolfram Language code: DSolve[z Derivative[3][w][z] + 2 Derivative[2][w][z] + z Derivative[1][w][z] == 0, w[z], z]//FunctionExpand

Calculate the Wronskian:

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {1, SinIntegral[x], CosIntegral[x]}, {0, 1, 2}]]//FullSimplify

Laplace transform:

Wolfram Language code: LaplaceTransform[CosIntegral[t], t, s]

Possible Issues  (2)

CosIntegral can take large values for moderate‐size arguments:

Wolfram Language code: CosIntegral[Sqrt[I] 10. ^ 6 ]

A larger setting for $MaxExtraPrecision can be needed:

Wolfram Language code: N[CosIntegral[10 ^ 60 ], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[CosIntegral[10 ^ 60 ], 20]]

Neat Examples  (1)

Nested integrals:

Wolfram Language code: NestList[Integrate[#, x]&, CosIntegral[ x], 4]
Wolfram Research (1991), CosIntegral, Wolfram Language function, https://reference.wolfram.com/language/ref/CosIntegral.html (updated 2022).

Text

Wolfram Research (1991), CosIntegral, Wolfram Language function, https://reference.wolfram.com/language/ref/CosIntegral.html (updated 2022).

CMS

Wolfram Language. 1991. "CosIntegral." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/CosIntegral.html.

APA

Wolfram Language. (1991). CosIntegral. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CosIntegral.html

BibTeX

@misc{reference.wolfram_2026_cosintegral, author="Wolfram Research", title="{CosIntegral}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/CosIntegral.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_cosintegral, organization={Wolfram Research}, title={CosIntegral}, year={2022}, url={https://reference.wolfram.com/language/ref/CosIntegral.html}, note=[Accessed: 13-June-2026]}