WOLFRAM

Wolfram Language & System Documentation Center

FrameLabel

is an option for Graphics, Manipulate, and related functions that specifies labels to be placed on the edges of a frame.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Workflows
History
Cite this Page

FrameLabel

FrameLabel

is an option for Graphics, Manipulate, and related functions that specifies labels to be placed on the edges of a frame.

Details

  • FrameLabel->None specifies that no labels should be given.
  • FrameLabel->label specifies a label for the bottom edge of the frame.
  • FrameLabel->{bottom,left} specifies labels for the bottom and left‐hand edges of the frame.
  • FrameLabel->{{left,right},{bottom,top}} specifies labels for each of the edges of the frame.
  • Any expression can be specified as a label. It will be given by default in TraditionalForm. Arbitrary strings of text can be given as "text". »
  • Labels for the vertical edges of the frame are by default written vertically. RotateLabel->False specifies that they should be horizontal.

Examples

open all close all

Basic Examples  (4)

Place labels on the bottom edge of the frame:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> x]

Place labels on the bottom and left frame edges:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {x, y}]

Specify labels for each edge:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {{y, Sin[x]}, {x, "plot"}}]

Overall style of all the label-like elements can be specified by LabelStyle:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {x, y}, LabelStyle -> Directive[Red, Bold]]

Scope  (3)

Labels use TraditionalForm by default:

Wolfram Language code: Graphics[Circle[], Frame -> True, FrameLabel -> {x, y}]

Use StandardForm instead:

Wolfram Language code: Graphics[Circle[], Frame -> True, FrameLabel -> {StandardForm[x], StandardForm[y]}]

Individually styled labels can be used together with LabelStyle, and have higher priority:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {Style[x, Bold, Red], Style[y, Bold, Blue]}, LabelStyle -> Directive[Orange, Medium]]

Generalizations & Extensions  (3)

Specify frame labels for Manipulate:

Wolfram Language code: Manipulate[x, {x, 0, 1}, FrameLabel -> {{a, b}, {c, d}}]

Use labels based on variables specified in ContourPlot and DensityPlot:

Wolfram Language code: ContourPlot[ρ Sin[θ], {ρ, -5, 5}, {θ, -5, 5}, FrameLabel -> Automatic]
Wolfram Language code: DensityPlot[ρ Sin[θ], {ρ, -5, 5}, {θ, -5, 5}, FrameLabel -> Automatic]

Use graphics as a frame label:

Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}, Frame -> True, FrameLabel -> Table[Graphics[{Arrowheads[Medium], Arrow[{{0, 0}, {1, 0}}]}, AspectRatio -> 1 / 4, ImageSize -> 40], {2}]]

Applications  (1)

Use ColorData image as a label:

Wolfram Language code: l = Show[ColorData["SunsetColors", "Image"], ImageSize -> 120, Frame -> True, FrameTicks -> {{None, None}, {{{0, "Low"}, {1, "High"}}, None}}]
Wolfram Language code: DensityPlot[x + Sin[x y], {x, 0, 6}, {y, -3, 3}, ColorFunction -> "SunsetColors", FrameLabel -> l]

Properties & Relations  (3)

The overall output format can be specified using FormatType:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {x, Sin[x]}, FormatType -> StandardForm]

Vertical frame labels are rotated in graphics, by default:

Wolfram Language code: Graphics[Circle[], Frame -> True, FrameLabel -> {{left, right}, {None, None}}]

Vertical frame labels are not rotated in Manipulate, by default:

Wolfram Language code: Manipulate[x, {x, 0, 1}, FrameLabel -> {{left, right}, {None, None}}]

The vertical label rotation can be specified using RotateLabel:

Wolfram Language code: Graphics[Circle[], Frame -> True, FrameLabel -> {None, "y-axis"}, RotateLabel -> False]

Possible Issues  (1)

When different format types are combined the result is likely to be unpredictable:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {x, TraditionalForm@Sin[x]}, FormatType -> StandardForm]

This is equivalent to:

Wolfram Language code: StandardForm[TraditionalForm[Sin[x]]]

Neat Examples  (1)

Control the ellipse with the sliders:

Wolfram Language code: Graphics[{StandardPink, EdgeForm[ThemeColor["Foreground"]], Dynamic@Disk[{0, 0}, {r, s}]}, PlotRange -> 10, Frame -> True, ImageSize -> 300, FrameLabel -> {Slider[Dynamic[r], {1, 10}], VerticalSlider[Dynamic[s], {1, 10}]}, RotateLabel -> False]
Wolfram Research (1991), FrameLabel, Wolfram Language function, https://reference.wolfram.com/language/ref/FrameLabel.html (updated 2007).

Text

Wolfram Research (1991), FrameLabel, Wolfram Language function, https://reference.wolfram.com/language/ref/FrameLabel.html (updated 2007).

CMS

Wolfram Language. 1991. "FrameLabel." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/FrameLabel.html.

APA

Wolfram Language. (1991). FrameLabel. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FrameLabel.html

BibTeX

@misc{reference.wolfram_2026_framelabel, author="Wolfram Research", title="{FrameLabel}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/FrameLabel.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_framelabel, organization={Wolfram Research}, title={FrameLabel}, year={2007}, url={https://reference.wolfram.com/language/ref/FrameLabel.html}, note=[Accessed: 13-June-2026]}