WOLFRAM

Wolfram Language & System Documentation Center

DihedralAngle[{p1,p2},{v,w}]

gives the angle between two half-planes bounded by the line through p1 and p2 and extended in the direction v and w.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

DihedralAngle

DihedralAngle[{p1,p2},{v,w}]

gives the angle between two half-planes bounded by the line through p1 and p2 and extended in the direction v and w.

Details

  • DihedralAngle is also known as face angle or torsion angle.
  • DihedralAngle[{p1,p2},{v,w}] is the length of the arc of the unit circle Circle[p1] on the plane with normal p2-p1 and delimited by the half‐planes HalfPlane[{p1,p2},v] and HalfPlane[{p1,p2},w].

Examples

open all close all

Basic Examples  (1)

The angle between the half‐planes:

Wolfram Language code: DihedralAngle[{{0, 0, 0}, {0, 1, 0}}, {{1, 0, 1}, {1, 0, 0}}]
Wolfram Language code: Graphics3D[{HalfPlane[{{0, 0, 0}, {0, 1, 0}}, {1, 0, 1}], HalfPlane[{{0, 0, 0}, {0, 1, 0}}, {1, 0, 0}]}]

Scope  (2)

Use DihedralAngle to find the angle between two half‐planes:

Wolfram Language code: DihedralAngle[{{0, 0, 0}, {0, 1, 0}}, {{1, 0, 1}, {1, 0, 0}}]
Wolfram Language code: Graphics3D[{HalfPlane[{{0, 0, 0}, {0, 1, 0}}, {1, 0, 1}], HalfPlane[{{0, 0, 0}, {0, 1, 0}}, {1, 0, 0}]}]

DihedralAngle works with numeric arguments:

Wolfram Language code: DihedralAngle[{{0, 1, 0}, {0, 0, 0}}, {{1, 0, 1}, {1, 0, 0}}]

Symbolic arguments:

Wolfram Language code: DihedralAngle[{{0, 1, 0}, {0, 0, 0}}, {{a, b, c}, {1, 0, 0}}]

Applications  (1)

Torsion angle in chloral:

Wolfram Language code: coords = QuantityMagnitude[ChemicalData["Chloral", "AtomPositions"]];
Wolfram Language code: Show[{ChemicalData["Chloral", "MoleculePlot"], Graphics3D[Table[Style[Text[i, coords[[i]]], Bold], {i, Length[coords]}]]}]

Torsion angle in a chain of atoms Cl-C-C-O:

Wolfram Language code: DihedralAngle[coords[[{5, 6}]], {Subtract@@coords[[{3, 5}]], Subtract@@coords[[{4, 6}]]}]

Properties & Relations  (2)

Dihedral angle is the planar angle in the plane defined by the normal p2-p1 and a point p1.

Wolfram Language code: p1 = {0, 0, 0};p2 = {0, 0, 1}; v = {1, 0, 0};w = {0, 1, 0};
Wolfram Language code: DihedralAngle[{p1, p2}, {v, w}]
Wolfram Language code: PlanarAngle[p1[[1 ;; 2]] -> {v, w}[[All, 1 ;; 2]]]

DihedralAngle[{p1,p2},{v,w}] is equivalent to PolyhedronAngle[ℛ,{p1,p2}], where v and w are vectors in adjacent faces of {p1,p2} in a polyhedron ℛ:

Wolfram Language code: ℛ = Polyhedron[{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}, {1, 0, 0}, {0, 0, 1}, {0, 1, 1}, {1, 1, 1}, {1, 0, 1}}, {{2, 3, 4, 1}, {1, 4, 8, 5}, {4, 3, 7, 8}, {3, 2, 6, 7}, {2, 1, 5, 6}, {5, 8, 7, 6}}];
Wolfram Language code: p1 = {0, 0, 0};p2 = {0, 1, 0};
Wolfram Language code: {v, w} = {{0, 0, 1}, {1, 0, 0}} - {p1, p1};
Wolfram Language code: {PolyhedronAngle[ℛ, {p1, p2}], DihedralAngle[{p1, p2}, {v, w}]}
Wolfram Language code: Graphics3D[{{Opacity[.5], Green, ℛ}, Thickness[.05], Red, Line[{{p1, p1 + v}, {p1, p1 + w}}], Blue, Line[{p1, p2}]}]

Possible Issues  (1)

DihedralAngle gives generic values for symbolic parameters:

Wolfram Language code: DihedralAngle[{{0, 1, 0}, {0, 0, a}}, {{1, 0, 1}, {1, 0, 0}}]
Wolfram Research (2019), DihedralAngle, Wolfram Language function, https://reference.wolfram.com/language/ref/DihedralAngle.html.

Text

Wolfram Research (2019), DihedralAngle, Wolfram Language function, https://reference.wolfram.com/language/ref/DihedralAngle.html.

CMS

Wolfram Language. 2019. "DihedralAngle." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DihedralAngle.html.

APA

Wolfram Language. (2019). DihedralAngle. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DihedralAngle.html

BibTeX

@misc{reference.wolfram_2026_dihedralangle, author="Wolfram Research", title="{DihedralAngle}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/DihedralAngle.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_dihedralangle, organization={Wolfram Research}, title={DihedralAngle}, year={2019}, url={https://reference.wolfram.com/language/ref/DihedralAngle.html}, note=[Accessed: 12-June-2026]}