WOLFRAM

Wolfram Language & System Documentation Center

CoxIngersollRossProcess[μ,σ,θ,x0]

represents a Cox–Ingersoll–Ross process with long‐term mean μ, volatility σ, speed of adjustment θ, and initial condition x0.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Process Slice Properties  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

CoxIngersollRossProcess

CoxIngersollRossProcess[μ,σ,θ,x0]

represents a Cox–Ingersoll–Ross process with long‐term mean μ, volatility σ, speed of adjustment θ, and initial condition x0.

Details

Examples

open all close all

Basic Examples  (3)

Simulate a Cox–Ingersoll–Ross process:

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 1, 0.01}]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

Mean and variance functions:

Wolfram Language code: Mean[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]
Wolfram Language code: Variance[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]

Covariance function:

Wolfram Language code: CovarianceFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]], s, t]
Wolfram Language code: Plot3D[CovarianceFunction[CoxIngersollRossProcess[.3, .5, 1, 2], s, t], {s, 0, 5}, {t, 0, 5}, ColorFunction -> "Rainbow"]

Scope  (14)

Basic Uses  (9)

Simulate an ensemble of random paths for a Cox–Ingersoll–Ross process:

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 1, 0.01}, 3]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

Simulate with arbitrary precision:

Wolfram Language code: RandomFunction[CoxIngersollRossProcess[1 / 10, 1 / 3, 1, 2], {0, 1, 1 / 4}, WorkingPrecision -> 20]["Path"]

Compare paths for different values of the drift parameter:

Wolfram Language code: sample[μ_] := (SeedRandom[14];RandomFunction[CoxIngersollRossProcess[μ, .3, .4, 1], {0, 1, .01}])
Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["μ = ", ToString[#]]]& /@ {.3, 1, 2}

Compare paths for different values of the volatility parameter:

Wolfram Language code: sample[σ_] := (SeedRandom[1];RandomFunction[CoxIngersollRossProcess[.5, σ, .4, 1], {0, 1, .01}])
Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["σ = ", ToString[#]]]& /@ {-1, 0.2, 1}

Compare paths for different values of the speed adjustment parameter:

Wolfram Language code: sample[θ_] := (SeedRandom[1];RandomFunction[CoxIngersollRossProcess[.5, 1, θ, 1], {0, 1, .01}])
Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["θ = ", ToString[#]]]& /@ {0.2, 1, 4}

Simulate a Cox–Ingersoll–Ross process with different starting points:

Wolfram Language code: proc[x_] := CoxIngersollRossProcess[1, .4, .3, x];
Wolfram Language code: pts = {.5, 1, 3};
Wolfram Language code: SeedRandom[2]; ListLinePlot[RandomFunction[proc[#], {0, 10, .01}]& /@ pts, Filling -> Axis, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]

Process parameter estimation:

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 100, 0.01}];
Wolfram Language code: EstimatedProcess[data, CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

Correlation function:

Wolfram Language code: CorrelationFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]], s, t]

Absolute correlation function:

Wolfram Language code: AbsoluteCorrelationFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]], s, t]

Process Slice Properties  (5)

First-order probability density function for the slice distribution:

Wolfram Language code: proc = CoxIngersollRossProcess[.3, .5, 1, 2];
Wolfram Language code: times = {.5, 1, 2};
Wolfram Language code: Plot[Evaluate@Table[PDF[proc[t], x], {t, times}], {x, 0, 3}, Filling -> Axis, PlotLegends -> {StringJoin["t = ", ToString[#]]& /@ times}]
Wolfram Language code: PDF[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], x]

Multivariate slice distributions:

Wolfram Language code: Plot3D[PDF[CoxIngersollRossProcess[-.9, 1.2, -2.1, 3][{1, 2}], {x, y}], {x, 0, 10}, {y, 0, 15}]
Wolfram Language code: PDF[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][{1, 2}], {x, y}]

Compute the expectation of an expression:

Wolfram Language code: Expectation[x[t] ^ 2, xCoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

Calculate the probability of an event:

Wolfram Language code: Probability[x[t] < 6, xCoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

Skewness and kurtosis:

Wolfram Language code: Skewness[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]//Simplify[#, σ > 0]&
Wolfram Language code: Kurtosis[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t]]//Simplify

Moment of order r:

Wolfram Language code: Moment[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], r]

Generating functions:

Wolfram Language code: CharacteristicFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]
Wolfram Language code: MomentGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

CentralMoment and its generating function:

Wolfram Language code: CentralMoment[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], 2]
Wolfram Language code: CentralMomentGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

FactorialMoment and its generating function:

Wolfram Language code: FactorialMoment[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], 2]
Wolfram Language code: FactorialMomentGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

Cumulant and its generating function:

Wolfram Language code: Cumulant[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], r]
Wolfram Language code: CumulantGeneratingFunction[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]][t], w]

Properties & Relations  (3)

A Cox–ingersoll–Ross process is not weakly stationary:

Wolfram Language code: WeakStationarity[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

Conditional cumulative distribution function:

Wolfram Language code: Table[Plot[NProbability[(x[5] <= Subscript[x, 2])(x[2] == Subscript[x, 1]), xCoxIngersollRossProcess[.3, 1, .3, 1.2]], {Subscript[x, 2], 0, 6}, Filling -> Axis, PlotLabel -> Row[{"SubscriptBox[x, 1] = ", Subscript[x, 1]}]], {Subscript[x, 1], {.3, 1, 2.3, 3}}]

A Cox–ingersoll–Ross process is a special ItoProcess:

Wolfram Language code: ItoProcess[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

As well as StratonovichProcess:

Wolfram Language code: StratonovichProcess[CoxIngersollRossProcess[μ, σ, θ, Subscript[x, 0]]]

Neat Examples  (3)

Simulate a Cox–Ingersoll–Ross process in two dimensions:

Wolfram Language code: SeedRandom[103];sample = RandomFunction[CoxIngersollRossProcess[.3, .5, 1, 2], {0, 1, .001}, 2]["ValueList"];
Wolfram Language code: ListLinePlot[Transpose@sample, ColorFunction -> "FallColors"]

Simulate a Cox–Ingersoll–Ross process in three dimensions:

Wolfram Language code: proc = CoxIngersollRossProcess[-.4, .5, -1.3, 2]; SeedRandom[123]; sample = Table[RandomFunction[proc, {0, 1, 0.01}, 3]["ValueList"], {6}];
Wolfram Language code: Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@sample[[i]]}, {i, 6}]

Simulate 500 paths from a Cox–Ingersoll–Ross process:

Wolfram Language code: data = RandomFunction[CoxIngersollRossProcess[.4, .5, .3, 2], {0, 1, .01}, 500];

Take a slice at 1 and visualize its distribution:

Wolfram Language code: sd = data["SliceData", 1];
Wolfram Language code: cf = ColorData["Rainbow"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 62]&[HistogramList[sd, {Range[Min[sd], Max[sd], (Max[sd] - Min[sd]) / 20]}]];

Plot paths and histogram distribution of the slice distribution at 1:

Wolfram Language code: ListLinePlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {1.01, 2}, {0, 10}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, .25}, {.5, .5}}]
Wolfram Research (2012), CoxIngersollRossProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html.

Text

Wolfram Research (2012), CoxIngersollRossProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html.

CMS

Wolfram Language. 2012. "CoxIngersollRossProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html.

APA

Wolfram Language. (2012). CoxIngersollRossProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html

BibTeX

@misc{reference.wolfram_2026_coxingersollrossprocess, author="Wolfram Research", title="{CoxIngersollRossProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_coxingersollrossprocess, organization={Wolfram Research}, title={CoxIngersollRossProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/CoxIngersollRossProcess.html}, note=[Accessed: 13-June-2026]}