DaubechiesWavelet
represents a Daubechies wavelet of order 2.
represents a Daubechies wavelet of order n.
Details
- DaubechiesWavelet defines a family of orthogonal wavelets.
- DaubechiesWavelet[n] is defined for any positive integer n.
- The scaling function (
) and wavelet function (
) have compact support length of 2n. The scaling function has n vanishing moments. - DaubechiesWavelet can be used with such functions as DiscreteWaveletTransform, WaveletPhi, etc.
Examples
open all close allBasic Examples (3)
Plot[WaveletPhi[DaubechiesWavelet[4], x], {x, 0, 7}]WaveletPhi[DaubechiesWavelet[4], x]Plot[WaveletPsi[DaubechiesWavelet[4], x], {x, -3, 4}, PlotRange -> All]WaveletPsi[DaubechiesWavelet[4], x]WaveletFilterCoefficients[DaubechiesWavelet[2], {"PrimalLowpass", "PrimalHighpass"}, WorkingPrecision -> ∞]Scope (14)
Basic Uses (8)
Compute primal lowpass filter coefficients:
WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalLowpass"]Primal highpass filter coefficients:
WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalHighpass"]WaveletFilterCoefficients[DaubechiesWavelet[2], "LiftingFilter", WorkingPrecision -> ∞]%[{"LiftingMatrixForm", z}]Generate a function to compute a lifting wavelet transform:
lf = WaveletFilterCoefficients[DaubechiesWavelet[2], "LiftingFilter", WorkingPrecision -> ∞]lf["ForwardLiftingFunction"][Range[8]]//Simplifylf["InverseLiftingFunction"][%]//SimplifyDaubechies scaling function of order 2:
Plot[WaveletPhi[DaubechiesWavelet[2], x], {x, 0, 3}]Daubechies scaling function of order 6:
Plot[WaveletPhi[DaubechiesWavelet[6], x], {x, 0, 11}, PlotRange -> All]Plot scaling function using different levels of recursion:
Table[Plot[WaveletPhi[DaubechiesWavelet[2], x, MaxRecursion -> i], {x, 0, 3}, PlotLabel -> i], {i, 1, 8, 2}]Daubechies wavelet function of order 2:
Plot[WaveletPsi[DaubechiesWavelet[2], x], {x, -1, 2}]DaubechiesWavelet of order 6:
Plot[WaveletPsi[DaubechiesWavelet[6], x], {x, -5, 6}, PlotRange -> All]Plot wavelet function different levels of recursion:
Table[Plot[WaveletPsi[DaubechiesWavelet[2], x, MaxRecursion -> i], {x, -1, 2}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]Wavelet Transforms (5)
Compute a DiscreteWaveletTransform:
data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];ListLinePlot[data, PlotRange -> All]dwt = DiscreteWaveletTransform[data, DaubechiesWavelet[3], 2]View the tree of wavelet coefficients:
dwt["TreeView"]Get the dimensions of wavelet coefficients:
dwt["Dimensions"]Plot the wavelet coefficients:
WaveletListPlot[dwt, PlotLayout -> "CommonXAxis"]Compute a DiscreteWaveletPacketTransform:
data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];dwpt = DiscreteWaveletPacketTransform[data, DaubechiesWavelet[4], 2]View the tree of wavelet coefficients:
dwpt["TreeView"]Get the dimensions of wavelet coefficients:
dwpt["Dimensions"]Plot the wavelet coefficients:
WaveletListPlot[dwpt, PlotLayout -> "CommonXAxis"]Compute a StationaryWaveletTransform:
data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];swt = StationaryWaveletTransform[data, DaubechiesWavelet[4], 2];View the tree of wavelet coefficients:
swt["TreeView"]Get the dimensions of wavelet coefficients:
swt["Dimensions"]Plot the wavelet coefficients:
WaveletListPlot[swt, PlotLayout -> "CommonXAxis"]Compute a StationaryWaveletPacketTransform:
data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];swpt = StationaryWaveletPacketTransform[data, DaubechiesWavelet[4], 2];View the tree of wavelet coefficients:
swpt["TreeView"]Get the dimensions of wavelet coefficients:
swpt["Dimensions"]Plot the wavelet coefficients:
WaveletListPlot[swpt, PlotLayout -> "CommonXAxis"]Compute a LiftingWaveletTransform:
(data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];);lwt = LiftingWaveletTransform[data, DaubechiesWavelet[4], 2];View the tree of wavelet coefficients:
lwt["TreeView"]Get the dimensions of wavelet coefficients:
lwt["Dimensions"]Plot the wavelet coefficients:
WaveletListPlot[lwt, PlotLayout -> "CommonXAxis"]Higher Dimensions (1)
Multivariate scaling and wavelet functions are products of univariate ones:
ϕ = WaveletPhi[DaubechiesWavelet[3]];
ψ = WaveletPsi[DaubechiesWavelet[3]];Plot3D[Evaluate[ϕ[x] ψ[y]], {x, 0, 5}, {y, 0, 5}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Plot3D[Evaluate[ϕ[x] ψ[y]], {x, 0, 5}, {y, -2, 3}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Plot3D[Evaluate[ψ[x] ϕ[y]], {x, -2, 3}, {y, 0, 5}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Plot3D[Evaluate[ψ[x] ψ[y]], {x, -2, 3}, {y, -2, 3}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]Applications (3)
Approximate a function using Daubechies wavelet coefficients:
data = Table[Abs[Sin[2 π x]] + 1.5 Abs[Cos[2 π x - π]], {x, 0, 1, (1/2^6 - 1)}];Perform a LiftingWaveletTransform:
dwd = LiftingWaveletTransform[data, DaubechiesWavelet[4]];Approximate original data by keeping n largest coefficients and thresholding everything else:
{data8, data16, data32} = Table[InverseWaveletTransform[WaveletThreshold[dwd, {"LargestCoefficients", n}, Automatic]], {n, {8, 16, 32}}];Compare the different approximations:
ListLinePlot[{data, data8, data16, data32}, PlotRange -> All]Compute the multiresolution representation of a signal containing an impulse:
data = Table[Sin[4 π t] + 2 Exp[-10^5 ((1/3) - t)^2], {t, 0, 1, (1/2^9)}];ListLinePlot[data]dwt = DiscreteWaveletTransform[data, DaubechiesWavelet[4], 4]WaveletListPlot[dwt, {{1}, {0, 1}, {0, 0, 1}, {0, 0, 0}}, PlotLayout -> "CommonXAxis", Method -> {"Inverse" -> True}]Compare the cumulative energy in a signal and its wavelet coefficients:
data = Table[Sin[2 π t], {t, 0, 1, (1/63)}];ListPlot[data]Compute the ordered cumulative energy in the signal:
cumulativeEnergy[data_] := Module[{c = Sort[Flatten[data]^2, Greater]}, (Accumulate[c]/Total[c])]ListPlot[cumulativeEnergy[data]]The energy in the signal is captured by relatively few wavelet coefficients:
dwd1 = LiftingWaveletTransform[data, DaubechiesWavelet[4], 1];dwd2 = LiftingWaveletTransform[data, DaubechiesWavelet[4], 2];ListPlot[{cumulativeEnergy[data], cumulativeEnergy[Last /@ dwd1[Automatic]], cumulativeEnergy[Last /@ dwd2[Automatic]]}, PlotStyle -> {Red, Blue, Orange}]Properties & Relations (13)
DaubechiesWavelet[1] is equivalent to HaarWavelet:
WaveletFilterCoefficients[HaarWavelet[]] === WaveletFilterCoefficients[DaubechiesWavelet[1]]Lowpass filter coefficients sum to unity; 
:
Chop[Total[WaveletFilterCoefficients[DaubechiesWavelet[3], "PrimalLowpass"][[All, 2]]]]Highpass filter coefficients sum to zero; 
:
Chop[Total[WaveletFilterCoefficients[DaubechiesWavelet[3], "PrimalHighpass"][[All, 2]]]]Scaling function integrates to unity; 
:
ϕ = WaveletPhi[DaubechiesWavelet[4]];Subsuperscript[∫, -∞, ∞]ϕ[x]ⅆx
Table[NIntegrate[ϕ[(x/2^j)], {x, -∞, ∞}, AccuracyGoal -> 4] - 2^j, {j, 0, 3}]Wavelet function integrates to zero; 
:
Subsuperscript[∫, -∞, ∞]WaveletPsi[DaubechiesWavelet[4], x]ⅆxWavelet function is orthogonal to the scaling function at the same scale; 
:
NIntegrate[WaveletPsi[DaubechiesWavelet[3], x] WaveletPhi[DaubechiesWavelet[3], x], {x, -∞, ∞}, AccuracyGoal -> 4]The lowpass and highpass filter coefficients are orthogonal; 
:
WaveletFilterCoefficients[DaubechiesWavelet[3]][[All, 2]].WaveletFilterCoefficients[DaubechiesWavelet[3], "PrimalHighpass"][[All, 2]]DaubechiesWavelet[n] has n vanishing moment; 
:
ψ = WaveletPsi[DaubechiesWavelet[2]];Chop[Table[NIntegrate[x^k ψ[x], {x, -∞, ∞}, AccuracyGoal -> 5, MaxRecursion -> 0], {k, 0, 4}]]This means linear signals are fully represented in the scaling functions part ({0}):
dwt = LiftingWaveletTransform[ArrayPad[{1, 2, 3, 4}, 2, "Extrapolated"], DaubechiesWavelet[2], 1];Take[InverseWaveletTransform[dwt, Automatic, {0}], 3 ;; -3]Quadratic or higher-order signals are not:
dwt = LiftingWaveletTransform[{1, 4, 9, 16}, DaubechiesWavelet[2], 1]InverseWaveletTransform[dwt, Automatic, {0}]
satisfies the recursion equation 
:
ϕ = WaveletPhi[DaubechiesWavelet[2]];a = WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalLowpass"];Plot the components and the sum of the recursion:
scalet[x_, ϕ_, a_] := 2 Table[a[[i, 2]] ϕ[2 x - a[[i, 1]]], {i, Length[a]}]{Plot[Evaluate[scalet[x, ϕ, a]], {x, 0, 3}, PlotRange -> All], Plot[Total[scalet[x, ϕ, a]], {x, 0, 3}, PlotRange -> All]}
satisfies the recursion equation 
:
ϕ = WaveletPhi[DaubechiesWavelet[2]];b = WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalHighpass"];Plot the components and the sum of the recursion:
wavelet[x_, ϕ_, b_] := 2 Table[b[[i, 2]] ϕ[2 x - b[[i, 1]]], {i, Length[b]}]{Plot[Evaluate[wavelet[x, ϕ, b]], {x, -1, 2}, PlotRange -> All], Plot[Total[wavelet[x, ϕ, b]], {x, -1, 2}, PlotRange -> All]}Frequency response for 
is given by 
:
h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]The filter is a lowpass filter:
Plot[Abs[h[DaubechiesWavelet[2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]The higher the order n, the flatter the response function at the ends:
Plot[{Abs[h[DaubechiesWavelet[2], ω]], Abs[h[DaubechiesWavelet[12], ω]]}, {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]Fourier transform of 
is given by 
:
h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]fh[wav_, ω_, j_] := Abs[Underoverscript[∏, i, j]h[wav, (ω/2^i)]]Plot[fh[DaubechiesWavelet[2], ω, 10], {ω, -10 π, 10 π}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ϕ, ^ ][ω]]}]Frequency response for 
is given by 
:
g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Underoverscript[∑, i, Length[b]]b[[i, 2]] Exp[-I b[[i, 1]] ω]]The filter is a highpass filter:
Plot[Abs[g[DaubechiesWavelet[2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]The higher the order n, the flatter the response function at the ends:
Plot[{Abs[g[DaubechiesWavelet[2], ω]], Abs[g[DaubechiesWavelet[12], ω]]}, {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]Fourier transform of 
is given by 
:
h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Underoverscript[∑, i, Length[b]]b[[i, 2]] Exp[-I b[[i, 1]] ω]]fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)] Underoverscript[∏, i = 2, j]h[wav, (ω/2^i)]]Plot[fg[DaubechiesWavelet[2], ω, 10], {ω, -10 π, 10 π}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ψ, ^ ][ω]]}]Neat Examples (2)
Plot translates and dilations of scaling function:
ϕ[x_, j_, k_] := 2^j / 2 WaveletPhi[DaubechiesWavelet[4], 2^j x - k]Plot[Evaluate[Table[ϕ[x, j, 0], {j, 0, 4}]], {x, 0, 2}, Filling -> Axis, PlotRange -> All]Plot[Evaluate[Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}]], {x, 0, 2}, Filling -> Axis, PlotRange -> All]Plot translates and dilations of wavelet function:
ψ[x_, j_, k_] := 2^j / 2 WaveletPsi[DaubechiesWavelet[4], 2^j x - k]Plot[Evaluate[Table[ψ[x, j, 0], {j, 0, 4}]], {x, 0, 2}, Filling -> Axis, PlotRange -> All]Plot[Evaluate[Table[ψ[x, 2, k], {k, 0, 2^2 - 1}]], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]Text
Wolfram Research (2010), DaubechiesWavelet, Wolfram Language function, https://reference.wolfram.com/language/ref/DaubechiesWavelet.html.
CMS
Wolfram Language. 2010. "DaubechiesWavelet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DaubechiesWavelet.html.
APA
Wolfram Language. (2010). DaubechiesWavelet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DaubechiesWavelet.html