WOLFRAM

Wolfram Language & System Documentation Center

CoulombH1[l,η,r]

gives the outgoing irregular Coulomb wavefunction TemplateBox[{l, eta, r}, CoulombH1].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Series Expansions  
Function Representations  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

CoulombH1

CoulombH1[l,η,r]

gives the outgoing irregular Coulomb wavefunction TemplateBox[{l, eta, r}, CoulombH1].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • CoulombH1[ℓ,η,r] is a solution of the ordinary differential equation .
  • CoulombH1[l,η,r] is proportional to for large .
  • CoulombH1[l,η,r] has a regular singularity at .
  • CoulombH1 has a branch cut discontinuity in the complex plane running from to .
  • For certain special arguments, CoulombH1 automatically evaluates to exact values.
  • CoulombH1 can be evaluated to arbitrary numerical precision.
  • CoulombH1 automatically threads over lists.
  • CoulombH1 can be used with CenteredInterval objects. »

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: CoulombH1[2, 0.2, 3.]

Evaluate to arbitrary precision:

Wolfram Language code: N[CoulombH1[3, 2, 5], 25]

CoulombH1 is a linear combination of the CoulombG and CoulombF functions:

Wolfram Language code: CoulombH1[1, 0.8, 5]
Wolfram Language code: CoulombG[1, 0.8, 5] + I CoulombF[1, 0.8, 5]

Complex plot:

Wolfram Language code: ComplexPlot[CoulombH1[3 / 2, -1, z], {z, -2 - 2I, 2 + 2I}]

Asymptotic behavior at large radius:

Wolfram Language code: Asymptotic[CoulombH1[ℓ, η, r], r -> ∞]//TrigToExp

Scope  (19)

Numerical Evaluation  (5)

Evaluate numerically:

Wolfram Language code: N[CoulombH1[1 / 2, 7, 1]]
Wolfram Language code: N[CoulombH1[1 / 2, -7, 1]]

Evaluate to high precision:

Wolfram Language code: N[CoulombH1[1, 7, 1], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: CoulombH1[-2 / 5, -3, 1.23456789101112131415]
Wolfram Language code: CoulombH1[-2 / 5, -3, 1.2345678910111213141516171819202122]

Complex number inputs:

Wolfram Language code: CoulombH1[2 / 3, 0.7 + 0.1 I, 3.2]

Evaluate efficiently at high precision:

Wolfram Language code: CoulombH1[11, -3, 70`100]//NumberForm[#, 20]&//Timing
Wolfram Language code: CoulombH1[11, -3, 70`1000]//NumberForm[#, 20]&//Timing

CoulombH1 can be used with CenteredInterval objects:

Wolfram Language code: CoulombH1[CenteredInterval[3 / 4, 10 ^ -6], CenteredInterval[5 / 6, 10 ^ -6], CenteredInterval[7 / 8, 10 ^ -6]]

Specific Values  (4)

Limiting value at the origin:

Wolfram Language code: Limit[CoulombH1[1, 1, r], r -> 0]//FullSimplify

Symbolic evaluation for special parameters:

Wolfram Language code: CoulombH1[0, 0, r]

For a zero value of the parameter η, CoulombH1 reduces to a spherical Hankel function:

Wolfram Language code: CoulombH1[n, 0, r]

Find the first positive zero of the real part of CoulombH1:

Wolfram Language code: rzero = r /. FindRoot[Re[CoulombH1[0, 3, r]], {r, 9}]//Quiet
Wolfram Language code: Plot[Re[CoulombH1[0, 3, r]], {r, 0, 20}, Epilog -> Style[Point[{rzero, Re[CoulombH1[0, 3, rzero]]}], PointSize[Large], Red]]

Visualization  (2)

Plot the real and imaginary parts of CoulombH1:

Wolfram Language code: ReImPlot[CoulombH1[2, 0, x], {x, 0, 4π}]

Plot the real part of TemplateBox[{2, 0, z}, CoulombH1]:

Wolfram Language code: ComplexContourPlot[Re[CoulombH1[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of TemplateBox[{2, 0, z}, CoulombH1]:

Wolfram Language code: ComplexContourPlot[Im[CoulombH1[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

Function Properties  (6)

Function domain of CoulombH1:

Wolfram Language code: FunctionDomain[CoulombH1[n, η, x], x]
Wolfram Language code: FunctionDomain[CoulombH1[n, η, z], z, Complexes]

CoulombH1[2,0,x] is not injective over complexes:

Wolfram Language code: FunctionInjective[CoulombH1[2, 0, x], x, Complexes]
Wolfram Language code: Plot[{Im[CoulombH1[2, 0, x]], 1 / 2}, {x, -4π, 4π}]

CoulombH1[2,0,x] is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[CoulombH1[2, 0, x], x]

CoulombH1[2,0,x] has both singularities and discontinuities:

Wolfram Language code: FunctionSingularities[CoulombH1[2, 0, x], x]
Wolfram Language code: FunctionDiscontinuities[CoulombH1[2, 0, x], x]

CoulombH1 is neither convex nor concave:

Wolfram Language code: FunctionConvexity[CoulombH1[2, 0, x], x]

TraditionalForm formatting:

Wolfram Language code: CoulombH1[n, η, z]//TraditionalForm

Series Expansions  (1)

Find the Taylor expansion using Series at zero and at infinity:

Wolfram Language code: Series[CoulombH1[1, 2, x], {x, 0, 2}]//FullSimplify
Wolfram Language code: Series[CoulombH1[1, 2, x], {x, ∞, 3}]//FullSimplify

Plots of the first three approximations for CoulombH1 around :

Wolfram Language code: terms = Normal@Table[Series[CoulombH1[1, 0, x], {x, 0, m}], {m, 1, 5, 2}]; ReImPlot[{CoulombH1[1, 0, x], terms}, {x, -2π, 2π}, PlotRange -> {0, 20}]

Function Representations  (1)

Relations with other Coulomb functions:

Wolfram Language code: (CoulombH2[``l``, η, ``r``] - CoulombH1[``l``, η, ``r``]) / 2 I//FullSimplify
Wolfram Language code: (CoulombH2[``l``, η, ``r``] + CoulombH1[``l``, η, ``r``]) / 2 //FullSimplify

Properties & Relations  (1)

CoulombH1 is proportional to WhittakerW in some region of the complex plane:

Wolfram Language code: coulombH1[el_, eta_, r_] := Exp[(LogGamma[el + 1 + I eta] - LogGamma[el + 1 - I eta]) / 2 + (eta - I el) Pi / 2] WhittakerW[-I eta, el + 1 / 2, -2I r]
Wolfram Language code: With[{r = 3`20}, {CoulombH1[3, 1, r], coulombH1[3, 1, r]}]

However, the stated definition has a branch cut at , while the built-in CoulombH1 has a branch cut at :

Wolfram Language code: {Labeled[ComplexPlot[CoulombH1[4 / 3, 1, r], {r, -3 - 3I, 3 + 3I}], "built-in"], Labeled[ComplexPlot[coulombH1[4 / 3, 1, r], {r, -3 - 3I, 3 + 3I}], "alternative"]}
Wolfram Research (2021), CoulombH1, Wolfram Language function, https://reference.wolfram.com/language/ref/CoulombH1.html (updated 2023).

Text

Wolfram Research (2021), CoulombH1, Wolfram Language function, https://reference.wolfram.com/language/ref/CoulombH1.html (updated 2023).

CMS

Wolfram Language. 2021. "CoulombH1." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CoulombH1.html.

APA

Wolfram Language. (2021). CoulombH1. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoulombH1.html

BibTeX

@misc{reference.wolfram_2026_coulombh1, author="Wolfram Research", title="{CoulombH1}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CoulombH1.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_coulombh1, organization={Wolfram Research}, title={CoulombH1}, year={2023}, url={https://reference.wolfram.com/language/ref/CoulombH1.html}, note=[Accessed: 13-June-2026]}