FoxH[{{{a1,α1},…,{an,αn}},{{an+1,αn+1},…,{ap,αp}}},{{{b1,β1},…,{bm,βm}},{{bm+1,βm+1},…,{bq,βq}}},z]
is the Fox H-function 
.
FoxH
FoxH[{{{a1,α1},…,{an,αn}},{{an+1,αn+1},…,{ap,αp}}},{{{b1,β1},…,{bm,βm}},{{bm+1,βm+1},…,{bq,βq}}},z]
is the Fox H-function 
.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- FoxH generalizes the MeijerG function and is defined by the Mellin–Barnes integral
where 
and 
are positive real numbers and the integration is along a path 
separating the poles of 
from the poles of 
. - Three choices are possible for the path
:
a.
is a loop beginning at 
and ending at 
and encircling all the poles of 
once in the positive direction.
b.
is a loop beginning at 
and ending at 
and encircling all the poles of 
once in the negative direction.
c.
is a contour starting at the point 
and going to 
such that all the poles of 
are separated from the poles of 
. - FoxH specializes to MeijerG if
for 
and 
: 
. - In many special cases, FoxH is automatically converted to other functions.
- FoxH can be evaluated for arbitrary complex parameters.
- FoxH can be evaluated to arbitrary numerical precision.
- FoxH automatically threads over lists. »
Examples
open all close allBasic Examples (5)
FoxH[{{{(1/2), 1}}, {{(1/3), 2}}}, {{{(1/4), 3}}, {{π, 4}}}, 0.2]Plot the FoxH function:
Plot[FoxH[{{{(1/2), (2/3)}}, {}}, {{{(3/4), (4/5)}}, {{(5/6), (6/7)}}}, x], {x, 0, 10}]Plot over a subset of the complexes:
ComplexPlot3D[FoxH[{{}, {}}, {{{-1, 1 / 2}}, {}}, z], {z, -3 - 3I, 3 + 3I}, PlotLegends -> Automatic]Series expansion at the origin:
Series[FoxH[{{{a1, 1 / 2}}, {}}, {{{b1, 1}}, {}}, z], {z, 0, 1}]Leading asymptotic term at Infinity:
Asymptotic[FoxH[{{{a1, 1}}, {}}, {{{b1, 1 / 2}}, {}}, z], z -> ∞]Scope (28)
Numerical Evaluation (7)
N[FoxH[{{{1 / 10, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, 1 / 5], 50]The precision of the output tracks the precision of the input:
FoxH[{{{1 / 10, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, 0.20000000000000000001]FoxH takes complex number parameters 
and 
:
FoxH[{{{1 / 10 + I, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, 1 / 5`20]FoxH[{{{1 / 10 + I, 6 / 5}, {1 / 2I, 1}}, {{17 / 5, 2}}}, {{{-4I, 2}}, {{1 / 5, 1}}}, 1 / 5`20]FoxH takes complex number arguments:
FoxH[{{{1 / 10 + I, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, 1 / 5`20 - I]Evaluate FoxH efficiently at high precision:
FoxH[{{{1 / 10, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, 1 / 5`200]//TimingCompute the elementwise values of an array using automatic threading:
FoxH[{{}, {}}, {{{1 + I, 1}}, {{3, 1}}}, {{1 / 2, -1}, {0, 1 / 2}}]Or compute the matrix FoxH function using MatrixFunction:
MatrixFunction[FoxH[{{}, {}}, {{{1 + I, 1}}, {{3, 1}}}, #]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplifyCompute average-case statistical intervals using Around:
FoxH[ {{{0, 1}}, {}}, {{{0, 1}}, {{0, 1}}}, Around[.9, 0.1]]Specific Values (3)
FoxH[{{{0, 1}}, {}}, {{{0, 1}}, {{0, 1}}}, 5]FoxH[{{}, {}}, {{{1 + I, 1}}, {{3, 1}}}, 1]Evaluate FoxH symbolically:
FoxH[{{{a, 1}}, {}}, {{{0, 1}}, {{b, 1}}}, z]FoxH[{{}, {{1, 1}}}, {{{1 / 2, 1}}, {}}, z]FoxH[{{{1 / 2, 1}}, {}}, {{{0, 1}}, {}}, 0]FoxH[{{{0, 1}}, {}}, {{{0, 1}}, {{0, 1 / 2}}}, 0]Visualization (4)
Plot a family of FoxH functions:
Plot[Evaluate[Table[FoxH[{{{(1/2), (2/3)}}, {}}, {{{b1, (4/5)}}, {{(5/6), (6/7)}}}, x], {b1, 0, 3}]], {x, 0, 10}, PlotRange -> All]ComplexContourPlot of FoxH[{{},{}},{{{-1,1/2}},{}}, z]:
f = FoxH[{{}, {}}, {{{-1, 1 / 2}}, {}}, z];ComplexContourPlot[{Re[f], Im[f]}, {z, 4}, Contours -> 24]Use AbsArgPlot and ReImPlot to plot complex values of FoxH over the real numbers:
AbsArgPlot[FoxH[{{{1 / 2, 1 / 4}}, {}}, {{{I, 3}}, {}}, x], {x, -1, 1}]ReImPlot[FoxH[{{{1 / 2, 1 / 4}}, {}}, {{{1 / 3 - 1 / 50I, 1}}, {}}, x], {x, -1, 1}]Plot FoxH as a function of parameters 
and 
:
Plot3D[FoxH[{{}, {}}, {{{Subscript[b, 1], 1 / 2}}, {}}, x], {Subscript[b, 1], 0, 1}, {x, 0, 3}, ...]Function Properties (5)
For simple parameters, FoxH evaluates to simpler functions:
FoxH[{{{Subscript[a, 1], 2}, {Subscript[a, 2], 2}}, {{Subscript[a, 3], 2}}}, {{{Subscript[b, 1], 2}}, {{Subscript[b, 2], 2}}}, z]FoxH[{{}, {}}, {{{b, 1 / 2}}, {}}, z]FoxH is symmetric in the pairs 
and 
:
FoxH[{{{Subscript[a, 1], Subscript[α, 1]}, {Subscript[a, 2], Subscript[α, 2]}}, {}}, {{}, {}}, z] == FoxH[{{{Subscript[a, 2], Subscript[α, 2]}, {Subscript[a, 1], Subscript[α, 1]}}, {}}, {{}, {}}, z]FoxH[{{}, {}}, {{}, {{Subscript[b, 1], Subscript[β, 1]}, {Subscript[b, 2], Subscript[β, 2]}}}, z] == FoxH[{{}, {}}, {{}, {{Subscript[b, 2], Subscript[β, 2]}, {Subscript[b, 1], Subscript[β, 1]}}}, z]FoxH might reduce to a simpler FoxH if some of the pairs are equal:
FoxH[{{{Subscript[a, 1], Subscript[α, 1]}}, {}}, {{}, {{Subscript[a, 1], Subscript[α, 1]}, {Subscript[b, 2], Subscript[β, 2]}}}, z]FoxH[{{{a1, A1}}, {{a2, A2}, {a3, A3}}}, {{{b1, B1}, {a2, A2}}, {{a1, A1}, {b2, B2}}}, z]FoxH threads elementwise over lists in the last argument:
FoxH[{{{1 / 10, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, {1 / 5`20, -0.1, 2I}]FoxH[{{{0.1, 3}}, {}}, {{{4 / 5, 3 / 2}}, {}}, (| | |
| :- | :---- |
| π | u |
| v | (π/2) |)]TraditionalForm formatting:
FoxH[{{{a, Sqrt[2]}}, {}}, {{{b, 3}}, {}}, z]//TraditionalFormFoxH[{{{1, 1}, {2, (1/2)}}, {{3, (1/3)}}}, {{{4, (1/4)}}, {{5, (1/5)}}}, z + (p/q)]//TraditionalFormDifferentiation (2)
First derivative with respect to z:
foxH = FoxH[{{{a1, α1}, {a2, α2}}, {{a3, α3}}}, {{{b1, β1}}, {{b2, β2}}}, z];D[foxH, z]Higher-order derivative with respect to z:
**D[foxH, {z, 4}] **Formula for the 
derivative of a specific FoxH with respect to z:
D[FoxH[{{}, {}}, {{{ν, 1}}, {{-ν, 1}}}, z], {z, k}]// FullSimplifyIntegration (3)
Compute the indefinite integral using Integrate:
Integrate[FoxH[{{{a1, α1}}, {{a2, α2}}}, {{{b1, β1}}, {{b2, β2}}}, z], z]Verify it by calculating the antiderivative:
D[%, z]Integrate[FoxH[{{{1, 1}}, {{2, 1}}}, {{{1 / 2, 1}}, {{-1 / 2, 1}}}, z], {z, 0, 5}]Integrate[z^2 FoxH[{{{a1, α1}}, {{a2, α2}}}, {{{b1, β1}}, {{b2, β2}}}, z], z]Integrate[z FoxH[{{{1 / 2, 1}}, {{2, 1}}}, {{{1 / 2, 1}}, {{-3, 1}}}, z^2], {z, 0, 3}]Series Expansions (4)
Get the series expansion of some FoxH function at the origin:
Series[FoxH[{{{1, 1}}, {{2, 1 / 3}}}, {{{3, 2}}, {{4, 3}}}, x], {x, 0, 2}]The first three approximations of this FoxH function around 
:
terms = Normal@Table[Series[FoxH[{{{1, 1}}, {{2, 1 / 10}}}, {{{3, 2}}, {{4, 3}}}, x], {x, 0, m}], {m, 0, 2}]Plot[Evaluate[{terms, FoxH[{{{1, 1}}, {{2, 1 / 10}}}, {{{3, 2}}, {{4, 3}}}, x]}], {x, 0, 100}]Find the series expansion of a general FoxH function at the origin:
Series[FoxH[{{{Subscript[a, 1], 1}}, {{Subscript[a, 2], 1 / 3}}}, {{{Subscript[b, 1], 1}, {Subscript[b, 2], 1 / 2}}, {{Subscript[b, 3], 3}}}, x], x -> 0]Find the series expansion of a general FoxH function at Infinity:
Series[FoxH[{{{Subscript[a, 1], 1}, {Subscript[a, 2], 1 / 3}}, {{Subscript[a, 3], 3}}}, {{{Subscript[b, 1], 1}}, {{Subscript[b, 2], 2}}}, x], x -> ∞]Get the general term in the series expansion using SeriesCoefficient:
SeriesCoefficient[FoxH[{{{a, 1}}, {}}, {{{b, 1}}, {}}, x], {x, 1, m}]Applications (3)
Use FoxHReduce to get the representation of almost any mathematical function in terms of FoxH:
FoxHReduce[Sin[a x], x]FoxHReduce[E^-x UnitStep[1 - Abs[x]], x]A root of the trinomial equation 
can be written in terms of FoxH:
root = (1/2) t FoxH[{{{0, 1}, {0, (3/2)}}, {}}, {{{0, 1}}, {{-1, 1}, {0, (1/2)}}}, -t] - 1;
t = N[(1/4), 20];
z^3 - z - t /. z -> rootThe roots of the general trinomial 
can also be expressed in terms of FoxH:
roots = Exp[(2π I/n - 1)]^-j + (t/n - 1)FoxH[{{{0, 1}, {0, (n/n - 1)}}, {}}, {{{0, 1}}, {{-1, 1}, {0, (1/n - 1)}}}, t Exp[(2π I/n - 1)]^j];
n = 6;z^n - z - t /. z -> Table[roots, {j, 0, n - 2}]Express the PDF of StableDistribution in terms of FoxH for the case of 
:
StableDistributionPDF[x_, α_, β_, μ_, σ_] := With[{Α = σ (1 + β^2Tan[(π α/2)]^2)^(1/2α), Β = (2/π α)Sign[x - μ]ArcTan[β Tan[(π α/2)]]}, (1/α Α) * FoxH[{{{1 - (1/α), (1/α)}}, {{ (1 - Β/2), (1 + Β/2)}}}, {{{0, 1}}, {{ (1 - Β/2), (1 + Β/2)}}}, (Abs[x - μ]/Α)]]Evaluate it and compare with the built-in PDF generated using StableDistribution:
Show[{ListPlot[Table[{x, StableDistributionPDF[x, 0.6, 0.4, 0.5, 2]}, {x, -20, 20, 0.2}], ...], Plot[PDF[StableDistribution[1, 0.6, 0.4, 0.5, 2], x], {x, -20, 20}, ...]}]Properties & Relations (3)
Many mathematical special functions are special cases of FoxH:
FoxH[{{}, {}}, {{{b, 1 / 2}}, {}}, z]FoxH[{{{0, 1}}, {}}, {{{0, 1}}, {{0, 5 / 3}}}, z]FoxH[{{{a1, 1}}, {{a2, 1}}}, {{{b1, 1}}, {{b2, 1}}}, z]Use FunctionExpand to expand FoxH into simpler functions:
FoxH[{{{1, 1}}, {{0, (1/2)}, {(1/2), 1}}}, {{{(1/2), (1/2)}}, {{0, (1/2)}, {0, 1}, {(1/2), 1}}}, z]FunctionExpand[%]FoxHReduce returns FoxH representations of functions:
FoxHReduce[Sin[x], x]Possible Issues (3)
is a singular point of FoxH:
FoxH[{{{1 / 3, 3}}, {}}, {{{4 / 5, 3 / 2}}, {}}, 0]Series at the origin is available when the parameters 
are positive and 
are positive and exact:
Series[FoxH[{{{1 / 3, 3 / 2}}, {}}, {{{4 / 5, 3}}, {}}, z], z -> 0]Series[FoxH[{{{1 / 3, 3 / 2}}, {}}, {{{4 / 5, -3}}, {}}, z], z -> 0]Series at Infinity is available when the parameters 
are positive and 
are positive and exact:
Series[FoxH[{{{1 / 3, 3}}, {}}, {{{4 / 5, 3 / 2}}, {}}, z], z -> ∞]Series[FoxH[{{{1 / 3, -3}}, {}}, {{{4 / 5, 3 / 2}}, {}}, z], z -> ∞]Neat Examples (1)
Many elementary and special functions are special cases of FoxH:
FoxHlist = Inactivate[{FoxH[{{}, {}}, {{{0, 1}}, {}}, x], FoxH[{{}, {}}, {{{b, 2}}, {}}, x], FoxH[{{{0, 1}}, {}}, {{{0, 1}}, {{0, (2/3)}}}, x], FoxH[{{{0, 1}}, {}}, {{{0, 1}}, {{2, (2/3)}}}, x], FoxH[{{}, {}}, {{{(n/2), (1/2)}}, {{-(n/2), (1/2)}}}, (x/2)], FoxH[{{{1 - a, 1}, {1 - b, 1}}, {}}, {{{0, 1}}, {{1 - c, 1}}}, x], FoxH[{{{Subscript[a, 1], 1}, {Subscript[a, 2], 1}}, {{Subscript[a, 3], 1}}}, {{{Subscript[b, 1], 1}}, {{Subscript[b, 2], 1}}}, x], FoxH[{{{Subscript[a, 1], 3}, {Subscript[a, 2], 3}}, {{Subscript[a, 2], 3}}}, {{{Subscript[b, 1], 3}}, {{Subscript[b, 2], 3}}}, x]}, FoxH];Grid[Join[{{Text["FoxH with specific parameters"], Text["Simpler function"]}}, Transpose[{HoldForm /@ FoxHlist /. Inactive[FoxH] -> FoxH, Activate[FoxHlist]}]], IconizedObject[«Grid options»]]//TraditionalFormRelated Links
MathWorldText
Wolfram Research (2021), FoxH, Wolfram Language function, https://reference.wolfram.com/language/ref/FoxH.html (updated 2021).
CMS
Wolfram Language. 2021. "FoxH." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/FoxH.html.
APA
Wolfram Language. (2021). FoxH. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FoxH.html