WOLFRAM

Wolfram Language & System Documentation Center

PlanarAngle[p{q1,q2}]

gives the angle between the half‐lines from p through q1 and q2.

PlanarAngle[{q1,p,q2}]

gives the angle at p formed by the triangle with vertex points p, q1 and q2.

PlanarAngle[…,"spec"]

gives the angle specified by "spec".

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Specifications  
"Counterclockwise"  
"Clockwise"  
"Interior"  
"Exterior"  
"FullExterior"  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

PlanarAngle

PlanarAngle[p{q1,q2}]

gives the angle between the half‐lines from p through q1 and q2.

PlanarAngle[{q1,p,q2}]

gives the angle at p formed by the triangle with vertex points p, q1 and q2.

PlanarAngle[…,"spec"]

gives the angle specified by "spec".

Details

  • PlanarAngle is also known as angle.
  • PlanarAngle[p{q1,q2}] gives the length of the arc of the unit circle Circle[p] delimited by the half-line from p through q1 on the left and the half-line from p to q2 on the right.
  • Two half‐lines from p through q1 and q2 delimit two angles α1 and α2 at p.
  • The following specifications "spec" can be given:
  • "Counterclockwise"angle formed by the counterclockwise rotation from q1 to q2
    "Clockwise"angle formed by the clockwise rotation from q1 to q2
  • PlanarAngle[p{q1,q2},"Counterclockwise"] is equivalent to PlanarAngle[p{q1,q2}].
  • PlanarAngle[p{q1,q2},"Clockwise"] is equivalent to PlanarAngle[p{q2,q1}].
  • PlanarAngle[{q1,p,q2}] is the angle subtended by the line segment q1 q2 from p.
  • The triangle with vertex points q1, p and q2 defines three angles α1, α2 and α3 at p.
  • The following specifications "spec" can be given:
  • "Interior"interior (inside) angle of the triangle at p
    "Exterior"exterior angle of the triangle at p
    "FullExterior"full exterior angle of the triangle at p
  • PlanarAngle[{q1,p,q2},"Interior"] is equivalent to PlanarAngle[{q1,p,q2}].
  • PlanarAngle[{q1,p,q2},"Exterior"] is equivalent to π-PlanarAngle[{q1,p,q2}].
  • PlanarAngle[{q1,p,q2},"FullExterior"] is equivalent to 2π-PlanarAngle[{q1,p,q2}].
  • With the specification "Interior", "Exterior" or "FullExterior", PlanarAngle[p{q1,q2},"spec"] is taken to be PlanarAngle[{q1,p,q2},"spec"].
  • With the specification "Counterclockwise" or "Clockwise", PlanarAngle[{q1,p,q2},"spec"] is taken to be PlanarAngle[p{q1,q2}, "spec"].
  • PlanarAngle can be used with symbolic points in GeometricScene.

Examples

open all close all

Basic Examples  (2)

The angle between the half‐lines from {0,0} through {1,1} and {1,0}:

Wolfram Language code: PlanarAngle[{0, 0} -> {{1, 0}, {1, 1}}]
Wolfram Language code: Graphics[{Arrow[{{0, 0}, {1, 0}}], Arrow[{{0, 0}, {1, 1}}]}]

The angle formed by a triangle at origin:

Wolfram Language code: PlanarAngle[{{0, 1}, {0, 0}, {1, 0}}]
Wolfram Language code: Graphics[Triangle[{{0, 1}, {0, 0}, {1, 0}}]]

Scope  (7)

Basic Uses  (2)

Use PlanarAngle to find the angle between two half‐lines:

Wolfram Language code: PlanarAngle[{0, 0} -> {{1, 0}, {1, 1}}]
Wolfram Language code: Graphics[{HalfLine[{0, 0}, {1, 0}], HalfLine[{0, 0}, {1, 1}]}]

PlanarAngle works with numeric arguments:

Wolfram Language code: PlanarAngle[{0, 0} -> {{1, 0}, {1, 1}}]

Symbolic arguments:

Wolfram Language code: PlanarAngle[{0, 0} -> {{0, 1}, {1, a}}]

Specifications  (5)

"Counterclockwise"  (1)

The angle formed by a counterclockwise rotation:

Wolfram Language code: PlanarAngle[{0, 0} -> {{1, 0}, {1, 1}}, "Counterclockwise"]
Wolfram Language code: Graphics[{Arrowheads[0.1], Arrow[{{{0, 0}, {1, 0}}, {{0, 0}, {1, 1}}}]}]

"Clockwise"  (1)

The angle formed by a clockwise rotation:

Wolfram Language code: PlanarAngle[{0, 0} -> {{1, 0}, {1, 1}}, "Clockwise"]
Wolfram Language code: Graphics[{Arrowheads[0.1], Arrow[{{{0, 0}, {1, 0}}, {{0, 0}, {1, 1}}}]}]

"Interior"  (1)

The interior angle of a triangle at the origin:

Wolfram Language code: PlanarAngle[{{1, 1}, {0, 0}, {1, 0}}, "Interior"]
Wolfram Language code: Graphics[{FaceForm[], EdgeForm[StandardGray], Triangle[{{1, 1}, {0, 0}, {1, 0}}]}]

"Exterior"  (1)

The exterior angle of a triangle at the origin:

Wolfram Language code: PlanarAngle[{{1, 1}, {0, 0}, {1, 0}}, "Exterior"]
Wolfram Language code: Graphics[{FaceForm[], EdgeForm[StandardGray], Triangle[{{1, 1}, {0, 0}, {1, 0}}]}]

"FullExterior"  (1)

The full exterior angle of a triangle at the origin:

Wolfram Language code: PlanarAngle[{{1, 1}, {0, 0}, {1, 0}}, "FullExterior"]
Wolfram Language code: Graphics[{FaceForm[], EdgeForm[StandardGray], Triangle[{{1, 1}, {0, 0}, {1, 0}}]}]

Applications  (6)

A straight angle:

Wolfram Language code: p = {0, 0};q1 = {1, 0};q2 = {-1, 0};
Wolfram Language code: Graphics[{Arrow[{{p, q1}, {p, q2}}], Point[p]}]

It is an angle of π:

Wolfram Language code: PlanarAngle[p -> {q1, q2}]

An obtuse angle:

Wolfram Language code: p = {0, 0};q1 = {1, 0};q2 = {-1, 1};
Wolfram Language code: Graphics[{Arrow[{{p, q1}, {p, q2}}], Point[p]}]

It is an angle between and π:

Wolfram Language code: PlanarAngle[p -> {q1, q2}]

A right angle:

Wolfram Language code: p = {0, 0};q1 = {1, 0};q2 = {0, 1};
Wolfram Language code: Graphics[{Arrow[{{p, q1}, {p, q2}}], Point[p]}]

It is an angle of :

Wolfram Language code: PlanarAngle[p -> {q1, q2}]

An acute angle:

Wolfram Language code: p = {0, 0};q1 = {1, 0};q2 = {1, 1};
Wolfram Language code: Graphics[{Arrow[{{p, q1}, {p, q2}}], Point[p]}]

It is an angle smaller than :

Wolfram Language code: PlanarAngle[p -> {q1, q2}]

Find the interior angle of a triangle at a point p:

Wolfram Language code: p = {0, 0};q1 = {2, 0};q2 = {1, 1};
Wolfram Language code: ℛ = Triangle[{p, q1, q2}];
Wolfram Language code: Graphics[ℛ]
Wolfram Language code: PlanarAngle[p -> {q1, q2}]

An AASTriangle:

Wolfram Language code: AASTriangle[Pi / 6, Pi / 3, 1]
Wolfram Language code: Graphics[%]

Get the angles:

Wolfram Language code: PlanarAngle[{0, 0} -> {{2, 0}, {(3/2), (Sqrt[3]/2)}}]
Wolfram Language code: PlanarAngle[{2, 0} -> {{(3/2), (Sqrt[3]/2)}, {0, 0}}]
Wolfram Language code: PlanarAngle[{(3/2), (Sqrt[3]/2)} -> {{0, 0}, {2, 0}}]

Properties & Relations  (7)

PlanarAngle[p,{q2,q1}] is equal to 2π-PlanarAngle[p,{q1,q2}]:

Wolfram Language code: PlanarAngle[{2, 1} -> {{1, 1}, {1, 0}}]
Wolfram Language code: 2Pi - PlanarAngle[{2, 1} -> {{1, 0}, {1, 1}}]

PlanarAngle[{q1,p,q2},"Interior"] is the smallest angle formed by the rotations around p:

Wolfram Language code: PlanarAngle[{{1, 1}, {2, 1}, {1, 0}}, "Interior"]
Wolfram Language code: Min[PlanarAngle[{2, 1} -> {{1, 1}, {1, 0}}, #]& /@ {"Counterclockwise", "Clockwise"}]

PlanarAngle[p{q1,q2}] takes values from 0 to 2π:

Wolfram Language code: Table[PlanarAngle[{0, 0} -> {{1, 0}, p}], {p, CirclePoints[{1, 0}, 12]}]

PlanarAngle[{q1,p,q2}] takes values from 0 to π:

Wolfram Language code: Table[PlanarAngle[{{1, 0}, {0, 0}, p}], {p, CirclePoints[{1, 0}, 12]}]

Dihedral angle is the planar angle in the plane defined by the normal p2-p1 and a point p1:

Wolfram Language code: p1 = {0, 0, 0};p2 = {0, 0, 1}; v = {1, 0, 0};w = {0, 1, 0};
Wolfram Language code: DihedralAngle[{p1, p2}, {v, w}]
Wolfram Language code: PlanarAngle[p1[[1 ;; 2]] -> {v[[1 ;; 2]], w[[1 ;; 2]]}]

PlanarAngle[p->{q1,q2}] is equivalent to PolygonAngle[ℛ, p] where q1 and q2 are adjacent points of p in a polygon ℛ:

Wolfram Language code: ℛ = Polygon[{{1., 0.}, {0.5, 0.8}, {-0.5, 0.8}, {-1., 0.}}]
Wolfram Language code: PolygonAngle[ℛ, {0.5, 0.8}]
Wolfram Language code: PlanarAngle[{0.5, 0.8} -> {{-0.5, 0.8}, {1., 0.}}]

PlanarAngle[{q1,p,q2}] is equivalent to SolidAngle[p,{q1,q2}]:

Wolfram Language code: PlanarAngle[{{1, 0}, {0, 0}, {1, 1}}]
Wolfram Language code: SolidAngle[{0, 0}, {{1, 0}, {1, 1}}]
Wolfram Language code: Graphics[Arrow[{{0, 0}, #}]& /@ {{1, 0}, {1, 1}}]

Possible Issues  (1)

PlanarAngle gives generic values for symbolic parameters:

Wolfram Language code: PlanarAngle[{0, 0} -> {{1, 0}, {0, a}}]
Wolfram Research (2019), PlanarAngle, Wolfram Language function, https://reference.wolfram.com/language/ref/PlanarAngle.html.

Text

Wolfram Research (2019), PlanarAngle, Wolfram Language function, https://reference.wolfram.com/language/ref/PlanarAngle.html.

CMS

Wolfram Language. 2019. "PlanarAngle." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PlanarAngle.html.

APA

Wolfram Language. (2019). PlanarAngle. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PlanarAngle.html

BibTeX

@misc{reference.wolfram_2026_planarangle, author="Wolfram Research", title="{PlanarAngle}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/PlanarAngle.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_planarangle, organization={Wolfram Research}, title={PlanarAngle}, year={2019}, url={https://reference.wolfram.com/language/ref/PlanarAngle.html}, note=[Accessed: 13-June-2026]}