WOLFRAM

Wolfram Language & System Documentation Center

WhittakerM[k,m,z]

gives the Whittaker function TemplateBox[{k, m, z}, WhittakerM].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

WhittakerM

WhittakerM[k,m,z]

gives the Whittaker function TemplateBox[{k, m, z}, WhittakerM].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • WhittakerM is related to the Kummer confluent hypergeometric function by TemplateBox[{k, m, z}, WhittakerM]=e^(-z/2)z^(m+1/2) TemplateBox[{{m, -, k, +, {1, /, 2}}, {{2, , m}, +, 1}, z}, Hypergeometric1F1].
  • TemplateBox[{k, m, z}, WhittakerM] vanishes at for .
  • For certain special arguments, WhittakerM automatically evaluates to exact values.
  • WhittakerM can be evaluated to arbitrary numerical precision.
  • WhittakerM automatically threads over lists.
  • WhittakerM[k,m,z] has a branch cut discontinuity in the complex plane running from to .
  • WhittakerM can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (6)

Evaluate numerically:

Wolfram Language code: WhittakerM[2, 3, 4.5]

Use FunctionExpand to expand in terms of hypergeometric functions:

Wolfram Language code: FunctionExpand[WhittakerM[k, m, x]]

Plot over a subset of the reals :

Wolfram Language code: Plot[WhittakerM[2, 1 / 2, x], {x, 0, 15}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[WhittakerM[2, 1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[WhittakerM[2, 1 / 2, x], {x, 0, 6}]

Series expansion at Infinity:

Wolfram Language code: Series[WhittakerM[2, 1 / 2, x], {x, ∞, 5}]//Normal

Scope  (35)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: WhittakerM[2, 3, 1.7]
Wolfram Language code: WhittakerM[2, 0.5, 0]

Evaluate to high precision:

Wolfram Language code: N[WhittakerM[2, 1 / 3, 1 / 7], 100]

The precision of the output tracks the precision of the input:

Wolfram Language code: WhittakerM[2, 1.33333333333333333333, 1]

Complex number input:

Wolfram Language code: N[WhittakerM[4 / 5, 2 - I, 2]]

Evaluate efficiently at high precision:

Wolfram Language code: WhittakerM[2, 1 / 3, 1 / 7`100]//Timing
Wolfram Language code: WhittakerM[2, 7 / 3, 4 / 7`10000];//Timing

WhittakerM can be used with Interval and CenteredInterval objects:

Wolfram Language code: WhittakerM[0.3, 0.4, Interval[{0.5, 0.6}]]
Wolfram Language code: WhittakerM[1, 2, CenteredInterval[3, 1 / 100]]

Compute the elementwise values of an array:

Wolfram Language code: WhittakerM[1, 3.1, {{2, 3}, {1, 2}}]

Or compute the matrix WhittakerM function using MatrixFunction:

Wolfram Language code: MatrixFunction[WhittakerM[1.3, 3, #]&, {{2, 0}, {1.2, -2}}]

Specific Values  (7)

WhittakerM for symbolic parameters:

Wolfram Language code: WhittakerM[k, m, 2]//FunctionExpand

Values at zero:

Wolfram Language code: WhittakerM[1, 1, 0]
Wolfram Language code: WhittakerM[0, 0, 0]

Find the first positive maximum of WhittakerM[5,1/2,x]:

Wolfram Language code: xmax = x /. FindRoot[D[WhittakerM[5, 1 / 2, x ], x] == 0, {x, 0.5}]
Wolfram Language code: Plot[WhittakerM[5, 1 / 2, x ], {x, 0, 10}, Epilog -> Style[Point[{xmax, WhittakerM[5, 1 / 2, xmax ]}], PointSize[Large], Red]]

Compute the associated WhittakerM[3,1/2,x] function:

Wolfram Language code: WhittakerM[3, 1 / 2, x]//FunctionExpand

Compute the associated WhittakerM function for half-integer parameters:

Wolfram Language code: WhittakerM[1 / 2, 1 / 2, x]//FunctionExpand

Different cases of WhittakerM give different symbolic forms:

Wolfram Language code: Table[WhittakerM[k, m, x], {k, {-1 / 2, 1 / 2}}, {m, {-1, 0, 1}}]//FunctionExpand

WhittakerM threads elementwise over lists:

Wolfram Language code: WhittakerM[2, 3, {1.5, 2.5, 3.5}]

Visualization  (3)

Plot the WhittakerM function for various orders:

Wolfram Language code: Plot[{WhittakerM[1, 1 / 2, x], WhittakerM[2, 1 / 2, x], WhittakerM[3, 1 / 2, x], WhittakerM[4, 1 / 2, x]}, {x, 0, 3}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[WhittakerM[10, 1 / 2, z]], {z, -2 - 2I, 2 + 2I}, Contours -> 24]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[WhittakerM[10, 1 / 2, z]], {z, -2 - 2I, 2 + 2I}, Contours -> 24]

Plot as real parts of two parameters vary:

Wolfram Language code: Plot3D[Re[WhittakerM[k, 1 / 2, z]], {k, 0, 3}, {z, 0, 2}, PlotRange -> All]

Function Properties  (11)

Real domain of TemplateBox[{2, 0, z}, WhittakerM]:

Wolfram Language code: FunctionDomain[WhittakerM[2, 0, x], x]

Complex domain of WhittakerM:

Wolfram Language code: FunctionDomain[WhittakerM[k, m, z], z, Complexes]

Approximate range of TemplateBox[{2, 0, z}, WhittakerM]:

Wolfram Language code: FunctionRange[WhittakerM[2, 0, z], z, y]//Quiet

WhittakerM may reduce to simpler functions:

Wolfram Language code: WhittakerM[-1 / 4, 1 / 4, x ^ 2]//FunctionExpand
Wolfram Language code: WhittakerM[n / 2 + 1 / 4, -1 / 4, 1 / 2z ^ 2]//FunctionExpand

TemplateBox[{k, m, x}, WhittakerM] is not an analytic function of for integer values of :

Wolfram Language code: FunctionAnalytic[WhittakerM[2, 0, x], x]

Nor is it meromorphic:

Wolfram Language code: FunctionMeromorphic[WhittakerM[2, 0, x], x]

It is analytic for other values of :

Wolfram Language code: FunctionAnalytic[WhittakerM[3 / 2, 1 / 2, x], x, ℂ]

TemplateBox[{2, 0, x}, WhittakerM] is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[WhittakerM[2, 0, x], x]

TemplateBox[{2, 0, x}, WhittakerM] is not injective:

Wolfram Language code: FunctionInjective[WhittakerM[2, 0, x], x]
Wolfram Language code: Plot[{WhittakerM[2, 0, x], .2}, {x, 0, 6}]

TemplateBox[{2, {1, /, 2}, x}, WhittakerM] is not surjective:

Wolfram Language code: FunctionSurjective[WhittakerM[2, 1 / 2, x], x]
Wolfram Language code: Plot[{WhittakerM[2, 1 / 2, x], 1}, {x, -3, 6}]

TemplateBox[{2, 0, x}, WhittakerM] is neither non-negative nor non-positive on its real domain:

Wolfram Language code: FunctionSign[{WhittakerM[2, 0, x], x >= 0}, x]

WhittakerM has both singularity and discontinuity in (-∞,0]:

Wolfram Language code: FunctionSingularities[WhittakerM[a, m, x], x]
Wolfram Language code: FunctionDiscontinuities[WhittakerM[a, m, x], x]

TemplateBox[{2, 0, x}, WhittakerM] is neither convex nor concave on its real domain:

Wolfram Language code: FunctionConvexity[{WhittakerM[2, 0, x], x >= 0}, x]

TraditionalForm formatting:

Wolfram Language code: WhittakerM[m, k, x]//TraditionalForm

Differentiation  (3)

First derivative with respect to z:

Wolfram Language code: D[WhittakerM[k, m, z] , z]

Higher derivatives with respect to z when k=1/3 and m=1/2:

Wolfram Language code: Table[D[WhittakerM[1 / 3, 1 / 2, z], {z, n}], {n, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to z when k=1/3 and m=1/2:

Wolfram Language code: Plot[%, {z, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the ^(th) derivative with respect to z:

Wolfram Language code: D[WhittakerM[k, m, z], {z, k}]// FullSimplify

Series Expansions  (5)

Find the Taylor expansion using Series:

Wolfram Language code: Series[WhittakerM[k, m, x], {x, 0, 4}]

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[WhittakerM[2, 1 / 2, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{WhittakerM[2, 1 / 2, x], terms}, {x, 0, 10}, PlotRange -> {-2, 2}]

General term in the series expansion using SeriesCoefficient:

Wolfram Language code: SeriesCoefficient[WhittakerM[k, m, x], {x, 1, n}]

Find the series expansion at Infinity:

Wolfram Language code: Series[WhittakerM[k, m, x], {x, Infinity, 1}]

Find series expansion for an arbitrary symbolic direction :

Wolfram Language code: Series[WhittakerM[k, m, x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]// FullSimplify

Taylor expansion at a generic point:

Wolfram Language code: Series[WhittakerM[k, m, x], {x, x0, 2}]// FullSimplify

Applications  (2)

The bound-state Coulomb eigenfunction in parabolic coordinates:

Wolfram Language code: Subscript[ψ, par][{n1_, n2_, m_}, ζ_, η_, ϕ_] := Module[{mm = Abs[m], n = n1 + n2 + Abs[m] + 1}, (Exp[I m ϕ]/Sqrt[π]Sqrt[ζ η]n)Sqrt[((n1 + mm)!/n1!)((n2 + mm)!/n2!)]WhittakerM[n1 + (mm + 1) / 2, mm / 2, (1/n) η]WhittakerM[n2 + (mm + 1) / 2, mm / 2, (1/n) ζ]]

Decompose the eigenfunction in terms of spherical eigenfunctions:

Wolfram Language code: Subscript[ψ, sph][{n_, l_, m_}, r_, θ_, ϕ_] := Sqrt[( (n - l - 1)!/(n + l)!)] E^-(r/n) ((2r/n))^l(2/n^2) LaguerreL[n - l - 1, 2l + 1, (2r/n)]SphericalHarmonicY[l, m, θ, ϕ]

Parabolic coordinates relate to radial coordinates as and :

Wolfram Language code: FunctionExpand[Subscript[ψ, par][{1, 1, -1}, r(1 + Cos[θ]), r(1 - Cos[θ]), ϕ]]//FullSimplify[#, 0 <= θ < π && r ≥ 0]&
Wolfram Language code: Simplify[% + (3/Sqrt[15]) Subscript[ψ, sph][{4, 3, -1}, r, θ, ϕ] - (2/Sqrt[10])Subscript[ψ, sph][{4, 1, -1}, r, θ, ϕ]]

Green's function of the 3D Coulomb potential:

Wolfram Language code: gf[r1_, r2_, e_] := Module[{ν, a1, a2, δ, 𝓋ℓ = Sqrt[Total[#1 ^ 2]]&}, ν = e ^ (-1 / 2);δ = 𝓋ℓ[r2 - r1];{a1, a2} = 𝓋ℓ[r2] + 𝓋ℓ[r1] + {δ, -δ};(-Gamma[1 - I ν]/4 π δ)Det[(| | | | ------------------------------------------- | ------------------------------------------- | | WhittakerW[I ν, (1/2), -(I a2/ν)] | WhittakerM[I ν, (1/2), -(I a1/ν)] | | WhittakerW^(0, 0, 1)[I ν, (1/2), -(I a2/ν)] | WhittakerM^(0, 0, 1)[I ν, (1/2), -(I a1/ν)] |)]]
Wolfram Language code: Plot[gf[{1, 0, 0}, {0, 0, 1}, e], {e, -2, .01}]

Properties & Relations  (4)

Use FunctionExpand to expand WhittakerM into other functions:

Wolfram Language code: FunctionExpand[WhittakerM[5, 1 / 2, x]]
Wolfram Language code: FunctionExpand[WhittakerM[-1 / 4, 1 / 4, x]]
Wolfram Language code: FunctionExpand[WhittakerM[0, m, x]]

Integrate expressions involving Whittaker functions:

Wolfram Language code: Integrate[Exp[-x]WhittakerM[3, 2, x]WhittakerW[1, -2, x], {x, 0, ∞}]

WhittakerM can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[WhittakerM[n, m, x], x]

WhittakerM can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[WhittakerM[k, y, z], k]
Wolfram Language code: DifferenceRootReduce[WhittakerM[y, k, z], k]

Neat Examples  (1)

Plot the Riemann surface of TemplateBox[{{3, /, 5}, {1, /, 3}, z}, WhittakerM]:

Wolfram Language code: With[{n = 3 / 5, m = 1 / 3, ε = 1*^-12}, Show[Table[ParametricPlot3D[{r Cos[φ], r Sin[φ], Im[(-1)^kExp[2π I m k]WhittakerM[n, m, r Exp[I φ]]]}, {r, 0, 3}, {φ, -π + ε, π - ε}, Mesh -> None, PlotPoints -> 21, PlotStyle -> Directive[Hue[0.85], Opacity[0.6]]], {k, -1, 1}], BoxRatios -> {1, 1, 3}, PlotRange -> {All, All, {-5, 5}}]]
Wolfram Research (2007), WhittakerM, Wolfram Language function, https://reference.wolfram.com/language/ref/WhittakerM.html.

Text

Wolfram Research (2007), WhittakerM, Wolfram Language function, https://reference.wolfram.com/language/ref/WhittakerM.html.

CMS

Wolfram Language. 2007. "WhittakerM." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/WhittakerM.html.

APA

Wolfram Language. (2007). WhittakerM. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WhittakerM.html

BibTeX

@misc{reference.wolfram_2026_whittakerm, author="Wolfram Research", title="{WhittakerM}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/WhittakerM.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_whittakerm, organization={Wolfram Research}, title={WhittakerM}, year={2007}, url={https://reference.wolfram.com/language/ref/WhittakerM.html}, note=[Accessed: 13-June-2026]}