Wolfram Language & System Documentation Center

StandardDeviation

StandardDeviation[data]

gives the standard deviation estimate of the elements in data.

StandardDeviation[dist]

gives the standard deviation of the distribution dist.

Details

StandardDeviation is also known as volatility.
StandardDeviation measures dispersion from the mean of data or distributions.
For VectorQ data with =Mean[data], the standard deviation estimate is given by for reals and for complexes.

For MatrixQ data, the standard deviation estimate is computed for each column vector with StandardDeviation[{{x₁,y₁,…},{x₂,y₂,…},…}] equivalent to {StandardDeviation[{x₁,x₂,…}],StandardDeviation[{y₁,y₂,…}]}. »

For ArrayQ data, standard deviation is equivalent to ArrayReduce[StandardDeviation,data,1]. »

For a real weighted WeightedData[{x₁,x₂,…},{w₁,w₂,…}], the standard deviation is given by . »
StandardDeviation handles both numerical and symbolic data.
The data can have the following additional forms and interpretations:

	Association	the values (the keys are ignored) »
	SparseArray	as an array, equivalent to Normal[data] »
	QuantityArray	quantities as an array »
	WeightedData	weighted variance, based on the underlying EmpiricalDistribution »
	EventData	based on the underlying SurvivalDistribution »
	TimeSeries, TemporalData, …	vector or array of values (the time stamps ignored) »
	Image,Image3D	RGB channel's values or grayscale intensity value »
	Audio	amplitude values of all channels »
	DateObject, TimeObject	list of dates or list of times »

For a univariate distribution dist, the standard deviation is given by σ=Expectation[(x-μ)²,xdist]^1/2 with μ=Mean[dist]. »

For multivariate distribution dist, the standard deviation is given by {σ_x,σ_y,…}=Expectation[{(x-μ_x)²,(y-μ_y)²,…},{x,y,…}dist]^1/2. »

For a random process proc, the standard deviation function can be computed for slice distribution at time t, SliceDistribution[proc,t], as σ[t]=StandardDeviation[SliceDistribution[proc,t]]. »

Examples

open all close all

Basic Examples (4)

Standard deviation of a list of numbers:

Wolfram Language code: StandardDeviation[{1.21, 3.4, 2, 4.66, 1.5, 5.61, 7.22}]

Standard deviation of elements in each column:

Wolfram Language code: StandardDeviation[{{5.2, 7}, {5.3, 8}, {5.4, 9}}]

Standard deviation of a list of dates:

Wolfram Language code: StandardDeviation[{Yesterday, Today, Tomorrow}]

Standard deviation of a parametric distribution:

Wolfram Language code: StandardDeviation[LogNormalDistribution[0, 1]]

Scope (24)

Basic Uses (8)

Exact input yields exact output:

Wolfram Language code: StandardDeviation[{1, 2, 3, 4}]

Wolfram Language code: StandardDeviation[{π, E, 3}]//Together

Approximate input yields approximate output:

Wolfram Language code: StandardDeviation[{1., 2., 3., 4.}]

Wolfram Language code: StandardDeviation[N[{1, 2, 3, 4}, 30]]

Find the standard deviation of WeightedData:

Wolfram Language code: StandardDeviation[WeightedData[{1, 2, 3}, {Subscript[w, 1], Subscript[w, 2], Subscript[w, 3]}]]

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: StandardDeviation[WeightedData[data, weights]]

Find the standard deviation of EventData:

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: StandardDeviation[EventData[e, ci]]

Find the standard deviation of TemporalData:

Wolfram Language code:

s1 = {2, 1, 6, 5, 7, 4};
s2 = {4, 7, 5, 6, 1, 2};
t = {1, 2, 5, 10, 12, 15};

Wolfram Language code: td = TemporalData[{s1, s2}, {t}];

Wolfram Language code: StandardDeviation[td[10]]

Find the standard deviation of a TimeSeries:

Wolfram Language code:

v = {3, 8, 4, 11, 9, 2};
t = {1, 3, 5, 7, 8, 10};
ts = TimeSeries[v, {t}];

Wolfram Language code: StandardDeviation[ts]//N

The standard deviation depends only on the values:

Wolfram Language code: StandardDeviation[ts["Values"]]//N

Find a three-element moving standard deviation:

Wolfram Language code: MovingMap[StandardDeviation, {2.5, 1.2, 6.9, 5.8, 7.1, 4.8}, Quantity[3, "Events"]]

Find the standard deviation of data involving quantities:

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]

Wolfram Language code: StandardDeviation[data]

Array Data (5)

StandardDeviation for a matrix gives columnwise standard deviations:

Wolfram Language code: StandardDeviation[Array[Subscript[a, ##]&, {2, 2}]]

StandardDeviation for a tensor gives columnwise standard deviations at the first level:

Wolfram Language code: StandardDeviation[Array[Subscript[a, ##]&, {2, 2, 2}]]

Works with large arrays:

Wolfram Language code: StandardDeviation[RandomReal[1, 10 ^ 7]]

Wolfram Language code: StandardDeviation[RandomReal[1, {10 ^ 6, 5}]]

When the input is an Association, StandardDeviation works on its values:

Wolfram Language code:

mat = RandomReal[1, {3, 2}];
assoc = AssociationThread[Range[3], mat]

Wolfram Language code: StandardDeviation[assoc]

SparseArray data can be used just like dense arrays:

Wolfram Language code: StandardDeviation[SparseArray[{{1} -> 1, {100} -> 1}]]

Wolfram Language code: StandardDeviation[SparseArray[{{1, 1} -> 1, {2, 2} -> 2, {3, 3} -> 3, {1, 3} -> 4}]]

Find the standard deviation of a QuantityArray:

Wolfram Language code: data = QuantityArray[RandomReal[1, 6], "Pounds"]

Wolfram Language code: StandardDeviation[data]

Image and Audio Data (2)

Channelwise standard deviation of an RGB image:

Wolfram Language code: StandardDeviation[[image]]

Standard deviation of a grayscale image:

Wolfram Language code: StandardDeviation[[image]]

On audio objects, StandardDeviation works channelwise:

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}]

Wolfram Language code: AudioMeasurements[a, "Channels"]

Wolfram Language code: StandardDeviation[a]

Date and Time (5)

Compute standard deviation of dates:

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];

Wolfram Language code: DateHistogram[dates]

Wolfram Language code: StandardDeviation[dates]

Compute the weighted standard deviation of dates:

Wolfram Language code: dates = RandomDate[4]

Wolfram Language code: weights = {1, 1, 1, 3};

Wolfram Language code: StandardDeviation[WeightedData[dates, weights]]

Compute the standard deviation of dates given in different calendars:

Wolfram Language code:

dates = {DateObject[{2024, 2, 29}, CalendarType -> "Julian"], DateObject[{1524, 1, 1}, CalendarType -> "Islamic"], DateObject[{6024, 1, 15}, CalendarType -> "Jewish"]}

Wolfram Language code: StandardDeviation[dates]

Wolfram Language code: UnitConvert[%, "Years"]

Compute the standard deviation of times:

Wolfram Language code: times = RandomTime[3]

Wolfram Language code: StandardDeviation[times]

Compute the standard deviation of times with different time zone specifications:

Wolfram Language code: times = {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}

Wolfram Language code: StandardDeviation[times]

Distributions and Processes (4)

Find the standard deviation for univariate distributions:

Wolfram Language code: StandardDeviation[BinomialDistribution[n, p]]

Wolfram Language code: StandardDeviation[NormalDistribution[μ, σ]]

Multivariate distributions:

Wolfram Language code: StandardDeviation[MultivariateHypergeometricDistribution[n, {Subscript[m, 1], Subscript[m, 2]}]]

Wolfram Language code: StandardDeviation[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ]]

Standard deviation for derived distributions:

Wolfram Language code: StandardDeviation[TransformedDistribution[x^2, xNormalDistribution[μ, σ]]]

Wolfram Language code: StandardDeviation[ProbabilityDistribution[(Sqrt[2] / π)(1 / (1 + (x - 2)^4)), {x, -∞, ∞}]]

Data distribution:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 3];

Wolfram Language code: StandardDeviation[HistogramDistribution[data]]

Standard deviation for distributions with quantities:

Wolfram Language code: StandardDeviation[QuantityDistribution[UniformDistribution[{10., 20.}], "Meters"]]

Wolfram Language code: StandardDeviation[QuantityDistribution[BinormalDistribution[{190, 72}, {12, 2}, 2 / 3], {"Pounds", "Inches"}]]

Wolfram Language code:

StandardDeviation[SmoothKernelDistribution[QuantityArray[ExampleData[{"Statistics", "OldFaithful"}], {"Seconds", "Minutes"}]]]

Standard deviation function for a random process:

Wolfram Language code: StandardDeviation[BrownianBridgeProcess[a, b][t]]

Wolfram Language code: Plot[Evaluate[% /. {a -> 3, b -> 5}], {t, 3, 5}, Filling -> Axis]

Applications (7)

StandardDeviation is a measure of dispersion:

Wolfram Language code: 𝒟 = NormalDistribution[0, σ];

Wolfram Language code: StandardDeviation[𝒟]

Wolfram Language code:

Table[Plot[PDF[𝒟, x], {x, -4, 4}, PlotRange -> {0, 0.4}, Filling -> Axis, Ticks -> {Automatic, None}, PlotLabel -> Row[{"σ = ", σ}]], {σ, {1, 1.5, 2}}]

Transform data to have mean 0 and unit variance:

Wolfram Language code: data = RandomReal[5, 20]

Wolfram Language code: standardized = (data - Mean[data]) / StandardDeviation[data]

Wolfram Language code: Mean[standardized]//Chop

Wolfram Language code: Variance[standardized]

Identify periods of high volatility in the S&P 500 using a five-year moving standard deviation:

Wolfram Language code: data = TemporalData[«4»];

Wolfram Language code: smooth = MovingMap[StandardDeviation, data, {Quantity[5 * 365, "Day"]}];

Wolfram Language code: DateListPlot[smooth]

Find the mean and standard deviation for the number of cycles to failure of deep-groove ball-bearings:

Wolfram Language code: data = ExampleData[{"Statistics", "FatigueLifeFailures"}];

Wolfram Language code: Length[data]

Wolfram Language code: {μ, σ} = {Mean[data], StandardDeviation[data]}

Plot the data:

Wolfram Language code:

m = {{0, μ}, {22, μ}};
s1 = {{0, μ + σ}, {22, μ + σ}};
s2 = {{0, μ - σ}, {22, μ - σ}};

Wolfram Language code:

ListPlot[{data, m, s1, s2}, Joined -> {False, True, True, True}, PlotStyle -> {Automatic, Automatic, Gray, Gray}, Filling -> {3 -> {4}, 1 -> 0}]

Probability that the values lie within two standard deviations of the mean:

Wolfram Language code: NProbability[Abs[x - μ] < 2σ, xdata]

Investigate weak stationarity of the process data by analyzing standard deviations of slices:

Wolfram Language code: data = TemporalData[«4»];

Wolfram Language code: times = Range[0, 1, .1];

Wolfram Language code: sd = Map[{#, StandardDeviation[data[#]]}&, times];

Wolfram Language code: ListLinePlot[sd]

Use a larger plot range to see how relatively small the variations are:

Wolfram Language code: ListLinePlot[sd, PlotRange -> {0, .7}]

Compute standard deviation for slices of a collection of paths of a random process:

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

Choose a few slice times:

Wolfram Language code: times = Range[0, 1, .1];

Compute standard deviations and means:

Wolfram Language code:

sd = Map[{#, StandardDeviation[data[#]]}&, times];
means = Map[{#, Mean[data[#]]}&, times];

Create a standard deviation band around the mean:

Wolfram Language code:

upper = TimeSeriesThread[#[[1]] + #[[2]]&, {means, sd}];
lower = TimeSeriesThread[#[[1]] - #[[2]]&, {means, sd}];

Plot standard deviations around the mean over these paths:

Wolfram Language code: Show[ListPlot[data], ListLinePlot[{upper, lower}, PlotStyle -> Black]]

Find the standard deviation of the heights for the children in a class:

Wolfram Language code:

heights = Quantity[{134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147, 
	        150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141}, "Centimeters"];

Wolfram Language code: ListPlot[heights, Filling -> Axis, AxesLabel -> Automatic]

Wolfram Language code: sd = StandardDeviation[heights]//N

The heights within one standard deviation from the mean:

Wolfram Language code:

m = Mean[heights];
n = Length[heights];
ListPlot[{heights, {{0, m}, {n, m}}, {{0, m - sd}, {n, m - sd}}, {{0, m + sd}, {n, m + sd}}}, Filling -> {1 -> 0, 3 -> {4}}, Joined -> {False, True, True, True}, PlotStyle -> {Automatic, Automatic, Gray, Gray}, AxesLabel -> Automatic, PlotLegends -> {"heights", "mean", "standard deviation bands"}]

Properties & Relations (9)

The square of StandardDeviation is Variance:

Wolfram Language code: Variance[{1, 2, 3, 4}]

Wolfram Language code: StandardDeviation[{1, 2, 3, 4}]

StandardDeviation is a scaled Norm of deviations from the Mean:

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code: StandardDeviation[data]

Wolfram Language code: Norm[data - Mean[data]] / Sqrt[Length[data] - 1]

StandardDeviation is the square root of a scaled CentralMoment:

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code: StandardDeviation[data]

Wolfram Language code: Sqrt[CentralMoment[data, 2] Length[data] / (Length[data] - 1)]

StandardDeviation is a scaled RootMeanSquare of the deviations:

Wolfram Language code: data = RandomReal[10, 10];

Wolfram Language code: RootMeanSquare[data - Mean[data]]Sqrt[Length[data] / (Length[data] - 1)]

Wolfram Language code: StandardDeviation[data]

StandardDeviation is the square root of a scaled Mean of squared deviations:

Wolfram Language code: data = RandomReal[5, 20];

Wolfram Language code: StandardDeviation[data]

Wolfram Language code: Sqrt[Mean[(data - Mean[data]) ^ 2] Length[data] / (Length[data] - 1)]

StandardDeviation as a scaled EuclideanDistance from the Mean:

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code: mean = Mean[data]

Wolfram Language code: len = Length[data]

Wolfram Language code: EuclideanDistance[data, Table[mean, {len}]] / Sqrt[(len - 1)]

Wolfram Language code: StandardDeviation[data]

StandardDeviation squared is less than MeanDeviation if all absolute deviations are less than 1:

Wolfram Language code: data = RandomReal[1, 10];

Wolfram Language code: MeanDeviation[data]

Wolfram Language code: StandardDeviation[data] ^ 2

StandardDeviation squared is greater than MeanDeviation if all absolute deviations are greater than 1:

Wolfram Language code: data = Join[RandomReal[{1, 2}, 5], RandomReal[{5, 6}, 5]];

Wolfram Language code: MeanDeviation[data]

Wolfram Language code: StandardDeviation[data] ^ 2

StandardDeviation of a random variable as the square root of Variance:

Wolfram Language code: dist = GammaDistribution[α, β];

Wolfram Language code: ev = Sqrt[Variance[dist]]

Wolfram Language code: sd = StandardDeviation[dist]

Wolfram Language code: Simplify[ev == sd, Assumptions -> α > 0 && β > 0]

Possible Issues (1)

StandardDeviation does not handle Missing directly:

Wolfram Language code:

data = {1.21, 3.4, 2.15, Missing[], 1.55};
StandardDeviation[data]

Convert data to a TabularColumn to use the non-missing values for computation:

Wolfram Language code: StandardDeviation[TabularColumn[data]]

Use Query:

Wolfram Language code: Query[StandardDeviation][data]

Neat Examples (1)

The distribution of StandardDeviation estimates for 20, 100, and 300 samples:

Wolfram Language code: StandardDeviation[ExponentialDistribution[0.9]]

Wolfram Language code:

SmoothHistogram[Table[StandardDeviation[RandomVariate[ExponentialDistribution[0.9], {s, 1000}]], {s, {20, 100, 300}}], Filling -> Axis, PlotLegends -> {20, 100, 300}, PlotRange -> {{0, 3}, Automatic}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

StandardDeviation

Details

Examples

Basic Examples (4)

Scope (24)

Basic Uses (8)

Array Data (5)

Image and Audio Data (2)

Date and Time (5)

Distributions and Processes (4)

Applications (7)

Properties & Relations (9)

Possible Issues (1)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

StandardDeviation

Details

Examples

Basic Examples (4)

Scope (24)

Basic Uses (8)

Array Data (5)

Image and Audio Data (2)

Date and Time (5)

Distributions and Processes (4)

Applications (7)

Properties & Relations (9)

Possible Issues (1)

Neat Examples (1)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX