Wolfram Language & System Documentation Center

FactorialMoment

FactorialMoment[data,r]

gives the order r factorial moment of data.

FactorialMoment[data,{r₁,…,r_m}]

gives the order {r₁,…,r_m} multivariate factorial moment of data.

FactorialMoment[dist,…]

gives the factorial moment of the distribution dist.

FactorialMoment[r]

represents the order r formal factorial moment.

Details

Factorial moments are defined using FactorialPower[x,r] given by .
For scalar order r and data being an array :
sum of r factorial powers »

columnwise sum of r factorial powers »

$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$ columnwise sum of r factorial powers »
FactorialMoment[x,r] is equivalent to ArrayReduce[FactorialMoment[#,r]&,x,1].
For vector order {r₁,…,r_m} and data being array :
sum the r_j factorial power in the j column

$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$ sum the r_j factorial power in the j column »
FactorialMoment[x,{r₁,…,r_m}] is equivalent to ArrayReduce[FactorialMoment[#,{r₁,…,r_m}]&,x,{{1},{2}}].
FactorialMoment handles both numerical and symbolic data.
The data can have the following additional forms and interpretations:

	Association	the values (the keys are ignored) »
	WeightedData	weighted mean, based on the underlying EmpiricalDistribution »
	EventData	based on the underlying SurvivalDistribution »
	TimeSeries, TemporalData, …	vector or array of values (the time stamps ignored) »
	Image,Image3D	RGB channel's values or grayscale intensity value »
	Audio	amplitude values of all channels »

For a distribution dist, the r factorial moment is given by Expectation[x^(r),xdist]. »
For a multivariate distribution dist, the {r₁,…,r_m} factorial moment is given by Expectation[x₁^(r₁)⋯ x_m^(r_m),{x₁,…,x_m}dist]. »
For a random process proc, the factorial moment function can be computed for slice distribution at time t, SliceDistribution[proc,t], as [t]=FactorialMoment[SliceDistribution[proc,t],r]. »
FactorialMoment[r] can be used in such functions as MomentConvert and MomentEvaluate, etc. »

Examples

open all close all

Basic Examples (2)

Compute factorial moment from data:

Wolfram Language code: data = RandomVariate[PoissonDistribution[4], 10 ^ 4];

Wolfram Language code: FactorialMoment[data, 3]

Use symbolic data:

Wolfram Language code: FactorialMoment[{Subscript[k, 1], Subscript[k, 2], Subscript[k, 3]}, 3]

Compute the second factorial moment of a discrete univariate distribution:

Wolfram Language code: FactorialMoment[BinomialDistribution[n, p], 2]

The factorial moment for a multivariate distribution:

Wolfram Language code: FactorialMoment[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}], {2, 2, 2}]

Scope (20)

Basic Uses (5)

Exact input yields exact output:

Wolfram Language code: FactorialMoment[{1, 2, 3, 4}, 1]

Wolfram Language code: FactorialMoment[{π, E, 2}, 2]//Together

Approximate input yields approximate output:

Wolfram Language code: FactorialMoment[{1., 2., 3., 4.}, 2]

Wolfram Language code: FactorialMoment[N[{1, 2, 3, 4}, 30], 2]

Find factorial moments of WeightedData:

Wolfram Language code: FactorialMoment[WeightedData[{1, 2, 3}, {Subscript[w, 1], Subscript[w, 2], Subscript[w, 3]}], 1]

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: FactorialMoment[WeightedData[data, weights], 2]

Find a factorial moment of EventData:

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: FactorialMoment[EventData[e, ci], 2]

Find a factorial moment of TimeSeries:

Wolfram Language code:

FactorialMoment[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.], 2]

Factorial moment depends only on the values:

Wolfram Language code:

FactorialMoment[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]["Values"], 2]

Array Data (4)

For a matrix, FactorialMoment gives columnwise moments:

Wolfram Language code:

FactorialMoment[(⁠|       |       |
| ----- | ----- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠), 2]

For an array, FactorialMoment gives columnwise moments at the first level:

Wolfram Language code: FactorialMoment[Array[Subscript[a, ##]&, {2, 2, 2}], 2]//Simplify//MatrixForm

Multivariate FactorialMoment for an array:

Wolfram Language code: FactorialMoment[Array[Subscript[a, ##]&, {2, 2, 2}], {2, 2}]//Simplify//TraditionalForm

Wolfram Language code: %//FunctionExpand//Simplify

Works with large arrays:

Wolfram Language code: FactorialMoment[RandomReal[1, 10 ^ 7], 2]

Wolfram Language code: FactorialMoment[RandomReal[1, {10 ^ 6, 5}], 1]

When the input is an Association, FactorialMoment works on its values:

Wolfram Language code:

mat = RandomReal[1, {2, 2}];
assoc = AssociationThread[Range[2], mat]

Wolfram Language code: FactorialMoment[assoc, 3]

SparseArray data can be used just like dense arrays:

Wolfram Language code: FactorialMoment[SparseArray[{{1} -> 1, {100} -> 1}], 1]

Wolfram Language code: FactorialMoment[SparseArray[{{1, 1} -> 1, {2, 2} -> 2, {3, 3} -> 3, {1, 3} -> 4}], 2]

Image and Audio Data (2)

Channelwise factorial moment of an RGB image:

Wolfram Language code: FactorialMoment[[image], 5]

Wolfram Language code: RGBColor[%]

Factorial moment intensity value of a grayscale image:

Wolfram Language code: FactorialMoment[[image], 4]

On audio objects, FactorialMoment works channelwise:

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}]

Wolfram Language code: AudioMeasurements[a, "Channels"]

Wolfram Language code: FactorialMoment[a, 3]

Distribution and Process Moments (5)

Scalar factorial moment for univariate distributions:

Wolfram Language code: FactorialMoment[BinomialDistribution[n, p], 1]//Together

Wolfram Language code: FactorialMoment[NormalDistribution[μ, σ], 2]

Scalar factorial moment for multivariate distributions:

Wolfram Language code: FactorialMoment[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ], 2]

Wolfram Language code: FactorialMoment[DirichletDistribution[{a, b, c}], 2]//Simplify

Joint factorial moment for multivariate distributions:

Wolfram Language code: FactorialMoment[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}], {1, 1, 1}]

Wolfram Language code:

FactorialMoment[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ], {2, 2}]

Compute a factorial moment for a symbolic order r:

Wolfram Language code: FactorialMoment[PoissonDistribution[μ], r]

A factorial moment may only evaluate for specific orders:

Wolfram Language code: FactorialMoment[BorelTannerDistribution[𝒶, n], r]

Wolfram Language code: % /. {r -> 2}

A factorial moment may only evaluate numerically:

Wolfram Language code: FactorialMoment[VonMisesDistribution[Pi / 2, 2], 4]

Wolfram Language code: N[%]

Factorial moments for derived distributions:

Wolfram Language code: FactorialMoment[TransformedDistribution[x^2, xNormalDistribution[μ, σ]], 1]

Wolfram Language code: FactorialMoment[ProbabilityDistribution[(Sqrt[2] / π)(1 / (1 + (x - 2)^4)), {x, -∞, ∞}], 2]

Data distribution:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 3];

Wolfram Language code: FactorialMoment[HistogramDistribution[data], 4]

Factorial moment function for a random process:

Wolfram Language code: FactorialMoment[BrownianBridgeProcess[μ, σ][t], 2]

Wolfram Language code: Plot[Evaluate[% /. {μ -> 3, σ -> 1}], {t, 0, 1}, PlotRange -> All]

Find a factorial moment of TemporalData at some time t=0.5:

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 500]

Wolfram Language code: FactorialMoment[td[0.5], 1]

Find the corresponding factorial moment function together with all the simulations:

Wolfram Language code:

Show[ListLinePlot[td, PlotStyle -> Directive[Opacity[0.2], Thin]], Plot[FactorialMoment[td[t], 1], {t, 0, 10}, PlotStyle -> Thick]]

Formal Moments (4)

TraditionalForm formatting for formal moments:

Wolfram Language code: FactorialMoment[r]//TraditionalForm

Wolfram Language code: FactorialMoment[{p, q, r}]//TraditionalForm

Convert combinations of formal moments to an expression involving FactorialMoment:

Wolfram Language code: MomentConvert[Moment[2], FactorialMoment]//TraditionalForm

Wolfram Language code: MomentConvert[CentralMoment[2]Cumulant[2], FactorialMoment]//TraditionalForm

Evaluate an expression involving formal moments for a distribution:

Wolfram Language code: MomentEvaluate[FactorialMoment[2] + FactorialMoment[3], PoissonDistribution[λ]]

Evaluate for data:

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[FactorialMoment[2] + FactorialMoment[3], data]

Find a sample estimator for an expression involving FactorialMoment:

Wolfram Language code: estimator = MomentConvert[FactorialMoment[2], "UnbiasedSampleEstimator"]

Evaluate the resulting estimator for data:

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[estimator, data]

Applications (4)

Estimate parameters of a distribution using the method of factorial moments:

Wolfram Language code: data = RandomVariate[SkellamDistribution[2, 5], 10 ^ 4];

Wolfram Language code: NSolve[Table[FactorialMoment[data, k] == FactorialMoment[SkellamDistribution[m1, m2], k], {k, 1, 2}], {m1, m2}]

Compare data and the estimated parametric distribution:

Wolfram Language code:

Show[Histogram[data, Automatic, "ProbabilityDensity"], DiscretePlot[Evaluate[PDF[SkellamDistribution[m1, m2], x] /. %], {x, -10, 10}, PlotStyle -> PointSize[Medium]]]

Reconstruct probability mass function from the sequence of factorial moments:

Wolfram Language code: fm[r_] = (7 / 3)^-r(3 + (-1)^r) / 4;

Find the factorial moment-generating function (FMGF):

Wolfram Language code: fmgf = Sum[fm[r](t - 1) ^ r / r!, {r, 0, Infinity}]

Use equivalence of the FMGF and the probability generating function:

Wolfram Language code:

dist = ProbabilityDistribution[
	SeriesCoefficient[fmgf, {t, 0, k}], {k, 0, Infinity, 1}]

Verify that factorial moments of the found distribution match the originals:

Wolfram Language code: Table[FactorialMoment[dist, r], {r, 0, 6}]

Wolfram Language code: Table[fm[r], {r, 0, 6}]

Compute a moving factorial moment for some data:

Wolfram Language code:

data = TemporalData[TimeSeries, {{{0., -0.1658757846470872, -0.2728638398721067, -0.20572896599603147, 
    -0.10538217461042272, -0.05347321047935807, -0.09210914812542037, -0.19681903814874602, 
    -0.2868001703261339, -0.39654025546507443, -0.42843667 ... 4643, -0.020432977410382067, 0.061353433083862305, 
    -0.05763556841195196}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];

Use the window of length .1:

Wolfram Language code: md = MovingMap[FactorialMoment[#, 2]&, data, .1];

Wolfram Language code: ListLinePlot[md, PlotRange -> All]

Compute factorial moments for slices of a collection of paths of a random process:

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

Choose a few slice times:

Wolfram Language code: times = Range[0, 1, .1];

Wolfram Language code: fm = Map[{#, FactorialMoment[data[#], 2]}&, times];

Plot factorial moments over these paths:

Wolfram Language code: Show[ListPlot[data], ListLinePlot[fm, PlotStyle -> StandardRed]]

Properties & Relations (5)

Factorial moment is equivalent to an expectation of FactorialPower:

Wolfram Language code: FactorialMoment[PoissonDistribution[μ], 2]

Wolfram Language code: Expectation[FactorialPower[x, 2], xPoissonDistribution[μ]]

First factorial moment is equivalent to Mean:

Wolfram Language code: FactorialMoment[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}, 1]

Wolfram Language code: Mean[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]

FactorialMoment can be computed from Moment through $mu^__r=sum_(k=1)^rTemplateBox[{r, k}, StirlingS1]mu_k$ :

Wolfram Language code: With[{r = 5, 𝒟 = BinomialDistribution[n, p]}, Subsuperscript[∑, k = 1, r]StirlingS1[r, k]Moment[𝒟, k]]

Wolfram Language code: With[{r = 5, 𝒟 = BinomialDistribution[n, p]}, FactorialMoment[𝒟, r]]

Wolfram Language code: Simplify[%% - %]

MomentConvert produces the same result:

Wolfram Language code: MomentConvert[FactorialMoment[5], Moment]

Wolfram Language code: Subsuperscript[∑, k = 1, r]StirlingS1[r, k]Moment[k] /. r -> 5

Moment can be computed from FactorialMoment through $mu_r=sum_(k=0)^rmu^__k TemplateBox[{r, k}, StirlingS2]$ :

Wolfram Language code:

With[{r = 5, 𝒟 = ExponentialDistribution[λ]}, Underoverscript[∑, k = 0, r]StirlingS2[r, k]FactorialMoment[𝒟, k]]

Wolfram Language code: With[{r = 5, 𝒟 = ExponentialDistribution[λ]}, Moment[𝒟, r]]

Wolfram Language code: Simplify[%% - %]

MomentConvert produces the same result:

Wolfram Language code: MomentConvert[Moment[5], FactorialMoment]

Wolfram Language code: Subsuperscript[∑, k = 1, r]StirlingS2[r, k]FactorialMoment[k] /. r -> 5

The multivariate factorial moment of an array of depth has depth :

Wolfram Language code:

arr = Array[Subscript[a, Row@{##}]&, {n = 4, m = 3, 2, 3}];
rs = {2, 2, 2};
Length[rs] == m

Wolfram Language code:

FactorialMoment[arr, rs] == 
	 ArrayReduce[Mean, 
	ArrayReduce[Times@@FactorialPower[#, rs]&, arr, 2], 
	1]//Simplify

Neat Examples (1)

The distribution of FactorialMoment estimates for 30, 100, and 300 samples:

Wolfram Language code: FactorialMoment[ExponentialDistribution[0.9], 2]

Wolfram Language code:

SmoothHistogram[Table[FactorialMoment[RandomVariate[ExponentialDistribution[0.9], {s, 1000}], 2], {s, {30, 100, 300}}], Filling -> Axis, PlotLegends -> {30, 100, 300}, PlotRange -> {{0, 4}, Automatic}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

FactorialMoment

Details

Examples

Basic Examples (2)

Scope (20)

Basic Uses (5)

Array Data (4)

Image and Audio Data (2)

Distribution and Process Moments (5)

Formal Moments (4)

Applications (4)

Properties & Relations (5)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

			sum of r factorial powers »
			columnwise sum of r factorial powers »
	$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$		columnwise sum of r factorial powers »

			sum the r_j factorial power in the j column
	$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$		sum the r_j factorial power in the j column »

FactorialMoment

Details

Examples

Basic Examples (2)

Scope (20)

Basic Uses (5)

Array Data (4)

Image and Audio Data (2)

Distribution and Process Moments (5)

Formal Moments (4)

Applications (4)

Properties & Relations (5)

Neat Examples (1)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX