WOLFRAM

Wolfram Language & System Documentation Center

FrameTicks

is an option for 2D graphics functions that specifies tick marks for the edges of a frame.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
FrameTicks Positions and Labeling  
FrameTicks Styling  
Generalizations & Extensions  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

FrameTicks

FrameTicks

is an option for 2D graphics functions that specifies tick marks for the edges of a frame.

Details

  • The following settings can be given for FrameTicks:
  • Noneno tick marks drawn
    Automatictick marks placed automatically
    Truetick marks placed automatically on bottom and left edges
    Alltick marks placed automatically on all edges
    {{left,right},{bottom,top}}tick mark options specified separately for each edge
  • When separate tick mark specifications are given for each edge, All specifies that tick mark labels should be included.
  • Automatic tick marks are usually placed at points whose coordinates have the minimum number of digits in their decimal representation.
  • For each edge, the following tick mark options can be given:
  • Noneno tick marks drawn
    Automatictick mark positions and labels chosen automatically
    Allautomatic positions are labeled
    {x1,x2,…}tick marks drawn at the specified positions
    {{x1,label1},{x2,label2},…}tick marks drawn with the specified labels
    {{x1,label1,len1},…}tick marks with specified scaled length
    { { x 1 , label 1 , { plen 1 , mlen 1 } } , … }
    		tick marks with specified lengths in the positive and negative directions
    {{x1,label1,len1,style1},…}tick marks with specified styles
    funca function to be applied to xmin, xmax to get the tick mark specification
  • If no explicit labels are given, the tick mark labels are given as the numerical values of the tick mark positions.
  • Any expression can be given as a tick mark label.
  • Tick mark lengths are given as a fraction of the distance across the whole plot.
  • Tick mark styles can involve any graphics directives.
  • The tick mark function func[xmin,xmax] may return any other tick mark option.
  • FrameTicksStyle gives default styles to use for frame tick marks and tick mark labels.
  • Frame ticks are only shown if the frame itself is drawn, as specified by Frame.

Examples

open all close all

Basic Examples  (4)

Put a frame, but no ticks:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> None]

Place frame tick marks and labels automatically:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> Automatic]
Wolfram Language code: LogLogPlot[Abs[(ω I - 1)(ω I + 1) / ((ω I + 10)(ω I - 10))], {ω, 1, 10 ^ 3}, Frame -> True, FrameTicks -> Automatic]

Place frame tick marks at the specified positions:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{{-1, 0, 1}, None}, {{0, Pi, 2Pi, 3Pi}, None}}]

Specify overall frame ticks style, including frame tick labels, using FrameTicksStyle:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicksStyle -> Directive[Orange, 12]]

Scope  (10)

FrameTicks Positions and Labeling  (4)

Place frame ticks and labels on all the edges:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> All]

Place frame ticks on the left edge of the frame:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{All, None}, {None, None}}]

Place frame ticks on the right and top edges:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{None, All}, {None, All}}]

Draw frame ticks at the specified positions on the right and bottom edges:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{None, {-1 / 2, 1 / 2}}, {{0, Pi, 2Pi, 3Pi}, None}}]

Draw frame ticks at the specified positions with the specific labels:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{{0, 0°}, {Pi, 180°}, {2Pi, 360°}, {3Pi, 540°}}, {-1 / 2, 1 / 2}}]

FrameTicks Styling  (6)

Specify frame ticks with scaled lengths:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{{0, 0°, .2}, {Pi, 180°, .2}, {2Pi, 360°, .2}, {3Pi, 540°, .2}}, {-1 / 2, 1 / 2}}]

Specify frame ticks with scaled lengths in positive and negative directions:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{{0, 0°, {.4, .05}}, {Pi, 180°, {.4, .05}}, {2Pi, 360°, {.4, .05}}, {3Pi, 540°, {.4, 0.05}}}, {-1 / 2, 1 / 2}}]

Specify the style of each frame tick:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{{Pi, 180°, {.4, .05}, Red}, {2Pi, 360°, {.4, .05}, Thick}, {3Pi, 540°, {.4, .05}, Directive[Red, Dashed]}}, {-1, 1}}]

Specify overall frame ticks style, using FrameTicksStyle:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Frame -> True, FrameTicks -> All, FrameTicksStyle -> Directive[Orange, 12]]

Specify frame ticks style for each edge:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Frame -> True, FrameTicks -> All, FrameTicksStyle -> {{Magenta, Blue}, {Red, Green}}]

Individually styled frame ticks can be used with FrameTicksStyle, and have higher priority:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{0, {Pi, Pi, {.4, 0}, Directive[Blue, Dashed]}, 2Pi, 3Pi}, None}, FrameTicksStyle -> Directive[Orange, 12]]

Generalizations & Extensions  (1)

Specify a frame ticks function applied to xmin and xmax values for each direction:

Wolfram Language code: fticks[min_, max_] := Table[If[EvenQ[i], {i, i, {.1, 0}, Red}, {i, i, {.05, 0}, Blue}], {i, Ceiling[min], Floor[max], 1}]
Wolfram Language code: Graphics[Circle[{0, 0}, 2], Frame -> True, FrameTicks -> fticks]

Properties & Relations  (6)

FrameTicksStyle affects frame ticks and frame tick labels:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {x, y}, PlotLabel -> 2Sin[x], FrameTicksStyle -> Green]

LabelStyle offers overall style of all the label-like elements, including frame tick labels:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {x, y}, PlotLabel -> 2Sin[x], LabelStyle -> Directive[Red, FontFamily -> "Helvetica"]]

FrameTicksStyle can be used together with LabelStyle and has higher priority:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {x, y}, PlotLabel -> 2Sin[x], LabelStyle -> Directive[Red, FontFamily -> "Helvetica"], FrameTicksStyle -> Green]

FrameStyle affects the style of the frame, frame labels, frame ticks, and frame tick labels:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {x, y}, PlotLabel -> 2Sin[x], FrameStyle -> Directive[Gray, FontSize -> 15]]

FrameTicksStyle can be used together with FrameStyle and has higher priority:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {x, y}, PlotLabel -> 2Sin[x], FrameStyle -> Directive[Gray, FontSize -> 15], FrameTicksStyle -> Green]

Individually styled frame ticks can be used with other styles and have higher priority:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{0, {Pi, Pi, {.4, 0}, Directive[Blue, Thick]}, 2Pi, 3Pi}, None}, FrameStyle -> Directive[Gray, Dashed], FrameTicksStyle -> Directive[Orange, 12]]

Ticks controls the ticks and tick labels on the axes:

Wolfram Language code: Graphics[Circle[], Axes -> True, Ticks -> Automatic]

Use DateListPlot to get frame ticks that correspond to date and time:

Wolfram Language code: DateListPlot[FinancialData["IBM", "Jan. 1, 2004"]]
Wolfram Research (1991), FrameTicks, Wolfram Language function, https://reference.wolfram.com/language/ref/FrameTicks.html (updated 2008).

Text

Wolfram Research (1991), FrameTicks, Wolfram Language function, https://reference.wolfram.com/language/ref/FrameTicks.html (updated 2008).

CMS

Wolfram Language. 1991. "FrameTicks." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/FrameTicks.html.

APA

Wolfram Language. (1991). FrameTicks. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FrameTicks.html

BibTeX

@misc{reference.wolfram_2026_frameticks, author="Wolfram Research", title="{FrameTicks}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/FrameTicks.html}", note=[Accessed: 15-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_frameticks, organization={Wolfram Research}, title={FrameTicks}, year={2008}, url={https://reference.wolfram.com/language/ref/FrameTicks.html}, note=[Accessed: 15-June-2026]}