Wolfram Language & System Documentation Center

RootMeanSquare

RootMeanSquare[list]

gives the root mean square of values in list.

RootMeanSquare[dist]

gives the root mean square of the distribution dist.

Details

RootMeanSquare measures scale of data or distributions.
RootMeanSquare[list] gives the square root of the second sample moment.
For the list {x₁,x₂,…,x_n}, the root mean square is given by .
RootMeanSquare handles both numerical and symbolic data.
RootMeanSquare[{{x₁,y₁,…},{x₂,y₂,…},…}] gives {RootMeanSquare[{x₁,x₂,…}],RootMeanSquare[{y₁,y₂,…}]}.
RootMeanSquare[dist] is equivalent to Sqrt[Expectation[x²,xdist]].

Examples

open all close all

Basic Examples (3)

RootMeanSquare of a list:

Wolfram Language code: RootMeanSquare[ {a, b, c, d}]

RootMeanSquare of columns of a matrix:

Wolfram Language code: RootMeanSquare[{{1, 2}, {5, 10}, {5, 2}, {4, 8}}]

RootMeanSquare of a parametric distribution:

Wolfram Language code: RootMeanSquare[LogNormalDistribution[0, 1]]

Scope (14)

Data (10)

Exact input yields exact output:

Wolfram Language code: RootMeanSquare[{1, 2, 3, 4}]

Wolfram Language code: RootMeanSquare[{π, E, 2}]

Approximate input yields approximate output:

Wolfram Language code: RootMeanSquare[{1., 2., 3., 4.}]

Wolfram Language code: RootMeanSquare[N[{1, 2, 3, 4}, 30]]

RootMeanSquare for a matrix gives columnwise means:

Wolfram Language code:

RootMeanSquare[(⁠|     |     |
| --- | --- |
| a11 | a12 |
| a21 | a22 |⁠)]

Works with large arrays:

Wolfram Language code: RootMeanSquare[RandomReal[1, 10 ^ 7]]

Wolfram Language code: RootMeanSquare[RandomReal[1, {10 ^ 6, 3}]]

SparseArray data can be used just like dense arrays:

Wolfram Language code: RootMeanSquare[SparseArray[{{1} -> 1, {2} -> 7}]]

Wolfram Language code: RootMeanSquare[SparseArray[{{1, 1} -> 1, {2, 1} -> 2, {2, 2} -> 3}]]

Compute results for a SparseArray:

Wolfram Language code: sp = SparseArray[{{i_, i_} :> i, {i_, j_} /; j == i + 1 :> i - 1}, {100, 10}]

Wolfram Language code: RootMeanSquare[sp]

RootMeanSquare for WeightedData:

Wolfram Language code: RootMeanSquare[WeightedData[{1, 2, 3}, {Subscript[w, 1], Subscript[w, 2], Subscript[w, 3]}]]

Wolfram Language code:

data = {8, 3, 5, 4, 9, 1, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0.3, 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: RootMeanSquare[WeightedData[data, weights]]

RootMeanSquare for EventData:

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: RootMeanSquare[EventData[e, ci]]

RootMeanSquare for TimeSeries:

Wolfram Language code:

RootMeanSquare[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]]

The root mean square depends only on the values:

Wolfram Language code:

RootMeanSquare[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]["Values"]]

RootMeanSquare for data involving quantities:

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]

Wolfram Language code: RootMeanSquare[data]

Distributions and Processes (4)

Find the RootMeanSquare for univariate distributions:

Wolfram Language code: RootMeanSquare[BinomialDistribution[n, p]]

Wolfram Language code: RootMeanSquare[NormalDistribution[μ, σ]]

Multivariate distributions:

Wolfram Language code: RootMeanSquare[MultinomialDistribution[n, {Subscript[m, 1], Subscript[m, 2]}]]

Wolfram Language code: RootMeanSquare[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {σ1, σ2}, ρ]]

RootMeanSquare for derived distributions:

Wolfram Language code: RootMeanSquare[TransformedDistribution[x^2, xNormalDistribution[μ, σ]]]

Wolfram Language code: RootMeanSquare[ProbabilityDistribution[(Sqrt[2] / π)(1 / (1 + (x - 2)^4)), {x, -∞, ∞}]]

Data distribution:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 3];

Wolfram Language code: RootMeanSquare[HistogramDistribution[data]]

RootMeanSquare for distributions with quantities:

Wolfram Language code: RootMeanSquare[QuantityDistribution[MaxwellDistribution[σ], "Meters" / "Seconds"]]

Wolfram Language code: RootMeanSquare[EmpiricalDistribution[QuantityArray[RandomChoice[{0, 5}, 1000], "Volts"]]]

RootMeanSquare for a random process:

Wolfram Language code: RootMeanSquare[BrownianBridgeProcess[a, b][t]]

Wolfram Language code: Plot[Evaluate[% /. {a -> 3, b -> 5}], {t, 3, 5}, PlotRange -> All]

Applications (3)

Root mean square error for a linear fit:

Wolfram Language code: data = {{1, 2.9}, {2, 5.0}, {3, 7.1}, {4, 8.9}, {5, 10.9}, {6, 13.1}, {7, 14.9}, {8, 16.8}, {9, 18.5}, {10, 22.2}};

Wolfram Language code: f[x_] = Fit[data, {1, x}, x]

Wolfram Language code: RootMeanSquare[data[[All, 2]] - Map[f, data[[All, 1]]]]

Sample a periodic signal:

Wolfram Language code: f[t_] := Sin[5 t] + Cos[7t] / 12

Wolfram Language code: ts = TimeSeries[Table[f[t], {t, 0, 2Pi, 0.01}]]

Wolfram Language code: ListPlot[ts]

Compute the root mean square value of the sample:

Wolfram Language code: RootMeanSquare[ts]

Compare with the exact value:

Wolfram Language code: Sqrt[Integrate[f[t] ^ 2, {t, 0, 2Pi}] / (2Pi)]

Wolfram Language code: N[%]

Find the root mean square value for the heights of children in a class:

Wolfram Language code:

heights = Quantity[{134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147, 
	        150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141}, "Centimeters"];

Wolfram Language code: ListPlot[heights, Filling -> Axis, AxesLabel -> Automatic]

Wolfram Language code: (rms = RootMeanSquare[heights])//N

Wolfram Language code:

ListPlot[{heights, {{0, rms}, {Length[heights], rms}}}, Joined -> {False, True}, Filling -> Axis, AxesLabel -> Automatic]