WOLFRAM

Wolfram Language & System Documentation Center

EuclideanDistance[u,v]

gives the Euclidean distance between vectors u and v.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

EuclideanDistance

EuclideanDistance[u,v]

gives the Euclidean distance between vectors u and v.

Details

Examples

open all close all

Basic Examples  (2)

Euclidean distance between two vectors:

Wolfram Language code: EuclideanDistance[{a, b, c}, {x, y, z}]

Euclidean distance between numeric vectors:

Wolfram Language code: EuclideanDistance[{1, 2, 3}, {2, 4, 6}]

Scope  (2)

Compute distance between any vectors of equal length:

Wolfram Language code: EuclideanDistance[RandomReal[5, 100], RandomReal[5, 100]]

Compute distance between vectors of any precision:

Wolfram Language code: EuclideanDistance[N[{1, 5, 2, 3, 10}, 50], N[{4, 15, 20, 5, 5}, 50]]

Applications  (2)

Cluster data using Euclidean distance:

Wolfram Language code: FindClusters[{{2, 3}, {5, 10}, {4, 5}, {2, 2}}, DistanceFunction -> EuclideanDistance]

Demonstrate the triangle inequality:

Wolfram Language code: d1 = EuclideanDistance[{a, b}, {a, c}]
Wolfram Language code: d2 = EuclideanDistance[{a, c}, {d, c}]
Wolfram Language code: d3 = EuclideanDistance[{a, b}, {d, c}]
Wolfram Language code: Simplify[d3 <= d1 + d2]

Properties & Relations  (7)

EuclideanDistance is equivalent to Norm of a difference:

Wolfram Language code: EuclideanDistance[{a, b, c}, {x, y, z}]
Wolfram Language code: Norm[{a, b, c} - {x, y, z}]

The square of EuclideanDistance is SquaredEuclideanDistance:

Wolfram Language code: EuclideanDistance[{a, b, c}, {x, y, z}] ^ 2
Wolfram Language code: SquaredEuclideanDistance[{a, b, c}, {x, y, z}]

EuclideanDistance is greater than or equal to ChessboardDistance:

Wolfram Language code: u = {a, b, c}; v = {x, y, z};
Wolfram Language code: Simplify[EuclideanDistance[u, v] ≥ ChessboardDistance[u, v]]

CosineDistance includes a dot product scaled by Euclidean distances from the origin:

Wolfram Language code: u = {a, b, c}; v = {x, y, z};
Wolfram Language code: scale = (EuclideanDistance[u, {0, 0, 0}]EuclideanDistance[v, {0, 0, 0}])
Wolfram Language code: 1 - u.v / scale == CosineDistance[u, v]

CorrelationDistance includes a dot product scaled by Euclidean distances from means:

Wolfram Language code: u = {a, b, c}; v = {x, y, z};
Wolfram Language code: scale = (EuclideanDistance[u, Mean[u]]EuclideanDistance[v, Mean[v]])
Wolfram Language code: CorrelationDistance[u, v] == 1 - (u - Mean[u]).(v - Mean[v]) / scale

StandardDeviation as a EuclideanDistance from the Mean:

Wolfram Language code: data = {a, b, c}
Wolfram Language code: mean = Table[Mean[data], {Length[data]}]
Wolfram Language code: StandardDeviation[data]
Wolfram Language code: % == EuclideanDistance[data, mean] / Sqrt[Length[data] - 1]//FullSimplify

EuclideanDistance computed from RootMeanSquare of a difference:

Wolfram Language code: EuclideanDistance[{1, 2, 3}, {2, 4, 6}]
Wolfram Language code: RootMeanSquare[{1, 2, 3} - {2, 4, 6}] Sqrt[Length[{1, 2, 3}]]
Wolfram Research (2007), EuclideanDistance, Wolfram Language function, https://reference.wolfram.com/language/ref/EuclideanDistance.html.

Text

Wolfram Research (2007), EuclideanDistance, Wolfram Language function, https://reference.wolfram.com/language/ref/EuclideanDistance.html.

CMS

Wolfram Language. 2007. "EuclideanDistance." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EuclideanDistance.html.

APA

Wolfram Language. (2007). EuclideanDistance. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EuclideanDistance.html

BibTeX

@misc{reference.wolfram_2026_euclideandistance, author="Wolfram Research", title="{EuclideanDistance}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/EuclideanDistance.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_euclideandistance, organization={Wolfram Research}, title={EuclideanDistance}, year={2007}, url={https://reference.wolfram.com/language/ref/EuclideanDistance.html}, note=[Accessed: 12-June-2026]}