WOLFRAM

Wolfram Language & System Documentation Center

SinIntegral[z]

gives the sine integral function TemplateBox[{z}, SinIntegral]=int_0^zsin(t)/t dt.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Function Identities and Simplifications  
Function Representations  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

SinIntegral

SinIntegral[z]

gives the sine integral function TemplateBox[{z}, SinIntegral]=int_0^zsin(t)/t dt.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • TemplateBox[{z}, SinIntegral]=int_0^zsin(t)/t dt.
  • SinIntegral[z] is an entire function of with no branch cut discontinuities.
  • For certain special arguments, SinIntegral automatically evaluates to exact values.
  • SinIntegral can be evaluated to arbitrary numerical precision.
  • SinIntegral automatically threads over lists.
  • SinIntegral can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (6)

Evaluate numerically:

Wolfram Language code: SinIntegral[2.8]

Plot :

Wolfram Language code: Plot[SinIntegral[x], {x, -20, 20}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[SinIntegral[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Differentiate :

Wolfram Language code: SinIntegral'[x]

Series expansion at the origin:

Wolfram Language code: Series[SinIntegral[x], {x, 0, 10}]

Asymptotic expansion at Infinity:

Wolfram Language code: Series[SinIntegral[z], {z, ∞, 3}]//Normal

Scope  (37)

Numerical Evaluation  (5)

Evaluate numerically to high precision:

Wolfram Language code: N[SinIntegral[2], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: SinIntegral[2.0000000000000000000000]

Evaluate for complex arguments:

Wolfram Language code: SinIntegral[2.5 + I]

Evaluate SinIntegral efficiently at high precision:

Wolfram Language code: SinIntegral[2`500]//Timing
Wolfram Language code: SinIntegral[2`10000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: SinIntegral[Interval[{1.1, 1.2}]]
Wolfram Language code: SinIntegral[CenteredInterval[2, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: SinIntegral[Around[2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: SinIntegral[{{-.2, 0.2}, {0, -.1}}]

Or compute the matrix SinIntegral function using MatrixFunction:

Wolfram Language code: MatrixFunction[SinIntegral, {{-.2, 0.2}, {0, -.1}}]

Specific Values  (3)

Value at a fixed point:

Wolfram Language code: SinIntegral[0]

Values at infinity:

Wolfram Language code: SinIntegral[{-Infinity, Infinity, -I Infinity, I Infinity}]
Wolfram Language code: SinIntegral[ComplexInfinity]

Find a local maximum as a root of (dTemplateBox[{x}, SinIntegral])/(dx)=0:

Wolfram Language code: xmax = Solve[D[SinIntegral[x], x] == 0 && 0 < x < 4, x][[1, 1]]
Wolfram Language code: Plot[SinIntegral[x], {x, -3π, 3π}, Epilog -> Style[Point[{xmax[[2]], SinIntegral[xmax[[2]]]}], PointSize[Large], Red]]

Visualization  (2)

Plot the SinIntegral function:

Wolfram Language code: Plot[SinIntegral[x], {x, -4π, 4π}]//Rasterize

Plot the real part of TemplateBox[{z}, SinIntegral]:

Wolfram Language code: ComplexContourPlot[Re[SinIntegral[z]], {z, -2π - π I, 2π + π I}, Contours -> 24]

Plot the imaginary part of TemplateBox[{z}, SinIntegral]:

Wolfram Language code: ComplexContourPlot[Im[SinIntegral[z]], {z, -2π - π I, 2π + π I}, Contours -> 24]

Function Properties  (10)

SinIntegral is defined for all real and complex values:

Wolfram Language code: FunctionDomain[SinIntegral[x], x]
Wolfram Language code: FunctionDomain[SinIntegral[z], z, Complexes]

Approximate function range of SinIntegral:

Wolfram Language code: FunctionRange[SinIntegral[x], x, y]//N

SinIntegral is an odd function:

Wolfram Language code: SinIntegral[-x]

SinIntegral is an analytic function of x:

Wolfram Language code: FunctionAnalytic[SinIntegral[x], x]

SinIntegral is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[SinIntegral[x], x]

SinIntegral is not injective:

Wolfram Language code: FunctionInjective[SinIntegral[x], x]
Wolfram Language code: Plot[{SinIntegral[x], 1.6}, {x, -15, 15}]

SinIntegral is not surjective:

Wolfram Language code: FunctionSurjective[SinIntegral[x], x]
Wolfram Language code: Plot[{SinIntegral[x], 3}, {x, -15, 15}]

SinIntegral is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[SinIntegral[x], x]

SinIntegral has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[SinIntegral[x], x]
Wolfram Language code: FunctionDiscontinuities[SinIntegral[x], x]

SinIntegral is neither convex nor concave:

Wolfram Language code: FunctionConvexity[SinIntegral[x], x]

Differentiation  (3)

First derivative:

Wolfram Language code: D[SinIntegral[x], x]

Higher derivatives:

Wolfram Language code: Table[D[SinIntegral[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -2π, 2π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]//Rasterize

Formula for the ^(th) derivative:

Wolfram Language code: D[SinIntegral[x], {x, n}]

Integration  (3)

Indefinite integral of SinIntegral:

Wolfram Language code: Integrate[SinIntegral[x], x]

Definite integral of an odd integrand over an interval centered at the origin is 0:

Wolfram Language code: Integrate[SinIntegral[x], {x, -2π, 2 π}]

More integrals:

Wolfram Language code: Integrate[x SinIntegral[Sqrt[x]], x]
Wolfram Language code: Integrate[SinIntegral[x]Sin[x], x]
Wolfram Language code: Integrate[(SinIntegral[x] - π / 2)^2, {x, 0, Infinity}]

Series Expansions  (4)

Taylor expansion for SinIntegral:

Wolfram Language code: Series[SinIntegral[x], {x, 0, 7}]

Plot the first three approximations for SinIntegral around :

Wolfram Language code: terms = Normal@Table[Series[SinIntegral[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{SinIntegral[x], terms}, {x, -1.5 π, 1.5π}]//Rasterize

General term in the series expansion of SinIntegral:

Wolfram Language code: SeriesCoefficient[SinIntegral[x], {x, 0, n}]

Find series expansion at infinity:

Wolfram Language code: Series[SinIntegral[x], {x, Infinity, 3}]

Give the result for an arbitrary symbolic direction :

Wolfram Language code: Series[SinIntegral[x], {x, DirectedInfinity[z], 1}]

SinIntegral can be applied to power series:

Wolfram Language code: SinIntegral[x + (x^2/2) + (x^3/9) + O[x]^4]

Function Identities and Simplifications  (3)

Use FullSimplify to simplify expressions containing sine integrals:

Wolfram Language code: FullSimplify[2SinIntegral[z] + I ExpIntegralEi[I z] - I ExpIntegralEi[-I z], z > 0]

Simplify expressions to SinIntegral:

Wolfram Language code: (I/2)(Gamma[0, -I z] - Gamma[0, I z] + Log[-I z] - Log[I z])//FullSimplify

Argument simplifications:

Wolfram Language code: SinIntegral[I z]
Wolfram Language code: SinIntegral[Sqrt[z^2]]//FunctionExpand

Function Representations  (4)

Series representation of SinIntegral:

Wolfram Language code: z Sum[((-1)^k z^2k/(1 + 2k)^2 (2k)!), {k, 0, Infinity}]//FullSimplify

SinIntegral can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[SinIntegral[x], x]
Wolfram Language code: Activate[%]

SinIntegral can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[SinIntegral[x], x]

TraditionalForm formatting:

Wolfram Language code: SinIntegral[x]//TraditionalForm

Generalizations & Extensions  (1)

Find series expansions at infinity:

Wolfram Language code: Series[SinIntegral[x], {x, Infinity, 3}]

Give the result for an arbitrary symbolic direction :

Wolfram Language code: Series[SinIntegral[x], {x, DirectedInfinity[z], 1}]

Applications  (6)

Plot the absolute value in the complex plane:

Wolfram Language code: Plot3D[Abs[SinIntegral[x + I y]], {x, -20, 20}, {y, -3, 3}]

Real part of the Euler–Heisenberg effective action:

Wolfram Language code: action[k_, {m_, e_}, {a_, b_}] := With[{x = k π (m^2/e a), y = k π (m^2/e b)}, -(e^2a b/4 π^3k)(Coth[k π (b/a)](CosIntegral[x] Cos[x] + (SinIntegral[x] - π / 2)Sin[x]) - Coth[k π (a/b)](ExpIntegralEi[y] Exp[-y] + ExpIntegralEi[-y] Exp[y]) / 2)]

Find a leading term in :

Wolfram Language code: Assuming[{q > 0 && a > 0 && b > 0 && m > 0 && k > 0}, Series[action[k, {m, q}, {a, b}], {q, 0, 4}]//Normal//FullSimplify]

Gibbs phenomenon for a square wave:

Wolfram Language code: Plot[Evaluate[Table[1 / 2 - 4x Sum[Sinc[2Pi (2k - 1)x], {k, n}], {n, 20}]], {x, 0, 1}]

Magnify the overshoot region:

Wolfram Language code: Show[%, PlotRange -> {{0.45, 0.55}, {0.8, 1.2}}]

Compute the asymptotic overshoot:

Wolfram Language code: N[1 / 2 + SinIntegral[Pi] / Pi]

Solve a differential equation:

Wolfram Language code: DSolve[x (y[x] + Derivative[2][y][x]) == Cos[x], y[x], x]

Integrate a composition of trigonometric functions:

Wolfram Language code: Integrate[Sin[Tan[x]], x]

Plot Nielsen's spiral:

Wolfram Language code: nielsen[t_] := {CosIntegral[t], SinIntegral[t]}
Wolfram Language code: ParametricPlot[nielsen[t], {t, 1 / 25, 25}, PlotRange -> All]

The curvature is a simple function of the parameter:

Wolfram Language code: FullSimplify[FrenetSerretSystem[nielsen[t], t][[1, 1]], t∈Reals]

Properties & Relations  (7)

Parity transformation is automatically applied:

Wolfram Language code: SinIntegral[-z]
Wolfram Language code: SinIntegral[I z]

Use FullSimplify to simplify expressions containing sine integrals:

Wolfram Language code: FullSimplify[2SinIntegral[z] + I ExpIntegralEi[I z] - I ExpIntegralEi[-I z], z > 0]

Find a numerical root:

Wolfram Language code: FindRoot[SinIntegral[z] == 1 / Pi, {z, 1}]

Obtain SinIntegral from integrals and sums:

Wolfram Language code: Integrate[(Sin[t]/t), {t, 0, z}]
Wolfram Language code: Underoverscript[∑, k = 0, ∞]((-1)^k z^2 k/(1 + 2 k)^2 (2 k)!)

Obtain SinIntegral from a differential equation:

Wolfram Language code: w[z] /. DSolve[z w'''[z] + 2 w''[z] + z w'[z] == 0, w[z], z]//FunctionExpand

Calculate the Wronskian:

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {1, SinIntegral[x], CosIntegral[x]}, {0, 1, 2}]]//FullSimplify

Compare with Wronskian:

Wolfram Language code: Wronskian[{1, SinIntegral[x], CosIntegral[x]}, x]

Integrals:

Wolfram Language code: Integrate[z SinIntegral[Sqrt[z]], z]

Laplace transform:

Wolfram Language code: LaplaceTransform[SinIntegral[t], t, s]

Possible Issues  (2)

SinIntegral can take large values for moderate‐size arguments:

Wolfram Language code: SinIntegral[10000. (1 + I)]

A larger setting for $MaxExtraPrecision can be needed:

Wolfram Language code: N[SinIntegral[10 ^ 60] - Pi / 2, 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 70}, N[SinIntegral[10 ^ 60] - Pi / 2, 20]]

Neat Examples  (1)

Nested integrals:

Wolfram Language code: NestList[Integrate[#, x]&, SinIntegral[ x], 6]//TraditionalForm
Wolfram Research (1991), SinIntegral, Wolfram Language function, https://reference.wolfram.com/language/ref/SinIntegral.html (updated 2022).

Text

Wolfram Research (1991), SinIntegral, Wolfram Language function, https://reference.wolfram.com/language/ref/SinIntegral.html (updated 2022).

CMS

Wolfram Language. 1991. "SinIntegral." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/SinIntegral.html.

APA

Wolfram Language. (1991). SinIntegral. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SinIntegral.html

BibTeX

@misc{reference.wolfram_2026_sinintegral, author="Wolfram Research", title="{SinIntegral}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/SinIntegral.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_sinintegral, organization={Wolfram Research}, title={SinIntegral}, year={2022}, url={https://reference.wolfram.com/language/ref/SinIntegral.html}, note=[Accessed: 13-June-2026]}