WOLFRAM

Wolfram Language & System Documentation Center

CoulombF[l,η,r]

gives the regular Coulomb wavefunction TemplateBox[{l, eta, r}, CoulombF].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Series Expansions  
Function Representations  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

CoulombF

CoulombF[l,η,r]

gives the regular Coulomb wavefunction TemplateBox[{l, eta, r}, CoulombF].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • CoulombF[l,η,r] is a solution of the ordinary differential equation .
  • CoulombF[l,η,r] is proportional to near .
  • CoulombF[l,η,r] tends to for large and some phase shift .
  • CoulombF has a branch cut discontinuity in the complex plane running from to .
  • For certain special arguments, CoulombF automatically evaluates to exact values.
  • CoulombF can be evaluated to arbitrary numerical precision.
  • CoulombF automatically threads over lists.
  • CoulombF can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: CoulombF[3, 0.12, 7.]

Evaluate to arbitrary precision:

Wolfram Language code: N[CoulombF[3, 2, 5], 50]

Plot the Coulomb wavefunction for repulsive () and attractive () interactions:

Wolfram Language code: Plot[{CoulombF[0, 0.3, r], CoulombF[0, -0.3, r]}, {r, 0, 10}]

Complex plot:

Wolfram Language code: ComplexPlot[CoulombF[3 / 2, 1 / 4, z], {z, -3 - 3I, 3 + 3I}]

Series expansion at the origin:

Wolfram Language code: Series[CoulombF[0, 2, r], {r, 0, 2}]

Asymptotic behavior for large radius:

Wolfram Language code: Asymptotic[CoulombF[ℓ, η, r], r -> ∞]

Scope  (20)

Numerical Evaluation  (5)

Evaluate numerically:

Wolfram Language code: N[CoulombF[1 / 2, 7, 1]]
Wolfram Language code: N[CoulombF[1 / 2, -7, 1]]

Evaluate to high precision:

Wolfram Language code: N[CoulombF[1 / 2, 7, 1], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: CoulombF[-2 / 5, -3, 1.23456789101112131415]
Wolfram Language code: CoulombF[-2 / 5, -3, 1.2345678910111213141516171819202122]

Complex number inputs:

Wolfram Language code: CoulombF[2 / 3, 0.7 + 0.1 I, 3.2]

Evaluate efficiently at high precision:

Wolfram Language code: CoulombF[11, -3, 70`100]//N//Timing
Wolfram Language code: CoulombF[11, -3, 70`1000]//N//Timing

CoulombF can be used with Interval and CenteredInterval objects:

Wolfram Language code: CoulombF[Interval[{0.234, 0.235}], Interval[{0.345, 0.346}], Interval[{0.456, 0.457}]]
Wolfram Language code: CoulombF[CenteredInterval[3 / 4, 10 ^ -6], CenteredInterval[5 / 6, 10 ^ -6], CenteredInterval[7 / 8, 10 ^ -6]]

Specific Values  (3)

Limiting value at the origin:

Wolfram Language code: Limit[CoulombF[0, 2, r], r -> 0]

For zero value of the parameter η, CoulombF reduces to a spherical Bessel function:

Wolfram Language code: CoulombF[n, 0, r]

Find the first positive zero of CoulombF:

Wolfram Language code: rzero = r /. FindRoot[CoulombF[0, 3, r], {r, 9}]
Wolfram Language code: Plot[CoulombF[0, 3, r], {r, 0, 20}, Epilog -> Style[Point[{rzero, CoulombF[0, 3, rzero]}], PointSize[Large], Red]]

Visualization  (3)

Plot the CoulombF function:

Wolfram Language code: Plot[CoulombF[2, 0, x], {x, 0, 4π}]

Plot the real part of TemplateBox[{2, 0, z}, CoulombF]:

Wolfram Language code: ComplexContourPlot[Re[CoulombF[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of TemplateBox[{2, 0, z}, CoulombF]:

Wolfram Language code: ComplexContourPlot[Im[CoulombF[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

Polar plot with r=TemplateBox[{2, 0, {k, , phi}}, CoulombF]:

Wolfram Language code: Table[PolarPlot[...], {k, 1, 8}]

Function Properties  (7)

Function domain of CoulombF:

Wolfram Language code: FunctionDomain[CoulombF[n, η, x], x]
Wolfram Language code: FunctionDomain[CoulombF[n, η, z], z, Complexes]

CoulombF is an analytic function of η:

Wolfram Language code: FunctionAnalytic[CoulombF[n, η, x], η]

CoulombF[2,0,x] is not injective:

Wolfram Language code: FunctionInjective[CoulombF[2, 0, x], x]
Wolfram Language code: Plot[{CoulombF[2, 0, x], 1 / 2}, {x, -4π, 4π}]

CoulombF[2,0,x] is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[CoulombF[2, 0, x], x]

CoulombF[2,0,x] has both singularities and discontinuities at zero:

Wolfram Language code: FunctionSingularities[CoulombF[2, 0, x], x]
Wolfram Language code: FunctionDiscontinuities[CoulombF[2, 0, x], x]

CoulombF is neither convex nor concave:

Wolfram Language code: FunctionConvexity[CoulombF[2, 0, x], x]

TraditionalForm formatting:

Wolfram Language code: CoulombF[n, η, z]//TraditionalForm

Series Expansions  (1)

Find the Taylor expansion using Series at zero and at infinity:

Wolfram Language code: Series[CoulombF[1, 2, x], {x, 0, 3}]//FullSimplify
Wolfram Language code: Series[CoulombF[1, 2, x], {x, ∞, 3}]//FullSimplify

Plots of the first three approximations for CoulombF around :

Wolfram Language code: terms = Normal@Table[Series[CoulombF[1, 2, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{CoulombF[1, 2, x], terms}, {x, -2π, 2π}, PlotRange -> {-1.5, 1.5}]

Function Representations  (1)

Representation through other Coulomb functions:

Wolfram Language code: (CoulombH2[ℓ, η, r] - CoulombH1[ℓ, η, r]) / (2I)//FullSimplify

Applications  (3)

Solve the Coulomb wave equation:

Wolfram Language code: DSolve[{y''[r] + (1 - (2η/r) - (ℓ(ℓ + 1)/r^2))y[r] == 0}, y[r], r]

Wavefunction for the radial Schrödinger equation with Coulomb potential between two point particles with charges and separated by a distance and energy of relative motion :

Wolfram Language code: w[𝓈_] := CoulombF[ℓ, 𝒵 𝒵 Quantity[1, "FineStructureConstant"]Quantity[1, "SpeedOfLight"]Sqrt[(Quantity[1, "ElectronMass"]/2ℰ)], (𝓈/Quantity[1, "ReducedPlanckConstant"])Sqrt[2Quantity[1, "ElectronMass"]ℰ]]

Verify that the wavefunction satisfies the Schrödinger equation for specific values of the energy and separation:

Wolfram Language code: -(Quantity[1, "ReducedPlanckConstant"]^2/2Quantity[1, "ElectronMass"])w''[𝓈] + ((Quantity[1, "ReducedPlanckConstant"]^2/2Quantity[1, "ElectronMass"])(ℓ(ℓ + 1)/𝓈^2) + (𝒵 𝒵 Quantity[1, "FineStructureConstant"]Quantity[1, "ReducedPlanckConstant"]Quantity[1, "SpeedOfLight"]/𝓈))w[𝓈] == ℰ w[𝓈] /. {ℓ -> 2, 𝒵 -> -1, 𝒵 -> 1, ℰ -> Quantity[0.44, "Electronvolts"], 𝓈 -> 2.1ElementData["Hydrogen", "AtomicRadius"]}

Plot the wavefunction:

Wolfram Language code: Plot[w[Quantity[s, "Angstroms"]] /. {ℓ -> 2, 𝒵 -> -1, 𝒵 -> 1, ℰ -> Quantity[0.44, "Electronvolts"], 𝓈 -> 2.1ElementData["Hydrogen", "AtomicRadius"]}, {s, 0, 50}]

Construct a WKB approximation of CoulombF:

Wolfram Language code: wkbCoulombF[el_, eta_, r_ ? NumberQ] := Module[{rhoT = eta + √(eta^2 + el(el + 1)), a, phi}, CompoundExpression[...] ]

Compare the WKB approximation with the actual function:

Wolfram Language code: Plot[{CoulombF[3, 17, r], wkbCoulombF[3, 17, r]}, {r, 0, 50}, PlotStyle -> {Thick, Dashed}]

Properties & Relations  (2)

CoulombF is a linear combination of CoulombH1 and CoulombH2:

Wolfram Language code: (CoulombH1[ℓ, η, r] - CoulombH2[ℓ, η, r]) / (2I)//FullSimplify

CoulombF is related to Hypergeometric1F1Regularized in some region of the complex plane:

Wolfram Language code: coulombF[el_, eta_, r_] := With[{z = -2I r, w = 1 + el + I eta}, Exp[(LogGamma[el + 1 + I eta] + LogGamma[el + 1 - I eta]) / 2 + I Pi / 2 w]z ^ (el + 1)Exp[-z / 2]Hypergeometric1F1Regularized[w, 2 el + 2, z] / 2 ]
Wolfram Language code: Plot[{CoulombF[3, 1, r], coulombF[3, 1, r]}, {r, 0, 16}, PlotStyle -> {Thick, Dashed}, PlotLegends -> {"built-in", "alternative"}]

However, the stated definition has a branch cut at , while the built-in CoulombF has a branch cut at :

Wolfram Language code: {Labeled[ComplexPlot[CoulombF[4 / 3, 1, r], {r, -3 - 3I, 3 + 3I}], "built-in"], Labeled[ComplexPlot[coulombF[4 / 3, 1, r], {r, -3 - 3I, 3 + 3I}], "alternative"]}

Neat Examples  (1)

Plot the Riemann surface of TemplateBox[{{3, /, 5}, {{-, 1}, /, 2}, rho}, CoulombF]:

Wolfram Language code: With[{ℓ = 3 / 5, η = -1 / 2, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[Exp[2π I k ℓ]CoulombF[ℓ, η, r Exp[I φ]]]}, {k, -1, 1}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.85], Opacity[0.6]]]]
Wolfram Research (2021), CoulombF, Wolfram Language function, https://reference.wolfram.com/language/ref/CoulombF.html (updated 2023).

Text

Wolfram Research (2021), CoulombF, Wolfram Language function, https://reference.wolfram.com/language/ref/CoulombF.html (updated 2023).

CMS

Wolfram Language. 2021. "CoulombF." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CoulombF.html.

APA

Wolfram Language. (2021). CoulombF. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoulombF.html

BibTeX

@misc{reference.wolfram_2026_coulombf, author="Wolfram Research", title="{CoulombF}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CoulombF.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_coulombf, organization={Wolfram Research}, title={CoulombF}, year={2023}, url={https://reference.wolfram.com/language/ref/CoulombF.html}, note=[Accessed: 13-June-2026]}