Wolfram Language & System Documentation Center

ElectricCurrentDensityValue

ElectricCurrentDensityValue[pred,vars,pars]

represents a current density boundary condition for PDEs with predicate pred indicating where it applies, with model variables vars and global parameters pars.

ElectricCurrentDensityValue[pred,vars,pars,lkey]

represents a current density boundary condition with local parameters specified in pars[lkey].

Details

ElectricCurrentDensityValue specifies a boundary condition for ElectricCurrentPDEComponent and is used as part of the modeling equation:

ElectricCurrentDensityValue is used to model an electric current density in [ $TemplateBox[{InterpretationBox[, 1], {"A", , "/", , {"m", ^, 2}}, amperes per meter squared, {{(, "Amperes", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ], normal to the boundary, that enters or leaves through a boundary.
A positive value denotes an inward electric flow, and a negative value denotes an outward flow.
ElectricCurrentDensityValue models an electric current density , normal to the boundary, with dependent variable in volts [] and independent variables in [].
Stationary variables vars are vars={V[x₁,…,x_n],{x₁,…,x_n}}.
Frequency-dependent variables vars are vars={V[x₁,…,x_n],ω,{x₁,…,x_n}}.
ElectricCurrentDensityValue with a specified scalar electric current density , normal to the boundary, models:

ElectricCurrentDensityValue with a specified electric current density vector [ $TemplateBox[{InterpretationBox[, 1], {"A", , "/", , {"m", ^, 2}}, amperes per meter squared, {{(, "Amperes", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ], models:

with a unit normal.
ElectricCurrentDensityValue with a specified current [], normal to the boundary, models:

with [ $TemplateBox[{InterpretationBox[, 1], {{"m", ^, 2}}, meters squared, {"Meters", ^, 2}}, QuantityTF]$ ] the boundary area. Currents are automatically converted to a normal electric current density .
Model parameters pars are specified as for ElectricCurrentPDEComponent.
The following additional model parameters pars can be given:

parameter	default	symbol
"BoundaryUnitNormal"	Automatic
"Current"		, electric current in []
"CurrentDensity"	{0,...}	, electric current density in [ $TemplateBox[{InterpretationBox[, 1], {"A", , "/", , {"m", ^, 2}}, amperes per meter squared, {{(, "Amperes", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]
"NormalCurrentDensity"		, normal electric current density in [ $TemplateBox[{InterpretationBox[, 1], {"A", , "/", , {"m", ^, 2}}, amperes per meter squared, {{(, "Amperes", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]
"Thickness"	-	, thickness in []

All model parameters may depend on the spatial variables .
In two dimensions, the parameter "Thickness" is taken into account to convert the current from units [] to [ $TemplateBox[{InterpretationBox[, 1], {"A", , "/", , {"m", ^, 2}}, amperes per meter squared, {{(, "Amperes", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ].
To localize model parameters, a key lkey can be specified and values from association pars[lkey] are used for model parameters.
A prescribed electric current density boundary condition can be used with:
analysis type applicable

Frequency response Yes

Stationary Yes
ElectricCurrentDensityValue evaluates to a NeumannValue.
The boundary predicate pred can be specified as in NeumannValue.
If the ElectricCurrentDensityValue depends on parameters that are specified in the association pars as …,keyp_i…,p_iv_i,…, the parameters are replaced with .

Examples

open all close all

Basic Examples (3)

Set up a symbolic electric current density boundary condition:

Wolfram Language code: ElectricCurrentDensityValue[x >= 0, {V[x, y], {x, y}}, <|"NormalCurrentDensity" -> Jn|>]

Set up a symbolic electric current density boundary condition with a current density:

Wolfram Language code: ElectricCurrentDensityValue[x >= 0, {V[x, y], {x, y}}, <|"CurrentDensity" -> {J0x, J0y}|>]

Model a copper wire that is excited with a direct current (DC) of [] with a current density boundary condition at the lower-left boundary and with a zero electric potential condition at the lower-right boundary.

Set up the stationary current PDE model variables and :

Wolfram Language code:

vars = {V[x, y], {x, y}};
pars = <|"Material" -> Entity["Element", "Copper"]|>;

Set up the equation:

Wolfram Language code: op = ElectricCurrentPDEComponent[vars, pars];

Define the geometry of the wire:

Wolfram Language code: Ω = RegionUnion[Rectangle[{0, 0}, {1 / 3, 1}], Rectangle[{1 / 3, 2 / 3}, {2, 1}], Rectangle[{2 - 1 / 3, 0}, {2, 1}]];

Visualize the wire:

Wolfram Language code: RegionPlot[Ω]

Specify ground potential at the lower-right boundary:

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[x >= 2 - 1 / 3 && y == 0, vars, pars, <|"ElectricPotential" -> 0|>];

Specify an inward current flow at the lower-left boundary:

Wolfram Language code: Subscript[Γ, source] = ElectricCurrentDensityValue[x <= 1 / 3 && y == 0, vars, pars, <|"Current" -> 1|>];

Solve the PDE:

Wolfram Language code: Vfun = NDSolveValue[{op == Subscript[Γ, source], Subscript[Γ, ground]}, V, {x, y}∈Ω]

Visualize the electric potential:

Wolfram Language code: DensityPlot[Vfun[x, y], {x, y}∈Ω, ...]

Scope (6)

Create an electric current density boundary condition:

Wolfram Language code: ElectricCurrentDensityValue[x == 0, {V[x, y, z], {x, y, z}}, <|"CurrentDensity" -> {10, 0, 0}|>]

Create an electric current density boundary condition with a boundary unit normal :

Wolfram Language code: ElectricCurrentDensityValue[x == 0, {V[x, y], {x, y}}, <|"CurrentDensity" -> {10, 0}, "BoundaryUnitNormal" -> {-1, 0}|>]

Create an electric current density boundary condition with :

Wolfram Language code: ElectricCurrentDensityValue[x == 0, {V[x, y, z], {x, y, z}}, <|"NormalCurrentDensity" -> Jn|>]

Create an electric current density boundary condition with a current :

Wolfram Language code: ElectricCurrentDensityValue[x == 0, {V[x, y, z], {x, y, z}}, <|"Current" -> I0|>]

Create an electric current density boundary condition in 2D with a current and a thickness :

Wolfram Language code:

ElectricCurrentDensityValue[x == 0, {V[x, y], {x, y}}, <|"ElectricalConductivity" -> σ, "Thickness" -> d|>, <|"Current" -> I0|>]

Create a parametric-frequency electric current density boundary condition:

Wolfram Language code: ElectricCurrentDensityValue[x == 0, {V[x, y, z], ω, {x, y, z}}, <|"Current" -> (4I0 Subscript[ω, 0]/ π ω)|>]

Applications (2)

3D Stationary Analysis (1)

Model a copper spiral inductor that is excited with a current density normal to the left boundary and has a zero electric potential boundary condition at the right boundary.

Define the spiral inductor geometry:

Wolfram Language code:

Ω = RegionUnion[Cuboid[{0, 0, 0}, {2, 1, 1}], Cuboid[{1, 1, 0}, {2, 8, 1}], Cuboid[{2, 7, 0}, {8, 8, 1}], Cuboid[{7, 7, 0}, {8, 0, 1}], Cuboid[{7, 0, 0}, {3, 1, 1}], Cuboid[{3, 1, 0}, {4, 6, 1}], Cuboid[{4, 6, 0}, {6, 5, 1}], Cuboid[{6, 5, 0}, {5, 2, 1}], Cuboid[{5, 2, 1}, {6, 3, 1.2}], Cuboid[{5, 2, 1.2}, {10, 3, 2.2}]]

Set up the stationary current PDE model variables and :

Wolfram Language code:

vars = {V[x, y, z], {x, y, z}};
pars = <|"Material" -> Entity["Element", "Copper"]|>;

Specify an inward current flow on the left boundary:

Wolfram Language code: Subscript[Γ, source] = ElectricCurrentDensityValue[x == 0, vars, pars, <|"NormalCurrentDensity" -> 10|>];

Specify a ground potential:

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[x == 10, vars, pars];

Solve the PDE:

Wolfram Language code:

Vfun = NDSolveValue[{ElectricCurrentPDEComponent[vars, pars] == Subscript[Γ, source], Subscript[Γ, ground]}, V, {x, y, z}∈Ω]

Compute the current density vector:

Wolfram Language code: Jfield = -QuantityMagnitude[pars["Material"]["ElectricalConductivity"]] * Grad[Vfun[x, y, z], {x, y, z}];

Visualize the current density magnitude:

Wolfram Language code:

SliceDensityPlot3D[Sqrt[Total[Jfield ^ 2]], {{"XStackedPlanes", 10}, {"YStackedPlanes", 10}, {"ZStackedPlanes", 5}}, {x, y, z}∈Ω, ...]

Frequency Analysis (1)

Model a dielectric material of a cylindrical capacitor that is excited with an alternating current (AC ) of [], with a current density boundary condition at the upper boundary, which represents one of the capacitor electrodes, and with a zero electric potential boundary condition at the lower boundary.

Set up the frequency current PDE model variables :

Wolfram Language code: vars = {V[x, y, z], ω, {x, y, z}};

Define the frequency and the period:

Wolfram Language code:

f0 = 60;
T0 = 1 / f0;

Set up a region :

Wolfram Language code:

r0 = 0.01;
h = 0.001;
Ω = Cylinder[{{0, 0, 0}, {0, 0, h}}, r0];

Specify an electrical conductivity and a relative permittivity :

Wolfram Language code: pars = <|"ElectricalConductivity" -> 1*^-8, "RelativePermittivity" -> 2|>;

Specify the ground potential at the lower boundary:

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[z == 0, vars, pars];

Specify an inward current flow at the upper boundary:

Wolfram Language code: Subscript[Γ, current] = ElectricCurrentDensityValue[z == h, vars, pars, <|"Current" -> 1*^-7|>];

Set up the equation:

Wolfram Language code: op = ElectricCurrentPDEComponent[vars, pars];

Solve the harmonic PDE for []:

Wolfram Language code: Vfun = NDSolveValue[{(op /. {ω -> 2 Pi f0}) == Subscript[Γ, current], Subscript[Γ, ground]}, V, {x, y, z}∈Ω]

Transform the voltage at the upper boundary to the time domain:

Wolfram Language code: Vlist = Table[{t, Re[Vfun[0, 0, h] * Exp[I ω t] /. {ω -> 2 Pi f0}]}, {t, 0, 3 * T0, T0 / 100}];

Visualize the voltage at the upper plate of the capacitor:

Wolfram Language code: ListLinePlot[Vlist]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

ElectricCurrentDensityValue

Details

Examples

Basic Examples (3)

Scope (6)

Applications (2)

3D Stationary Analysis (1)

Frequency Analysis (1)

Text

CMS

APA

BibTeX

BibLaTeX

	analysis type	applicable
	Frequency response	Yes
	Stationary	Yes

ElectricCurrentDensityValue

Details

Examples

Basic Examples (3)

Scope (6)

Applications (2)

3D Stationary Analysis (1)

Frequency Analysis (1)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX