WOLFRAM

Wolfram Language & System Documentation Center

Ticks

is an option for graphics functions that specifies tick marks for axes.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Ticks Positions and Labeling  
Ticks Styling  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
History
Cite this Page

Ticks

Ticks

is an option for graphics functions that specifies tick marks for axes.

Details

  • The following settings can be given for Ticks:
  • Noneno tick marks drawn
    Automatictick marks placed automatically
    {xticks,yticks,…}tick mark options specified separately for each axis
  • With the Automatic setting, tick marks are usually placed at points whose coordinates have the minimum number of digits in their decimal representation.
  • For each axis, the following tick mark options can be given:
  • Noneno tick marks drawn
    Automatictick mark positions and labels chosen automatically
    {x1,x2,…}tick marks drawn at the specified positions
    {{x1,label1},{x2,label2},…}tick marks drawn with the specified labels
    {{x1,label1,len1},…}tick marks with specified scaled length
    { { x 1 , label 1 , { plen 1 , mlen 1 } } , … }
    		tick marks with specified lengths in the positive and negative directions
    {{x1,label1,len1,style1},…}tick marks with specified styles
    funca function to be applied to xmin, xmax to get the tick mark specification
  • If no explicit labels are given, the tick mark labels are given as the numerical values of the tick mark positions.
  • Any expression can be given as a tick mark label.
  • Tick mark lengths are given as a fraction of the distance across the whole plot.
  • Tick mark styles can involve any graphics directives.
  • The tick mark function func[xmin,xmax] may return any other tick mark option.
  • Ticks can be used in both two- and three-dimensional graphics.
  • AbsoluteOptions gives the explicit form of Ticks specifications when Automatic settings are given.
  • TicksStyle gives default styles to use for tick marks and tick mark labels.

Examples

open all close all

Basic Examples  (4)

Draw the axes but no tick marks:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> None]

Place tick marks automatically:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> Automatic]
Wolfram Language code: LogLogPlot[Abs[(ω I - 1)(ω I + 1) / ((ω I + 10)(ω I - 10))], {ω, 1, 10 ^ 3}, Ticks -> Automatic]

Place tick marks at specific positions:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> {{0, Pi, 2Pi, 3Pi}, {-1, 1}}]
Wolfram Language code: Plot3D[Sin[x y], {x, 0, Pi}, {y, 0, Pi}, Ticks -> {{0, Pi / 2, Pi}, {0, Pi / 2, Pi}, {-1, 0, 1}}]

Specify overall ticks style, including the tick labels, using TicksStyle:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, TicksStyle -> Directive[Orange, 12]]

Scope  (8)

Ticks Positions and Labeling  (3)

Place ticks on the axis only:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> {Automatic, None}]

Place ticks on the axis only:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> {None, Automatic}]

Draw tick marks at the specified positions:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> {{Pi, 2Pi, 3Pi}, {-1, 1}}]
Wolfram Language code: Graphics3D[Cylinder[], Ticks -> {{-1, 0, 1}, {-1, 0, 1}, {-1, 0, 1}}, Axes -> True]

Draw tick marks at the specified positions with the specified labels:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> {{{Pi, 180°}, {2Pi, 360°}, {3Pi, 540°}}, {-1, 1}}]
Wolfram Language code: Graphics3D[Cylinder[], Axes -> True, Ticks -> {None, None, {{-1, "bottom"}, {0, "center"}, {1, "top"}}}]

Ticks Styling  (5)

Specify tick marks with scaled lengths:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Ticks -> {{{Pi, 180°, 1}, {2Pi, 360°, 1}, {3Pi, 540°, 1}}, {-1, 1}}]

Specify tick marks with scaled lengths in positive and negative directions:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Ticks -> {{{Pi, 180°, {0, .5}}, {2Pi, 360°, {.5, 0}}, {3Pi, 540°, {0, .5}}}, {-1, 1}}]

Specify the style of each tick mark:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Ticks -> {{{Pi, 180°, {0, .5}, Red}, {2Pi, 360°, {.5, 0}, Thick}, {3Pi, 540°, {0, .5}, Directive[Red, Dashed]}}, {-1, 1}}]

Specify overall ticks style, including tick labels, using TicksStyle:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, TicksStyle -> Directive[Orange, 12]]

Specify ticks style for each axis:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, TicksStyle -> {Red, Blue}]

Individually styled ticks can be used with TicksStyle, and have higher priority:

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Ticks -> {{0, {Pi, Pi, .5, Directive[Blue, Dashed]}, 2Pi, 3Pi}, None}, TicksStyle -> Directive[Orange, 12]]

Generalizations & Extensions  (1)

Specify a grid function applied to xmin and xmax values of each direction:

Wolfram Language code: ticks[min_, max_] := Table[If[EvenQ[i], {i, i, .06, Red}, {i, i, .02, Blue}], {i, Ceiling[min], Floor[max], 1}]
Wolfram Language code: Graphics[Circle[{0, 0}, 4], Axes -> True, Ticks -> ticks]

Applications  (1)

Put a major tick with a label at each integer, and a minor tick in between:

Wolfram Language code: ticks[min_, max_] := Join[Table[{i, Style[i, 12], {.04, 0}}, {i, Ceiling[min], Floor[max]}], Table[{j + .5, , {.02, 0}}, {j, Round[min], Round[max - 1], 1}]]
Wolfram Language code: Plot3D[Sin[x y], {x, 0, 4}, {y, 0, 4}, Ticks -> ticks, Mesh -> None]

Properties & Relations  (7)

TicksStyle affects ticks and tick labels:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, AxesLabel -> {x, y}, PlotLabel -> 2Sin[x], TicksStyle -> Orange]

LabelStyle offers overall style of all the label-like elements, including tick labels:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, PlotLabel -> 2Sin[x], AxesLabel -> {x, y}, LabelStyle -> Directive[Blue, FontFamily -> "Helvetica"]]

TicksStyle can be used together with LabelStyle and has higher priority:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, PlotLabel -> 2Sin[x], AxesLabel -> {x, y}, LabelStyle -> Directive[Blue, FontFamily -> "Helvetica"], TicksStyle -> Orange]

AxesStyle affects the axes, axes labels, ticks and tick labels:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, AxesLabel -> {x, y}, PlotLabel -> 2Sin[x], TicksStyle -> Orange]

TicksStyle can be used together with AxesStyle, and has higher priority:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, AxesLabel -> {x, y}, PlotLabel -> 2Sin[x], AxesStyle -> Directive[Gray, FontSize -> 15], TicksStyle -> Orange]

Individually styled ticks can be used with other styles, and have higher priority:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> {{0, {Pi, Pi, 1, Directive[Blue, Thick]}, 2Pi, 3Pi}, {-1, 1}}, AxesStyle -> Directive[Gray, Dashed], TicksStyle -> Directive[Orange, 12]]

FrameTicks controls the ticks and tick labels on the frame edges:

Wolfram Language code: Graphics[Circle[], Frame -> True, FrameTicks -> All]

GridLines puts grids across the image:

Wolfram Language code: Graphics[Circle[], GridLines -> Automatic, Axes -> True]

FaceGrids puts grids on the faces of the bounding box in 3D:

Wolfram Language code: Graphics3D[Cylinder[], FaceGrids -> All, Axes -> True]

Possible Issues  (1)

A tick label on the axes origin is not displayed:

Wolfram Language code: Plot[Sin[x], {x, -4, 4}, Ticks -> {{-Pi, 0, Pi}, {-1, 0, 1}}]
Wolfram Research (1988), Ticks, Wolfram Language function, https://reference.wolfram.com/language/ref/Ticks.html (updated 2007).

Text

Wolfram Research (1988), Ticks, Wolfram Language function, https://reference.wolfram.com/language/ref/Ticks.html (updated 2007).

CMS

Wolfram Language. 1988. "Ticks." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/Ticks.html.

APA

Wolfram Language. (1988). Ticks. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Ticks.html

BibTeX

@misc{reference.wolfram_2026_ticks, author="Wolfram Research", title="{Ticks}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Ticks.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_ticks, organization={Wolfram Research}, title={Ticks}, year={2007}, url={https://reference.wolfram.com/language/ref/Ticks.html}, note=[Accessed: 13-June-2026]}