Wolfram Language & System Documentation Center

CentralMoment

CentralMoment[data,r]

gives the order r central moment of data.

CentralMoment[data,{r₁,…,r_m}]

gives the order {r₁,…,r_m} multivariate central moment of data.

CentralMoment[dist,…]

gives the central moment of the distribution dist.

CentralMoment[r]

represents the order r formal central moment.

Details

CentralMoment is also known as a moment about the mean.
For scalar order r and data being an array , with mean (first raw moment) :
sum of r powers »

columnwise sum of r central powers »

$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$ columnwise sum of r central powers »
CentralMoment[x,r] is equivalent to ArrayReduce[CentralMoment[#,r]&,x,1].
For vector order {r₁,…,r_m} and data being array , with first raw moment :
sum the r_j central power in the j column

$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$ sum the r_j central power in the j column »
CentralMoment[x,{r₁,…,r_m}] is equivalent to ArrayReduce[CentralMoment[#, ${r_1,r_2,...,r_m}$ ]&,x,{{1},{2}}].
CentralMoment handles both numerical and symbolic data.
The data can have the following additional forms and interpretations:

	Association	the values (the keys are ignored) »
	WeightedData	weighted mean, based on the underlying EmpiricalDistribution »
	EventData	based on the underlying SurvivalDistribution »
	TimeSeries, TemporalData, …	vector or array of values (the time stamps ignored) »
	Image,Image3D	RGB channels' values or grayscale intensity value »
	Audio	amplitude values of all channels »
	DateObject, TimeObject	list of dates or list of times »

For a distribution dist, the rcentral moment is given by Expectation[(x-Mean[dist])^r,xdist]. »
For a multivariate distribution dist, the {r₁,…,r_m} central moment is given by Expectation[(x₁-μ₁)^r₁⋯(x₂-μ_m)^r_m,{x₁,…,x_m}dist] and {μ₁,…,μ_m}=Mean[dist]. »
For a random process proc, the central moment function can be computed for slice distribution at time t, SliceDistribution[proc,t], as [t]=CentralMoment[SliceDistribution[proc,t],r]. »
CentralMoment[r] can be used in functions such as MomentConvert and MomentEvaluate, etc. »

Examples

open all close all

Basic Examples (3)

Compute central moments from data:

Wolfram Language code: data = RandomVariate[LogNormalDistribution[1, 1], 10 ^ 5];

Wolfram Language code: CentralMoment[data, 3]

Use symbolic data:

Wolfram Language code: CentralMoment[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, 2]

Central moment of a list of dates:

Wolfram Language code: CentralMoment[{Yesterday, Today, Tomorrow}, 4]

Compute the second central moment of a univariate distribution:

Wolfram Language code: CentralMoment[GammaDistribution[α, β], 2]

The central moment of a multivariate distribution:

Wolfram Language code: CentralMoment[DirichletDistribution[{Subscript[α, 1], Subscript[α, 2], Subscript[α, 3]}], {1, 1}]

Scope (26)

Basic Uses (6)

Exact input yields exact output:

Wolfram Language code: CentralMoment[{1, 2, 3, 4}, 4]

Wolfram Language code: CentralMoment[{π, E, 2}, 2]//Together

Approximate input yields approximate output:

Wolfram Language code: CentralMoment[{1., 2., 3., 4.}, 2]

Wolfram Language code: CentralMoment[N[{1, 2, 3, 4}, 30], 2]

Find central moments of WeightedData:

Wolfram Language code: CentralMoment[WeightedData[{1, 2, 3}, {Subscript[w, 1], Subscript[w, 2], Subscript[w, 3]}], 2]

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: CentralMoment[WeightedData[data, weights], 2]

Find a central moment of EventData:

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: CentralMoment[EventData[e, ci], 2]

Find a central moment of TimeSeries:

Wolfram Language code:

CentralMoment[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.], 2]

Central moment depends only on the values:

Wolfram Language code:

CentralMoment[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]["Values"], 2]

Find a central moment for data involving quantities:

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]

Wolfram Language code: CentralMoment[data, 2]

Array Data (5)

For a matrix, CentralMoment gives columnwise moments:

Wolfram Language code:

CentralMoment[(⁠|       |       |
| ----- | ----- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠), 4]//Simplify

For an array, CentralMoment gives columnwise moments at the first level:

Wolfram Language code: CentralMoment[Array[Subscript[a, ##]&, {2, 2, 2}], 2]//Simplify//MatrixForm

Multivariate CentralMoment for an array:

Wolfram Language code: CentralMoment[Array[Subscript[a, ##]&, {2, 2, 2}], {2, 2}]//Simplify

Works with large arrays:

Wolfram Language code: CentralMoment[RandomReal[1, 10 ^ 7], 2]

Wolfram Language code: CentralMoment[RandomReal[1, {10 ^ 6, 5}], 2]

When the input is an Association, CentralMoment works on its values:

Wolfram Language code:

mat = RandomReal[1, {3, 2}];
assoc = AssociationThread[Range[3], mat]

Wolfram Language code: CentralMoment[assoc, 3]

SparseArray data can be used just like dense arrays:

Wolfram Language code: CentralMoment[SparseArray[{{1} -> 1, {100} -> 1}], 4]

Wolfram Language code: CentralMoment[SparseArray[{{1, 1} -> 1, {2, 2} -> 2, {3, 3} -> 3, {1, 3} -> 4}], 2]

Find the central moment of a QuantityArray:

Wolfram Language code: data = QuantityArray[RandomReal[1, 6], "Pounds"]

Wolfram Language code: CentralMoment[data, 5]

Image and Audio Data (2)

Channelwise central moment of an RGB image:

Wolfram Language code: CentralMoment[[image], 5]

Wolfram Language code: RGBColor[%]

Central moment intensity value of a grayscale image:

Wolfram Language code: CentralMoment[[image], 4]

On audio objects, CentralMoment works channelwise:

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}]

Wolfram Language code: AudioMeasurements[a, "Channels"]

Wolfram Language code: CentralMoment[a, 3]

Date and Time (4)

Compute central moment of dates:

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];

Wolfram Language code: DateHistogram[dates]

Wolfram Language code: CentralMoment[dates, 4]

Wolfram Language code: UnitConvert[%, "Decades" ^ 4]

Compute the weighted central moment of dates:

Wolfram Language code: dates = RandomDate[4]

Wolfram Language code: weights = {1, 1, 1, 3};

Wolfram Language code: CentralMoment[WeightedData[dates, weights], 3]

Wolfram Language code: UnitConvert[%, "Years" ^ 3]

Compute the central moment of dates given in different calendars:

Wolfram Language code:

dates = {DateObject[{2024, 2, 29}, CalendarType -> "Julian"], DateObject[{1524, 1, 1}, CalendarType -> "Islamic"], DateObject[{6024, 1, 15}, CalendarType -> "Jewish"]}

Wolfram Language code: CentralMoment[dates, 2]

Wolfram Language code: UnitConvert[%, "Years" ^ 2]

Compare with variance:

Wolfram Language code: Variance[dates]

Wolfram Language code: UnitConvert[%, "Years" ^ 2]

Compute the central moment of times:

Wolfram Language code: RandomTime[3]

Wolfram Language code: CentralMoment[%, 4]

List of times with different time zone specifications:

Wolfram Language code: {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}

Wolfram Language code: CentralMoment[%, 3]

Distribution and Process Moments (5)

Scalar central moment for univariate distributions:

Wolfram Language code: CentralMoment[BinomialDistribution[n, p], 2]//Together

Wolfram Language code: CentralMoment[NormalDistribution[μ, σ], 2]

Scalar central moment for multivariate distributions:

Wolfram Language code: CentralMoment[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ], 2]

Wolfram Language code: CentralMoment[DirichletDistribution[{a, b, c}], 3]

Joint central moment for multivariate distributions:

Wolfram Language code: CentralMoment[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}], {1, 1, 1}]

Wolfram Language code:

CentralMoment[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ], {2, 2}]

Compute a central moment for a symbolic order r:

Wolfram Language code: CentralMoment[BetaDistribution[a, b], r]

A central moment may only evaluate for specific orders:

Wolfram Language code: CentralMoment[ExtremeValueDistribution[a, b], r]

Wolfram Language code: % /. r -> 3

A central moment may only evaluate numerically:

Wolfram Language code: CentralMoment[VonMisesDistribution[Pi / 2, 2], 4]

Wolfram Language code: N[%]

Central moments for derived distributions:

Wolfram Language code: CentralMoment[TransformedDistribution[x^2, xNormalDistribution[μ, σ]], 2]

Wolfram Language code: CentralMoment[ProbabilityDistribution[(Sqrt[2] / π)(1 / (1 + (x - 2)^4)), {x, -∞, ∞}], 2]

Data distribution:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 3];

Wolfram Language code: CentralMoment[HistogramDistribution[data], 4]

Central moment function for a random process:

Wolfram Language code: CentralMoment[BrownianBridgeProcess[μ, σ][t], 4]

Wolfram Language code: Plot[Evaluate[% /. {μ -> 3, σ -> 1}], {t, 0, 1}, PlotRange -> All]

Find a central moment of TemporalData at some time t=0.5:

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 100]

Wolfram Language code: CentralMoment[td[0.5], 2]

Find the corresponding central moment function together with all the simulations:

Wolfram Language code:

Show[ListLinePlot[td, PlotStyle -> Directive[Opacity[0.2], Thin]], Plot[CentralMoment[td[t], 2], {t, 0, 10}, PlotStyle -> Thick]]

Formal Moments (4)

TraditionalForm formatting for formal moments:

Wolfram Language code: CentralMoment[r]//TraditionalForm

Wolfram Language code: CentralMoment[{p, q, r}]//TraditionalForm

Convert combinations of formal moments to an expression involving CentralMoment:

Wolfram Language code: MomentConvert[Moment[2], CentralMoment]//TraditionalForm

Wolfram Language code: MomentConvert[Moment[2]Cumulant[2], CentralMoment]//TraditionalForm

Evaluate an expression involving formal moments for a distribution:

Wolfram Language code: MomentEvaluate[CentralMoment[2] + CentralMoment[4], PoissonDistribution[λ]]

Evaluate for data:

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[CentralMoment[2] + Moment[4], data]

Find a sample estimator for an expression involving CentralMoment:

Wolfram Language code: (estimator = MomentConvert[CentralMoment[2], "UnbiasedSampleEstimator"])//TraditionalForm

Evaluate the resulting estimator for data:

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[estimator, data]

Applications (11)

The first central moment is always 0:

Wolfram Language code: data = RandomReal[{-7, 3}, 100];

Wolfram Language code: CentralMoment[data, 1]

The second central moment is a measure of dispersion:

Wolfram Language code: 𝒟 = NormalDistribution[0, σ];

Wolfram Language code: CentralMoment[𝒟, 2]

Wolfram Language code:

Table[Plot[PDF[𝒟, x], {x, -4, 4}, PlotRange -> {0, 0.4}, Filling -> Axis, Ticks -> {Automatic, None}], {σ, {1, 1.5, 2}}]

The third central moment is a measure of skewness:

Wolfram Language code: dists = {NormalDistribution[0, 2.5], ChiSquareDistribution[5], GumbelDistribution[3, 2]};

Wolfram Language code: Table[CentralMoment[dists[[i]], 3], {i, 3}]//N

Wolfram Language code: Table[Plot[PDF[dists[[i]], x], {x, -7, 15}, PlotRange -> {0, 0.2}, Filling -> Axis, Ticks -> {Automatic, None}], {i, 3}]

Estimate parameters of a distribution using the method of moments:

Wolfram Language code: data = RandomVariate[GammaDistribution[3, 6], 10 ^ 4];

Wolfram Language code: meq = Table[CentralMoment[data, k] == CentralMoment[GammaDistribution[α, β], k], {k, 2, 3}]

Wolfram Language code: NSolve[meq, {α, β}]

Compare data and the estimated parametric distribution:

Wolfram Language code:

Show[Histogram[data, Automatic, "ProbabilityDensity"], Plot[Evaluate[PDF[GammaDistribution[α, β], x] /. %], {x, 0, 100}, PlotStyle -> Thick]]

Find a normal approximation to GammaDistribution using the method of moments:

Wolfram Language code: gdist = GammaDistribution[α, β];

Wolfram Language code:

meq = {Moment[gdist, 1] == Moment[NormalDistribution[μ, σ], 1], CentralMoment[gdist, 2] == CentralMoment[NormalDistribution[μ, σ], 2]}

Show how and depend on and :

Wolfram Language code: Solve[(And@@meq)∧σ > 0, {μ, σ}, Reals]

Wolfram Language code: {ndist} = Refine[NormalDistribution[μ, σ] /. %, β > 0∧α > 0]

Compare an original and an approximated distribution:

Wolfram Language code: Plot[{PDF[gdist, x], PDF[ndist, x]} /. {α -> 13, β -> 3}, {x, 0, 80}, Evaluated -> True]

Construct a sample estimator of the second central moment:

Wolfram Language code: estim = MomentConvert[CentralMoment[2], "SampleEstimator"]

Find its sample distribution expectation, assuming sample size :

Wolfram Language code: MomentConvert[estim, {CentralMoment, n}]

Find sample distribution variance of the estimator:

Wolfram Language code: MomentConvert[(estim - %) ^ 2, {CentralMoment, n}]

Variance of the estimator for uniformly distributed sample:

Wolfram Language code: MomentEvaluate[%, UniformDistribution[{0, 1}]]

The law of large numbers states that a sample moment approaches population moment as sample size increases. Use Histogram to show the probability distribution of a second sample central moment of uniform random variates for different sample sizes:

Wolfram Language code:

Histogram[Table[CentralMoment[RandomReal[1, {n, 2 * 10 ^ 3}], 2], {n, {10, 10^2, 10^3}}], 30, "ProbabilityDensity", ChartLegends -> {10, 10^2, 10^3}]

Edgeworth expansion for near-normal data correcting for third and fourth central moments:

Wolfram Language code:

pdf = (Exp[-(x^2/2)]/Sqrt[2 π]) (1 + ((-6 Sqrt[2] x + 2 Sqrt[2] x^3) CentralMoment[3]/12 Sqrt[2]) + (1/576) (-120 + 360 x^2 - 120 x^4 + 8 x^6) CentralMoment[3]^2 + (1/96) (12 - 24 x^2 + 4 x^4) (-3 + CentralMoment[4]));

Wolfram Language code: data = Standardize[Total[RandomReal[1, {3, 10 ^ 5}]]];

Wolfram Language code: dist = ProbabilityDistribution[MomentEvaluate[pdf, data], {x, -∞, ∞}]

Wolfram Language code: {NExpectation[x ^ 3, xdist], NExpectation[x ^ 4, xdist]}

Wolfram Language code: {CentralMoment[data, 3], CentralMoment[data, 4]}

Wolfram Language code:

Show[Histogram[data, Automatic, "ProbabilityDensity"], Plot[{PDF[dist, z], PDF[NormalDistribution[], z]}, {z, -3, 3}, PlotStyle -> {Directive[Thick], Directive[Dashed, Red]}]]

Function computing sample Jarque–Bera statistics [link]:

Wolfram Language code:

JarqueBera[list_] := With[{cm2 = CentralMoment[list, 2]}, (Length[list]/6)((CentralMoment[list, 3]^2/cm2^3) + (1/4)((CentralMoment[list, 4]/cm2^2) - 3)^2)]

Accumulate statistics on samples of normal random variates:

Wolfram Language code: data = Table[JarqueBera[RandomVariate[NormalDistribution[], 2 * 10^3]], {2 * 10^3}];

Compare the statistics histogram with an asymptotic distribution:

Wolfram Language code:

Show[
	Histogram[data, 30, "ProbabilityDensity"], 
	Plot[PDF[ChiSquareDistribution[2], x], {x, 0, 20}, PlotRange -> All]]

Compute a moving central moment for some data:

Wolfram Language code:

data = TemporalData[TimeSeries, {{{0., 0.007220215826254015, -0.028898335552430553, -0.24236658577144637, 
    -0.05412788592296647, -0.03667481168713718, -0.17138823136819967, -0.3007558946785308, 
    -0.43687938826754796, -0.3573927720423709, -0.345586 ... 33201685, -1.2078738741401542, -1.1504147295751919, 
    -1.1306360665338737}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];

Use the window of length .1:

Wolfram Language code: md = MovingMap[CentralMoment[#, 2]&, data, {.1}];

Wolfram Language code: ListLinePlot[md, PlotRange -> All]

Compute central moments for slices of a collection of paths of a random process:

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

Choose a few slice times:

Wolfram Language code: times = Range[0, 1, .1];

Wolfram Language code: cm = Map[{#, CentralMoment[data[#], 2]}&, times];

Plot central moments over these paths:

Wolfram Language code: Show[ListPlot[data], ListLinePlot[cm, PlotStyle -> Green]]

Properties & Relations (11)

Central moments are translation invariant:

Wolfram Language code: CentralMoment[ExponentialDistribution[λ], 5]

Wolfram Language code: CentralMoment[TransformedDistribution[x + a, xExponentialDistribution[λ]], 5]

The second central moment is a scaled Variance:

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code: Variance[data] (Length[data] - 1) / Length[data]

Wolfram Language code: CentralMoment[data, 2]

The odd moments of 2×2 matrices vanish:

Wolfram Language code:

CentralMoment[(⁠|       |       |
| ----- | ----- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠), 5]//Simplify

For a multivariate order, the total order must be odd:

Wolfram Language code:

CentralMoment[(⁠|       |       |
| ----- | ----- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠), {2, 3}]//Simplify

The multivariate central moment of an array of depth has depth :

Wolfram Language code:

arr = Array[Subscript[a, Row@{##}]&, {n = 4, m = 3, 2, 3}];
rs = {2, 2, 2};
Length[rs] == m

Wolfram Language code:

CentralMoment[arr, rs] == 
	ArrayReduce[Mean, 
	ArrayReduce[Times@@Power[#, rs]&, 
	(*Centralize*)
	arr - TensorProduct[ConstantArray[1, n], Mean[arr]], 
	2], 
	1]//Simplify

Sqrt of the second central moment is RootMeanSquare of deviations from the Mean:

Wolfram Language code: Sqrt[CentralMoment[{a, b, c, d}, 2]]

Wolfram Language code: RootMeanSquare[{a, b, c, d} - Mean[{a, b, c, d}]]

Skewness is a ratio of powers of third and second central moments:

Wolfram Language code: data = RandomReal[10, 10];

Wolfram Language code: Skewness[data]

Wolfram Language code: CentralMoment[data, 3] / CentralMoment[data, 2] ^ (3 / 2)

Kurtosis is a ratio of powers of fourth and second central moments:

Wolfram Language code: data = RandomReal[10, 10];

Wolfram Language code: Kurtosis[data]

Wolfram Language code: CentralMoment[data, 4] / CentralMoment[data, 2] ^ 2

CentralMoment is equivalent to an Expectation of a power of a random variable around its mean:

Wolfram Language code: list = Range[100];

Wolfram Language code: Expectation[(x - Mean[list]) ^ 5, xlist] == CentralMoment[list, 5]

Wolfram Language code: dist = PoissonDistribution[μ];

Wolfram Language code: Expectation[(x - Mean[dist]) ^ 5, xdist] == CentralMoment[dist, 5]

CentralMoment of order is equivalent to when both exist:

Wolfram Language code: cmgf = CentralMomentGeneratingFunction[LaplaceDistribution[0, 1], t]

Wolfram Language code: SeriesCoefficient[cmgf, {t, 0, r}]r!

Use CentralMoment directly:

Wolfram Language code: CentralMoment[LaplaceDistribution[0, 1], r]

Find the central moment–generating function by using GeneratingFunction:

Wolfram Language code: GeneratingFunction[CentralMoment[ExponentialDistribution[λ], r] / r!, r, t, Assumptions -> λ > 0]

Compare with direct evaluation of CentralMomentGeneratingFunction:

Wolfram Language code: CentralMomentGeneratingFunction[ExponentialDistribution[λ], t]

Wolfram Language code: FullSimplify[% - %%]

CentralMoment can be expressed in terms of Moment, Cumulant, or FactorialMoment:

Wolfram Language code: MomentConvert[CentralMoment[4], Cumulant]

Wolfram Language code: MomentConvert[CentralMoment[4], Moment]

Wolfram Language code: MomentConvert[CentralMoment[2], FactorialMoment]

Possible Issues (2)

Central moments of higher order are undefined for a heavy-tailed distribution:

Wolfram Language code: Table[CentralMoment[StudentTDistribution[3], r], {r, 2, 5}]

Compute central moments on 5 independent samples of the distribution:

Wolfram Language code: data = RandomVariate[StudentTDistribution[3], {10 ^ 5, 5}];

Sample central moments of higher order exhibit wild fluctuations:

Wolfram Language code: ListLogPlot[Abs@Table[CentralMoment[data, r], {r, 2, 5}], Joined -> True]

Sample estimators of central moments are biased:

Wolfram Language code: MomentConvert[CentralMoment[2], "SampleEstimator"]//TraditionalForm

Find sampling population expectation assuming a sample of size :

Wolfram Language code: MomentConvert[%, {CentralMoment, n}]

The estimator is asymptotically unbiased:

Wolfram Language code: Limit[%, n -> ∞]

Construct an unbiased estimator:

Wolfram Language code: MomentConvert[CentralMoment[2], "UnbiasedEstimator", "PowerSymmetricPolynomial"]//TraditionalForm

The expected value of the estimator is the central moment for all sample sizes:

Wolfram Language code: MomentConvert[%, {CentralMoment, n}]

Neat Examples (1)

The distribution of CentralMoment estimates for 20, 100, and 300 samples:

Wolfram Language code: CentralMoment[ExponentialDistribution[0.9], 2]

Wolfram Language code:

SmoothHistogram[Table[CentralMoment[RandomVariate[ExponentialDistribution[0.9], {s, 1000}], 2], {s, {20, 100, 300}}], Filling -> Axis, PlotLegends -> {20, 100, 300}, PlotRange -> {{0, 4}, Automatic}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

CentralMoment

Details

Examples

Basic Examples (3)

Scope (26)

Basic Uses (6)

Array Data (5)

Image and Audio Data (2)

Date and Time (4)

Distribution and Process Moments (5)

Formal Moments (4)

Applications (11)

Properties & Relations (11)

Possible Issues (2)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

			sum of r powers »
			columnwise sum of r central powers »
	$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$		columnwise sum of r central powers »

			sum the r_j central power in the j column
	$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$		sum the r_j central power in the j column »

CentralMoment

Details

Examples

Basic Examples (3)

Scope (26)

Basic Uses (6)

Array Data (5)

Image and Audio Data (2)

Date and Time (4)

Distribution and Process Moments (5)

Formal Moments (4)

Applications (11)

Properties & Relations (11)

Possible Issues (2)

Neat Examples (1)

See Also

Tech Notes

Related Guides

Related Workflows

History

Text

CMS

APA

BibTeX

BibLaTeX