Wolfram Language & System Documentation Center

HypergeometricPFQ

HypergeometricPFQ[{a₁,…,a_p},{b₁,…,b_q},z]

is the generalized hypergeometric function .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
has the series expansion $sum_(k=0)^(infty)TemplateBox[{{a, _, 1}, k}, Pochhammer]...TemplateBox[{{a, _, p}, k}, Pochhammer]/TemplateBox[{{b, _, 1}, k}, Pochhammer]...TemplateBox[{{b, _, q}, k}, Pochhammer]z^k/k!$ , where is the Pochhammer symbol.
Hypergeometric0F1, Hypergeometric1F1, and Hypergeometric2F1 are special cases of HypergeometricPFQ.
In many special cases, HypergeometricPFQ is automatically converted to other functions.
For certain special arguments, HypergeometricPFQ automatically evaluates to exact values.
HypergeometricPFQ can be evaluated to arbitrary numerical precision.
For , HypergeometricPFQ[alist,blist,z] has a branch cut discontinuity in the complex plane running from to .
FullSimplify and FunctionExpand include transformation rules for HypergeometricPFQ.
HypergeometricPFQ can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (5)

Evaluate numerically:

Wolfram Language code: HypergeometricPFQ[{1, 1}, {3, 3, 3}, 2.]

Plot over a subset of the reals:

Wolfram Language code: Plot[HypergeometricPFQ[{1, 1}, {3, 3, 3}, x], {x, -30, 30}]

Evaluate symbolically:

Wolfram Language code: HypergeometricPFQ[{1, 1, 2}, {3, 3}, z]

Series expansion at the origin:

Wolfram Language code: Series[ HypergeometricPFQ[{a1, a2, a3}, {b1, b2}, z], {z, 0, 2}]

Series expansion at Infinity:

Wolfram Language code: Series[HypergeometricPFQ[{1, 1, 2}, {3, 3}, x], {x, ∞, 5}]//Normal

Scope (34)

Numerical Evaluation (6)

Evaluate to high precision:

Wolfram Language code: N[HypergeometricPFQ[{1, 1, 1}, {3 / 2, 3 / 2, 3 / 2}, 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: HypergeometricPFQ[{1, 1, 1}, {3 / 2, 3 / 2, 3 / 2}, 10.00000000000000000000000000]

Evaluate for complex arguments and parameters:

Wolfram Language code: HypergeometricPFQ[{I, I, I}, {2, 2 , 2}, -1.0I]

Evaluate HypergeometricPFQ efficiently at high precision:

Wolfram Language code: HypergeometricPFQ[{1, 1, 1}, {3 / 2, 3 / 2, 3 / 2}, 10`500]//Timing

Wolfram Language code: HypergeometricPFQ[{1, 1, 1}, {3 / 2, 3 / 2, 3 / 2}, 10`5000];//Timing

HypergeometricPFQ threads elementwise over lists in its third argument:

Wolfram Language code: HypergeometricPFQ[{1, 2, 3, 4}, {5, 6, 7}, {0.1, 0.3, 0.5}]

HypergeometricPFQ threads elementwise over sparse and structured arrays in its third argument:

Wolfram Language code: HypergeometricPFQ[{1, 2, 3, 4}, {5, 6, 7}, SparseArray[Automatic, {2, 2}, 0, {1, {{0, 1, 2}, {{1}, {2}}}, {1, 1}}]]

Wolfram Language code:

HypergeometricPFQ[{1, 2, 3, 4}, {5, 6, 7}, SymmetrizedArray[StructuredArray`StructuredData[{2, 2}, 
  {{{1, 1} -> 1, {1, 2} -> 1/2, {2, 2} -> 1/3}, Symmetric[{1, 2}]}]]]

HypergeometricPFQ can be used with Interval and CenteredInterval objects:

Wolfram Language code: HypergeometricPFQ[{1 / 2, 2 / 3, 3 / 4}, {4 / 5, 5 / 6}, Interval[{0.11, 0.12}]]

Wolfram Language code: HypergeometricPFQ[{1 / 2, 2 / 3, 3 / 4}, {4 / 5, 5 / 6}, CenteredInterval[1 / 2, 1 / 100]]

Compute the elementwise values of an array:

Wolfram Language code: HypergeometricPFQ[{1, 3}, {2, 2}, {{1, 0}, {1 / 2, 1}}]

Or compute the matrix HypergeometricPFQ function using MatrixFunction:

Wolfram Language code: MatrixFunction[HypergeometricPFQ[{1, 3}, {2, 2}, #]&, {{1, 0}, {1 / 2, 1}}]

Specific Values (4)

For simple parameters, HypergeometricPFQ evaluates to simpler functions:

Wolfram Language code: HypergeometricPFQ[{1, 1, 3}, {2, 2}, x]

HypergeometricPFQ evaluates to a polynomial if any of the parameters a_k is a non-positive integer:

Wolfram Language code: HypergeometricPFQ[{-3, a}, {b, c}, x]

Value at the origin:

Wolfram Language code:

HypergeometricPFQ[{Subscript[a, 1], Subscript[a, 2], Subscript[a, 3]}, {Subscript[b, 1], Subscript[b, 2], Subscript[b, 3]}, 0]

Find a value of satisfying the equation :

Wolfram Language code:

f[x_] := HypergeometricPFQ[{1, 1, 2}, {3, 3}, x] - 1 / 2;
xzero = Solve[f[x] == 0 && -8 < x < -6.0, x][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[f[x], {x, -10, 3}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

Visualization (2)

Plot the HypergeometricPFQ function:

Wolfram Language code:

Plot[{HypergeometricPFQ[{1, 1}, {3, 3, 3}, x], HypergeometricPFQ[{2, 2}, {3, 3, 3}, x], HypergeometricPFQ[{3, 3}, {3, 3, 3}, x]}, {x, -10, 10}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[HypergeometricPFQ[{1, 1}, {3, 3, 3}, z]], {z, -10 - 10I, 10 + 10I}, Contours -> 24]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[HypergeometricPFQ[{1, 1}, {3, 3, 3}, z]], {z, -10 - 10I, 10 + 10I}, Contours -> 24]

Function Properties (9)

Domain of HypergeometricPFQ:

Wolfram Language code: FunctionDomain[HypergeometricPFQ[{a1, a2}, {b1, b2, b3}, x], x]

Wolfram Language code: FunctionDomain[HypergeometricPFQ[{a1, a2}, {b1, b2, b3}, z], z, Complexes]

Permutation symmetry:

Wolfram Language code: HypergeometricPFQ[{a1, a2}, {b1, b2, b3}, x] == HypergeometricPFQ[{a2, a1}, {b1, b2, b3}, x]

Wolfram Language code: HypergeometricPFQ[{a1, a2}, {b1, b2, b3}, x] == HypergeometricPFQ[{a1, a2}, {b1, b3, b2}, x]

HypergeometricPFQ is an analytic function of z for specific values:

Wolfram Language code: FunctionAnalytic[HypergeometricPFQ[{1, 1}, {3, 3, 3}, z], z]

Wolfram Language code: FunctionAnalytic[HypergeometricPFQ[{1, 1, 2}, {3, 3}, z], z]

HypergeometricPFQ is neither non-decreasing nor non-increasing for specific values:

Wolfram Language code: FunctionMonotonicity[HypergeometricPFQ[{1, 1, 2}, {3, 3}, z], z]

Wolfram Language code: FunctionMonotonicity[HypergeometricPFQ[{1, 1}, {3, 3, 3}, z], z]

HypergeometricPFQ[{1,1,1},{3,3,3},z] is injective:

Wolfram Language code: FunctionInjective[HypergeometricPFQ[{1, 1, 1}, {3, 3, 3}, z], z]

Wolfram Language code: Plot[{HypergeometricPFQ[{1, 1, 1}, {3, 3, 3}, z], 2}, {z, -20, 20}]

HypergeometricPFQ[{1,1,1},{3,3,3},z] is not surjective:

Wolfram Language code: FunctionSurjective[HypergeometricPFQ[{1, 1, 1}, {3, 3, 3}, z], z]

Wolfram Language code: Plot[{HypergeometricPFQ[{1, 1, 1}, {3, 3, 3}, z], -2}, {z, -20, 20}]

HypergeometricPFQ is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[HypergeometricPFQ[{1, 1, 1}, {3, 3, 3}, z], z]

Wolfram Language code: FunctionSign[HypergeometricPFQ[{1, 1, 2}, {3, 3}, z], z]

HypergeometricPFQ[{1,1,2},{3,3},z] has both singularity and discontinuity for z≥1 and at zero:

Wolfram Language code: FunctionSingularities[HypergeometricPFQ[{1, 1, 2}, {3, 3}, z], z]

Wolfram Language code: FunctionDiscontinuities[HypergeometricPFQ[{1, 1, 2}, {3, 3}, z], z]

HypergeometricPFQ is neither convex nor concave:

Wolfram Language code: FunctionConvexity[HypergeometricPFQ[{1, 1, 2}, {3, 3}, z], z]

Wolfram Language code: FunctionConvexity[HypergeometricPFQ[{1, 1, 1}, {3, 3, 3}, z], z]

Differentiation (2)

First derivative:

Wolfram Language code: D[HypergeometricPFQ[{a1, a2}, {b1, b2, b3}, x], x]

Higher derivatives:

Wolfram Language code: derivs = Table[D[HypergeometricPFQ[{a1, a2}, {b1, b2, b3}, x], {x, n}], {n, 1, 3}]//FullSimplify

Plot higher derivatives for some values parameters:

Wolfram Language code:

Plot[Evaluate[derivs /. {a1 -> 1, a2 -> 1, b1 -> 3, b2 -> 3, b3 -> 3}], {x, -100, 100}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Integration (3)

Indefinite integral of HypergeometricPFQ:

Wolfram Language code: Integrate[HypergeometricPFQ[{a1, a2}, {b1, b2, b3}, x], x]

Definite integral of HypergeometricPFQ:

Wolfram Language code: Integrate[HypergeometricPFQ[{1, a2}, {b1, b2, b3}, x], {x, 0, 1}]

Integral with a power function:

Wolfram Language code: Integrate[x ^ (α - 1)HypergeometricPFQ[{a1, a2}, {b1, b2, b3}, x], x]//FullSimplify

Series Expansions (4)

Taylor expansion for HypergeometricPFQ:

Wolfram Language code: Series[HypergeometricPFQ[{a1, a2}, {b1, b2, b3}, x], {x, 0, 3}]

Plot the first three approximations for around :

Wolfram Language code:

terms = Normal@Table[Series[HypergeometricPFQ[{1, 1}, {3, 3, 3}, x], {x, 0, m}], {m, 1, 3}];
Plot[{HypergeometricPFQ[{1, 1}, {3, 3, 3}, x], terms}, {x, -30, 30}]

General term in the series expansion of HypergeometricPFQ:

Wolfram Language code: SeriesCoefficient[HypergeometricPFQ[{a1, a2}, {b1, b2, b3}, x], {x, 0, n}]

Expand HypergeometricPFQ of type into a series at the branch point :

Wolfram Language code: Series[ HypergeometricPFQ[{(1/3), (2/3), 1}, {(4/3), (4/3)}, z], {z, 1, 1}]

Expand HypergeometricPFQ into a series around :

Wolfram Language code: Series[ HypergeometricPFQ[{1 / 3, 2 / 3}, {-1 / 3, -1 / 3}, z], {z, Infinity, 2}]//FullSimplify

Function Representations (4)

Primary definition:

Wolfram Language code:

Underoverscript[∑, k = 0, ∞](Pochhammer[a1, k]Pochhammer[a2, k]  z^k/Pochhammer[b1, k]Pochhammer[b2, k]Pochhammer[b3, k]k!)

HypergeometricPFQ can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[HypergeometricPFQ[{a}, {b1, b2}, x], x]

HypergeometricPFQ can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[HypergeometricPFQ[{a}, {b1, b2}, x], x]

Wolfram Language code: Activate[%]//FullSimplify

TraditionalForm formatting:

Wolfram Language code:

HypergeometricPFQ[{Subscript[a, 1], Subscript[a, 2], Subscript[a, 3]}, {Subscript[b, 1], Subscript[b, 2]}, z]//TraditionalForm

Applications (7)

Solve a differential equation of hypergeometric type:

Wolfram Language code: DSolve[f'''[z] == z^3 f[z], f[z], z]

Solve a third-order singular ODE in terms of the HypergeometricPFQ and MeijerG functions:

Wolfram Language code: DSolve[x y'''[x] + x y'[x] - y[x] == 0, y, x]

Verify that the components of the general solution for an ODE are linearly independent:

Wolfram Language code: Wronskian[Coefficient[y[x] /. %[[1]], Table[C[i], {i, 3}]], x]

A formula for solutions to the trinomial equation :

Wolfram Language code:

x[m_, n_Integer, t_] /; m < n := Sum[-(1/k! (n - 1))Pochhammer[1 + (k - 1/n - 1), k - 1]Exp[((k - 1) 2 π I m/n - 1)]t^k HypergeometricPFQ[(k - 1/n - 1) + (Range[n - 1]/n), (Delete[Range[k + 1, k + n - 1], n - k - 1]/n - 1), n ((n t/n - 1))^n - 1], {k, 0, n - 2}];
x[m_, n_Integer, t_] /; m == n := t HypergeometricPFQ[(Range[n]/n), (Range[2, n]/n - 1), n ((n t/n - 1))^n - 1]

First root of the quintic :

Wolfram Language code: x[1, 5, 1]//TraditionalForm

Wolfram Language code: N[%, 20]

Check the solution:

Wolfram Language code: x ^ 5 - x + 1 == 0 /. x -> %

Effective confining potential in random matrix theory for a Gaussian density of states:

Wolfram Language code: v[x_] := x ^ 2 HypergeometricPFQ[{1, 1}, {2, 3 / 2}, -x ^ 2]

Wolfram Language code: Plot[v[x], {x, 0, 5}]

Its series expansion at infinity reveals logarithmic growth:

Wolfram Language code: Series[v[x], {x, ∞, 3}]//Expand

An expression for the surface tension of an electrolyte solution as a function of concentration y:

Wolfram Language code:

2 BesselK[0, 2Sqrt[y]]HypergeometricPFQ[{1}, {2 / 3, 5 / 3}, y] + 3Sqrt[y]BesselK[1, 2Sqrt[y]]HypergeometricPFQ[{1}, {5 / 3, 5 / 3}, y];

Onsager–Samaras limiting law for very low concentrations:

Wolfram Language code: Normal[Series[%, {y, 0, 0}, Assumptions -> y > 0]]

Fractional derivative of Sin:

Wolfram Language code: 𝒟[z_, m_] = Integrate[(z - t)^-m - 1 Sin[t] / Gamma[-m], {t, 0, z}, GenerateConditions -> False]

Derivative of order of Sin:

Wolfram Language code: 𝒟[z, 1 / 2]//FunctionExpand//FullSimplify

Plot a smooth transition between the derivative and integral of Sin:

Wolfram Language code: Plot3D[𝒟[z, m], {z, 0, 2Pi}, {m, -1, 1}]

Define the Gram polynomial in terms of HypergeometricPFQ:

Wolfram Language code: gramP[k_Integer, m_Integer, t_Integer] := (-1) ^ k HypergeometricPFQ[{-k, k + 1, -t - m}, {1, -2 m}, 1]

Verify a discrete orthogonality relation satisfied by the Gram polynomials:

Wolfram Language code:

With[{m = 4}, Table[Underoverscript[∑, t = -m, m]gramP[n1, m, t]gramP[n2, m, t] == KroneckerDelta[n1, n2](2 m + n1 + 1/2 n1 + 1)(Binomial[2m + n1, n1]/Binomial[2m, n1]), {n1, m + 1}, {n2, m + 1}]]

Use the Gram polynomial to compute the Savitzky–Golay smoothing coefficients:

Wolfram Language code:

savitzkyGolayCoefs[m_Integer, n_Integer] := Table[Underoverscript[∑, k = 0, n](Binomial[2 m, k]/Binomial[2 m + k + 1, k + 1]) (1 + (k/k + 1))gramP[k, m, i] gramP[k, m, 0], {i, -m, m}]

Wolfram Language code: savitzkyGolayCoefs[7, 4]

Compare with the result of SavitzkyGolayMatrix:

Wolfram Language code: SavitzkyGolayMatrix[{7}, 4, WorkingPrecision -> ∞]

Properties & Relations (3)

Integrate frequently returns results containing HypergeometricPFQ:

Wolfram Language code: Integrate[Exp[-x ^ 2]Log[x], x]

Sum may return results containing HypergeometricPFQ:

Wolfram Language code: Sum[((2k)!/ (4k + 3)!), {k, 0, Infinity}]

Use FunctionExpand to transform HypergeometricPFQ into less general functions:

Wolfram Language code: FunctionExpand[HypergeometricPFQ[{(3/2)}, {1, 1}, x]]

Possible Issues (2)

Machine-precision input may be insufficient to get a correct answer:

Wolfram Language code: HypergeometricPFQ[{10, 10}, {50}, 2.]

With exact input, the answer is correct:

Wolfram Language code: N[HypergeometricPFQ[{10, 10}, {50}, 2], 20]

Common symbolic parameters in HypergeometricPFQ generically cancel:

Wolfram Language code: HypergeometricPFQ[{a, b, c}, {a, d, e}, z]

However, when there is a negative integer among common elements, HypergeometricPFQ is interpreted as a polynomial:

Wolfram Language code: HypergeometricPFQ[{-2, a, b, c}, {-2, d, e}, z]

Neat Examples (1)

The period of an anharmonic oscillator with Hamiltonian :

Wolfram Language code:

period[n_, ℰ_, λ_, ω_] := (2 π/ω)HypergeometricPFQ[Range[1 / 2, n - 1 / 2] / n, Range[n - 1] / (n - 1), -((2n/ω^2))^n(λ ℰ^n - 1/(n - 1)^n - 1)]

Period for quartic anharmonicity:

Wolfram Language code: period[2, ℰ, λ, ω]

Limit of pure quartic potential:

Wolfram Language code: Limit[%, ω -> 0, Direction -> 1]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

HypergeometricPFQ

Details

Examples

Basic Examples (5)

Scope (34)

Numerical Evaluation (6)

Specific Values (4)

Visualization (2)

Function Properties (9)

Differentiation (2)

Integration (3)

Series Expansions (4)

Function Representations (4)

Applications (7)

Properties & Relations (3)

Possible Issues (2)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

HypergeometricPFQ

Details

Examples

Basic Examples (5)

Scope (34)

Numerical Evaluation (6)

Specific Values (4)

Visualization (2)

Function Properties (9)

Differentiation (2)

Integration (3)

Series Expansions (4)

Function Representations (4)

Applications (7)

Properties & Relations (3)

Possible Issues (2)

Neat Examples (1)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX