Wolfram Language & System Documentation Center

Area

Area[reg]

gives the area of the two-dimensional region reg.

Area[{x₁,…,x_n},{s,s_min,s_max},{t,t_min,t_max}]

gives the area of the parametrized surface whose Cartesian coordinates x_i are functions of s and t.

Area[{x₁,…,x_n},{s,s_min,s_max},{t,t_min,t_max},chart]

interprets the x_i as coordinates in the specified coordinate chart.

Details and Options

Area is also known as surface area.
A two-dimensional region can be embedded in any dimension greater than or equal to two.

In Area[x,{s,s_min,s_max},{t,t_min,t_max}], if x is a scalar, Area returns the area of the parametric surface {s,t,x}.
Coordinate charts in the fourth argument of Area can be specified as triples {coordsys,metric,dim} in the same way as in the first argument of CoordinateChartData. The short form in which dim is omitted may be used.
The following options can be given:

AccuracyGoal	Infinity	digits of absolute accurary sought
Assumptions	$Assumptions	assumptions to make about parameters
GenerateConditions	Automatic	whether to generate conditions on parameters
PerformanceGoal	$PerformanceGoal	aspects of performance to try to optimize
PrecisionGoal	Automatic	digits of precision sought
WorkingPrecision	Automatic	the precision used in internal computations

Symbolic limits of integration are assumed to be real and ordered. Symbolic coordinate chart parameters are assumed to be in range given by the "ParameterRangeAssumptions" property of CoordinateChartData.
Area can be used with symbolic regions in GeometricScene.

Examples

open all close all

Basic Examples (4)

The area of a disk:

Wolfram Language code: Area[Disk[]]

The surface area of a sphere:

Wolfram Language code: Area[Sphere[]]

The area of an annulus with inner radius 1 and outer radius 2:

Wolfram Language code: Area[{r Sin[θ], r Cos[θ]}, {r, 1, 2}, {θ, 0, 2Pi}]

The surface area of the open cylinder , expressed in cylindrical coordinates:

Wolfram Language code: Area[{1, t, z}, {z, 0, 1}, {t, 0, 2Pi}, "Cylindrical"]

Scope (23)

Special Regions (5)

Rectangle:

Wolfram Language code: Region[Rectangle[{0, 0}, {2, 1}]]

Wolfram Language code: Area[Rectangle[{Subscript[l, x], Subscript[l, y]}, {Subscript[u, x], Subscript[u, y]}]]

Parallelogram:

Wolfram Language code: Region[Parallelogram[{0, 0}, {{2, 0}, {1, 2}}]]

Wolfram Language code:

Area[Parallelogram[{Subscript[p, x], Subscript[p, y]}, {{Subscript[u, x], Subscript[u, y]}, {Subscript[v, x], Subscript[v, y]}}]]

Simplex:

Wolfram Language code: Region[Simplex[2]]

Wolfram Language code: Area[Simplex[2]]

Area is defined for a 2D Simplex embedded in any dimension:

Wolfram Language code: Area[Simplex[{{0, 0, 0, 0}, {0, 1, 1, 0}, {1, 0, 0, 1}}]]

The area of a Polygon:

Wolfram Language code: ℛ = Polygon[{{0, 0}, {2, -1}, {1, 0}, {2, 1}}];

Wolfram Language code: Region[ℛ]

Wolfram Language code: Area[ℛ]

In 3D:

Wolfram Language code: ℛ = Polygon[{{0, 0, 0}, {(5/3), (2/3), -(4/3)}, {(2/3), (2/3), -(1/3)}, {1, 2, 0}}];

Wolfram Language code: Region[ℛ]

Wolfram Language code: Area[ℛ]

Disk:

Wolfram Language code: Region[Disk[{0, 0}, 1]]

Wolfram Language code: Area[Disk[{Subscript[c, x], Subscript[c, y]}, r]]

Disk can be used as an ellipse:

Wolfram Language code: Region[Disk[{0, 0}, {3, 2}]]

Wolfram Language code: Area[Disk[{Subscript[c, x], Subscript[c, y]}, {Subscript[r, x], Subscript[r, y]}]]

The Area of a Sphere is its surface area:

Wolfram Language code: Region[Sphere[]]

Wolfram Language code: Area[Sphere[]]

Wolfram Language code: Area[Sphere[{Subscript[c, x], Subscript[c, y], Subscript[c, z]}, r]]

Formula Regions (2)

The area of a disk represented as an ImplicitRegion:

Wolfram Language code: Area[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]]

The surface area of a sphere:

Wolfram Language code: Area[ImplicitRegion[x^2 + y^2 + z^2 == 1, {x, y, z}]]

The area of a disk represented as a ParametricRegion:

Wolfram Language code: Area[ParametricRegion[{r Cos[θ], r Sin[θ]}, {{r, 0, 1}, {θ, 0, 2π}}]]

Using a rational parameterization of the disk:

Wolfram Language code: Area[ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2)}, {t, {r, 0, 1}}]]

The surface area of a sphere:

Wolfram Language code: Area[ParametricRegion[{Cos[θ]Cos[ϕ], Sin[θ]Cos[ϕ], Sin[ϕ]}, {{θ, 0, 2π}, {ϕ, -π / 2, π / 2}}]]

Mesh Regions (2)

The area of a MeshRegion:

Wolfram Language code: DelaunayMesh[RandomReal[1, {10, 2}]]

Wolfram Language code: Area[%]

A 2D mesh embedded in 3D:

Wolfram Language code: MeshRegion[{{0, 0, 0}, {0, 0, 1}, {0, 1, 0}, {1, 0, 0}}, {Polygon[{{1, 2, 3}, {1, 2, 4}, {1, 3, 4}}]}]

Wolfram Language code: Area[%]

The area of a BoundaryMeshRegion:

Wolfram Language code: ConvexHullMesh[RandomReal[1, {10, 2}]]

Wolfram Language code: Area[%]

Derived Regions (3)

The area of a RegionIntersection:

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{1, 0}, 1]];

Wolfram Language code: Show[Graphics[{LightBlue, EdgeForm[Gray], Disk[{0, 0}, 1], Disk[{1, 0}, 1]}], HighlightMesh[DiscretizeRegion[ℛ], 2]]

Wolfram Language code: Area[ℛ]

The measure of a TransformedRegion:

Wolfram Language code: ℛ = TransformedRegion[Disk[], ScalingTransform[{a, b}]];

Wolfram Language code: Region[ℛ /. {a -> 3, b -> 2}]

Wolfram Language code: Area[ℛ]

The surface area of a RegionBoundary:

Wolfram Language code: ℛ = RegionBoundary[Ball[]]

Wolfram Language code: Region[ℛ]

Wolfram Language code: Area[ℛ]

Parametric Formulas (6)

The area of an ellipse with semimajor axes 2 and 1:

Wolfram Language code: Area[{2r Sin[θ], r Cos[θ]}, {r, 0, 1}, {θ, 0, 2Pi}]

Wolfram Language code: ParametricPlot[{2r Sin[θ], 1r Cos[θ]}, {r, 0, 1}, {θ, 0, 2Pi}]

The area of a half-cone at in spherical coordinates:

Wolfram Language code: Area[{r, Pi / 4, t}, {r, 0, 1}, {t, 0, Pi} , "Spherical"]

Wolfram Language code: ParametricPlot3D[CoordinateTransform[ "Spherical" -> "Cartesian", {r, Pi / 4, t}]//Evaluate, {r, 0, 1}, {t, 0, Pi}]

The surface area of a torus of major radius 5 and minor radius 2:

Wolfram Language code: Area[{(5 + 2Sin[p])Cos[t], (5 + 2Sin[p])Sin[t], 2Cos[p]}, {t, 0, 2Pi}, {p, 0, 2Pi} ]

Wolfram Language code: ParametricPlot3D[{(5 + 2Sin[p])Cos[t], (5 + 2Sin[p])Sin[t], 2Cos[p]}, {t, 0, 2Pi}, {p, 0, 2Pi} ]

The area of a "flat torus" embedded in four-dimensional space:

Wolfram Language code: Area[{5Sin[t], 5Cos[t], 2Sin[p], 2Cos[p]}, {t, 0, 2Pi}, {p, 0, 2Pi}]

The area of the paraboloid over the rectangle :

Wolfram Language code: Area[x ^ 2 + y ^ 2, {x, -2, 2}, {y, -3, 3}]

Wolfram Language code: Plot3D[x ^ 2 + y ^ 2, {x, -2, 2.}, {y, -3, 3.}]

The area of a surface in a three-sphere using stereographic coordinates:

Wolfram Language code: Area[{t, s, s}, {t, 0, ∞}, {s, 0, 1}, {"Stereographic", {"Sphere", 2}}]

Geographic Regions (3)

The area of a polygon with GeoPosition:

Wolfram Language code:

ℛ = Polygon[GeoPosition[{{{40.083441, -88.235716}, {40.083607, -88.257488}, {40.082603, -88.257149}, 
   {40.076136999999996, -88.25740499999999}, {40.076178, -88.270888}, {40.076516, -88.271558}, 
   {40.083686, -88.271512}, {40.083659999999995, -88.267046},  ... 33323}, {40.098112, -88.228687}, 
   {40.095216, -88.228627}, {40.095179, -88.238547}, {40.094480999999995, -88.238546}, 
   {40.094508999999995, -88.23267}, {40.094106, -88.232556}, {40.090666999999996, -88.232477}, 
   {40.090741, -88.235745}}}]];

Wolfram Language code: Area[ℛ]

The area of a polygon with GeoGridPosition:

Wolfram Language code:

ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015}, 
   {-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167}, 
   {-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449}, 
   {-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654}, 
   {-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825}, 
   {-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];

Wolfram Language code: Area[ℛ]

Area works on polygons with geographic entities:

Wolfram Language code: ℛ = Polygon[["france"]];

Wolfram Language code: Area[ℛ]

CSG Regions (1)

The area of a linear CSGRegion:

Wolfram Language code: CSGRegion["Difference", {Rectangle[], Rectangle[{1 / 2, 1 / 2}]}]

Wolfram Language code: Area[%]

Nonlinear:

Wolfram Language code: CSGRegion["Difference", {Disk[], Disk[{1 / 2, 1 / 2}]}]

Wolfram Language code: Area[%]

Subdivision Regions (1)

The area of a SubdivisionRegion in 2D:

Wolfram Language code: SubdivisionRegion[Rectangle[]]

Wolfram Language code: Area[%]

3D:

Wolfram Language code: SubdivisionRegion[RegionBoundary[Cube[]]]

Wolfram Language code: Area[%]

Options (6)

AccuracyGoal (1)

Consider a region whose area is difficult to compute exactly:

Wolfram Language code: Region[ℛ = ImplicitRegion[x ^ 2 + y ^ 2 <= Cos[x y], {x, y}]]

Wolfram Language code: area1 = Area[ℛ]

The AccuracyGoal option can be used to change the default absolute tolerance. Here, the area computation stops once the accuracy goal criterion has been exceeded:

Wolfram Language code: area2 = Area[ℛ, AccuracyGoal -> 8]

The result with the default settings is different since the default uses only a precision criterion:

Wolfram Language code: area1 - area2

Assumptions (1)

The area of an ellipse with arbitrary semimajor axes and :

Wolfram Language code: Area[{r, v}, {r, 0, ArcSech[Sqrt[1 - (b^2/a^2)]]}, {v, 0, 2Pi}, {{"Elliptic", Sqrt[a^2 - b^2]}}]

Adding an assumption that the semimajor axes are positive simplifies the answer:

Wolfram Language code:

Area[{r, v}, {r, 0, ArcSech[Sqrt[1 - (b^2/a^2)]]}, {v, 0, 2Pi}, {{"Elliptic", Sqrt[a^2 - b^2]}}, Assumptions -> a > 0 && b > 0]

PrecisionGoal (1)

The number of effective digits of precision that should be sought can be specified with PrecisionGoal:

Wolfram Language code: Table[Area[ImplicitRegion[x ^ 6 + y ^ 6 - x y <= 1, {x, y}], PrecisionGoal -> prec], {prec, 1, 14}]

Plot the areas computed for various precision settings:

Wolfram Language code: ListPlot[%, PlotRange -> All]

PerformanceGoal (1)

Consider a region whose area is difficult to compute exactly:

Wolfram Language code: Region[ℛ = ImplicitRegion[x ^ 2 + y ^ 2 <= Cos[x y], {x, y}]]

Use PerformanceGoal"Speed" to attempt to compute an area quickly:

Wolfram Language code: (area1 = Area[ℛ, PerformanceGoal -> "Speed"])//Timing

Use PerformanceGoal"Performance" to attempt to compute a result with as many correct digits as possible:

Wolfram Language code: (area2 = Area[ℛ, PerformanceGoal -> "Quality"])//Timing

WorkingPrecision (2)

Compute the Area using machine arithmetic:

Wolfram Language code: Area[ImplicitRegion[x ^ 6 + y ^ 6 - x y <= 1, {x, y}], WorkingPrecision -> MachinePrecision]

In some cases, the exact answer cannot be computed:

Wolfram Language code: Area[ImplicitRegion[x ^ 6 + y ^ 6 - x y <= 1, {x, y}]]

Find the Area using 30 digits of precision:

Wolfram Language code: Area[{a Cos[t], a Sin[t], a Sin[t]}, {t, 0, 2Pi}, {a, 0, 1}, WorkingPrecision -> 30]

Find the Area using infinite precision:

Wolfram Language code: Area[{a Cos[t], a Sin[t], a Sin[t]}, {t, 0, 2Pi}, {a, 0, 1}, WorkingPrecision -> ∞]

Applications (4)

The area of a function surface :

Wolfram Language code: 𝒮 = ParametricRegion[{x, y, x y}, {{x, 0, 1}, {y, 0, 1}}];

The region is a surface:

Wolfram Language code: RegionDimension[𝒮]

Wolfram Language code: Area[𝒮]

Equivalently:

Wolfram Language code: Area[x y, {x, 0, 1}, {y, 0, 1}]

Find the average density of a region with density given by :

Wolfram Language code: ℛ = Simplex[2];

Wolfram Language code: Integrate[x^2y^3, {x, y}∈ℛ] / Area[ℛ]

Compute the surface area of a polyhedron:

Wolfram Language code: p = PolyhedronData["SnubDodecahedron"];

Wolfram Language code: ℛ = DiscretizeGraphics[p]

PolyhedronData gives a surface, not a solid, so Area can be used:

Wolfram Language code: RegionDimension[ℛ]

Wolfram Language code: Area[ℛ]

Compute the surface area of a Solomon seal knot:

Wolfram Language code: g = Graphics3D[KnotData["SolomonSeal", "ImageData"]];

Wolfram Language code: ℛ = DiscretizeGraphics[g]

The region is a surface in 3D:

Wolfram Language code: RegionDimension[ℛ]

Wolfram Language code: Area[ℛ]

Properties & Relations (5)

Area is a non-negative quantity:

Wolfram Language code: Area[{Cos[φ]Sin[θ], Sin[φ]Sin[θ], Cos[θ]}, {θ, 0, π}, {φ, 0, 2Pi}]

Wolfram Language code: Area[{Cos[φ]Sin[θ], Sin[φ]Sin[θ], Cos[θ]}, {θ, 0, π}, {φ, 0, -2Pi}]

Area[r] is the same as RegionMeasure[r] for 2D regions:

Wolfram Language code:

ℛ = Simplex[2];
{Area[ℛ], RegionMeasure[ℛ]}

Embedded in 3D:

Wolfram Language code:

ℛ = Polygon[{{0, 0, 1}, {0, 1, 0}, {1, 0, 0}}];
{Area[ℛ], RegionMeasure[ℛ]}

Area[x,s,t,c] is equivalent to RegionMeasure[x,{s,t},c]:

Wolfram Language code: Area[{s t ^ 2, Pi / 2, Pi / 4, s t}, {s, 0, 1}, {t, 0, 2Pi}, "Hyperspherical"]

Wolfram Language code: RegionMeasure[{s t ^ 2, Pi / 2, Pi / 4, s t}, {{s, 0, 1}, {t, 0, 2Pi}}, "Hyperspherical"]

For a 2D region, Area is the integral of 1 over the region:

Wolfram Language code:

ℛ = Disk[];
{Area[ℛ], Integrate[1, x∈ℛ]}

Embedded in 3D:

Wolfram Language code:

ℛ = Sphere[];
{Area[ℛ], Integrate[1, x∈ℛ]}

To get the surface area of a 3D region, use RegionBoundary:

Wolfram Language code: ℛ = DelaunayMesh[RandomReal[1, {20, 3}]]

Wolfram Language code: Area[RegionBoundary[ℛ]]

Possible Issues (2)

The parametric form of Area computes the area of possibly multiple coverings:

Wolfram Language code: Area[{Cos[φ]Sin[θ], Sin[φ]Sin[θ], Cos[θ]}, {θ, 0, π}, {φ, 0, 4Pi}]

The region version computes the area of the image:

Wolfram Language code: Area[ParametricRegion[{Cos[φ]Sin[θ], Sin[φ]Sin[θ], Cos[θ]}, {{θ, 0, π}, {φ, 0, 4Pi}}]]

Wolfram Language code: Area[Sphere[{0, 0, 0}, 1]]

The area of a region of dimension other than two is Undefined:

Wolfram Language code: {Area[Point[{0, 0}]], Area[Line[{{0, 0}, {1, 1}}]], Area[Ball[]]}

Wolfram Language code: RegionDimension /@ {Point[{0, 0}], Line[{{0, 0}, {1, 1}}], Ball[]}

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

Area

Details and Options

Examples

Basic Examples (4)

Scope (23)

Special Regions (5)

Formula Regions (2)

Mesh Regions (2)

Derived Regions (3)

Parametric Formulas (6)

Geographic Regions (3)

CSG Regions (1)

Subdivision Regions (1)

Options (6)

AccuracyGoal (1)

Assumptions (1)

PrecisionGoal (1)

PerformanceGoal (1)

WorkingPrecision (2)

Applications (4)

Properties & Relations (5)

Possible Issues (2)

Text

CMS

APA

BibTeX

BibLaTeX

Area

Details and Options

Examples

Basic Examples (4)

Scope (23)

Special Regions (5)

Formula Regions (2)

Mesh Regions (2)

Derived Regions (3)

Parametric Formulas (6)

Geographic Regions (3)

CSG Regions (1)

Subdivision Regions (1)

Options (6)

AccuracyGoal (1)

Assumptions (1)

PrecisionGoal (1)

PerformanceGoal (1)

WorkingPrecision (2)

Applications (4)

Properties & Relations (5)

Possible Issues (2)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX