finds the discontinuities of 
for x∈Reals.
FunctionDiscontinuities[f,x,dom]
finds the discontinuities of 
for x∈dom.
FunctionDiscontinuities[{f1,f2,…},{x1,x2,…},dom]
finds the discontinuities of 
for x1,x2,…∈dom.
FunctionDiscontinuities
finds the discontinuities of 
for x∈Reals.
FunctionDiscontinuities[f,x,dom]
finds the discontinuities of 
for x∈dom.
FunctionDiscontinuities[{f1,f2,…},{x1,x2,…},dom]
finds the discontinuities of 
for x1,x2,…∈dom.
Details
- Function discontinuities are typically used to either find regions where a function is guaranteed to be continuous or to find points and curves where special analysis needs to be performed.
- FunctionDiscontinuities gives an implicit description of a set
such that 
is continuous in 
. The set 
is not guaranteed to be minimal. - The resulting implicit description consists of equations, inequalities, domain specifications and logical combinations of these suitable for use in functions such as Reduce and Solve, etc.
- Possible values for dom are Reals and Complexes.
Examples
open all close allBasic Examples (4)
Find the discontinuities of a real univariate function:
FunctionDiscontinuities[Tan[x], x]Find the discontinuities of a complex univariate function:
FunctionDiscontinuities[Log[x], x, Complexes]Find the discontinuities of a real multivariate function:
FunctionDiscontinuities[Beta[x, y], {x, y}]Find the discontinuities of a complex multivariate function:
FunctionDiscontinuities[ArcTan[x ^ y], {x, y}, Complexes]Scope (6)
Discontinuities of a real univariate function:
FunctionDiscontinuities[Gamma[x], x]Find the discontinuity points between 
and 
:
Solve[% && -5 ≤ x ≤ 5, x, Reals]Visualize the discontinuities:
Plot[Gamma[x], {x, -5, 5}, Epilog -> {PointSize[Medium], Red, Point[{x, 0}] /. %}]Discontinuities of a function composition:
FunctionDiscontinuities[Floor[1 / (x ^ 2 - 1)], x]Find a finite set of discontinuity points between 
and 
:
Solve[% && -2 ≤ x ≤ 2 && Abs[1 / (x ^ 2 - 1)] < 7, x, Reals]Visualize the discontinuities:
Plot[Floor[1 / (x ^ 2 - 1)], {x, -2, 2}, PlotStyle -> Thick, Epilog -> {Red, Thin, Dotted, InfiniteLine[{x, 0}, {0, 1}] /. %}]Discontinuities over the reals include the points where the function is not real valued:
FunctionDiscontinuities[Sqrt[x], x]Discontinuities of a complex univariate function:
FunctionDiscontinuities[ArcTan[z ^ 2], z, Complexes]Compute the discontinuities in terms of Re[z] and Im[z]:
Reduce[%, z]Visualize the discontinuities:
Show[{ComplexPlot[ArcTan[z ^ 2], {z, -2 - 2I, 2 + 2I}], Region[Style[ImplicitRegion[%, {Re[z], Im[z]}], Red]]}]Discontinuities of a real multivariate function:
FunctionDiscontinuities[(x ^ 2 + y ^ 2)Csc[x y], {x, y}]Visualize the discontinuities:
Show[{Plot3D[(x ^ 2 + y ^ 2)Csc[x y], {x, -3, 3}, {y, -3, 3}], ContourPlot3D@@{%, {x, -3, 3}, {y, -3, 3}, {z, -40, 40}, ContourStyle -> {Red, Opacity[0.7]}, Mesh -> False}}]Discontinuities of a complex mapping:
FunctionDiscontinuities[{Sqrt[x - y], Log[x + y]}, {x, y}, Complexes]Applications (6)
Basic Applications (4)
![x+cos(x) TemplateBox[{{{sin, (, x, )}}}, UnitStepSeq]](Files/FunctionDiscontinuities.en/12.png "x+cos(x) TemplateBox[{{{sin, (, x, )}}}, UnitStepSeq]"){kind=small}
f = x + Cos[x] UnitStep[Sin[x]];FunctionDiscontinuities[f, x]Find the discontinuity points between 
and 
:
Solve[% && -5Pi ≤ x ≤ 5Pi, x, Reals]Visualize the discontinuities:
Plot[f, {x, -5Pi, 5Pi}, Epilog -> {Red, Thin, Dotted, InfiniteLine[{x, 0}, {0, 1}] /. %}]![max(log(TemplateBox[{x}, Abs]+1),x sin(x))](Files/FunctionDiscontinuities.en/15.png "max(log(TemplateBox[{x}, Abs]+1),x sin(x))"){kind=small}
f = Max[Log[Abs[x] + 1], x Sin[x]];FunctionDiscontinuities[f, x]Show that there are no discontinuities:
Reduce[%, x, Reals]
Plot[f, {x, -20, 20}]Find the discontinuities of the complex function 
:
f = Log[z ^ 3];FunctionDiscontinuities[f, z, Complexes]Compute the discontinuities in terms of Re[z] and Im[z]:
Reduce[%, z]Visualize the discontinuities:
Show[{ComplexPlot[f, {z, -2 - 2I, 2 + 2I}], Region[Style[ImplicitRegion[%, {{Re[z], -2, 2}, {Im[z], -2, 2}}], Red]]}]Find the discontinuities of 
given the discontinuities of 
and 
:
f[y_] := 1 / (y ^ 2 - 1)
g[x_] := Csc[x]Suppose the discontinuities of 
and 
are contained in solution sets of 
and 
:
Φ = FunctionDiscontinuities[f[y], y]Ψ = FunctionDiscontinuities[g[x], x]The discontinuities of 
are contained in the solution set of 
:
FunctionDiscontinuities[f[g[x]], x](Φ /. y -> g[x]) || ΨCalculus (1)
![TemplateBox[{{f, (, x, )}, x, a}, Limit2Arg, DisplayFunction -> ({Sequence[{Sequence["lim"], _, DocumentationBuild`Utils`Private`Parenth[{#2, ->, #3}, LimitsPositioning -> True]}], #1} & ), InterpretationFunction -> ({Limit, [, {#1, ,, {#2, ->, #3}}, ]} & )]=f(a)](Files/FunctionDiscontinuities.en/29.png "TemplateBox[{{f, (, x, )}, x, a}, Limit2Arg, DisplayFunction -> ({Sequence[{Sequence[\"lim\"], _, DocumentationBuild`Utils`Private`Parenth[{#2, ->, #3}, LimitsPositioning -> True]}], #1} & ), InterpretationFunction -> ({Limit, [, {#1, ,, {#2, ->, #3}}, ]} & )]=f(a)"){kind=small}
f = Sin[5 x] Floor[x + Ceiling[Tan[x] ^ 2]];FunctionDiscontinuities[f, x]
% /. x -> 5 / 4The limit of 
at 
can be found by simple substitution:
f /. x -> 5 / 4Limit[f, x -> 5 / 4]Plot[f, {x, 0, Pi}, Epilog -> {Red, Point[{5 / 4, %}]}]Visualization (1)
Use discontinuities to find Exclusions settings for Plot:
f = Clip[Floor[Gamma[x]], {-10, 10}];disc = FunctionDiscontinuities[f, x]Convert the discontinuities into the format required by Exclusions:
excl[e_Or] := Join@@(excl /@ List@@e)
excl[And[a___, e_Equal, b___]] := {{e, And[a, b]}}
excl[e_Equal] := {{e, True}}
excl[other_] := {}ex = excl[disc]Use the exclusions in Plot:
Plot[f, {x, -1, 1}, Exclusions -> ex]Compare to a plot computed without using exclusions:
Plot[f, {x, -1, 1}, Exclusions -> None]Properties & Relations (2)
The function is continuous outside the set given by FunctionDiscontinuities:
FunctionDiscontinuities[Tan[x], x]Use FunctionContinuous to check the continuity:
FunctionContinuous[{Tan[x], Not[%]}, x]FunctionSingularities gives a set outside which the function is analytic:
FunctionSingularities[Abs[x] / (x ^ 2 - 1), x]The set of discontinuities is a subset of the set of singularities:
FunctionDiscontinuities[Abs[x] / (x ^ 2 - 1), x]Show[{Plot[Abs[x] / (x ^ 2 - 1), {x, -2, 2}], ListPlot[...]}]Possible Issues (2)
The discontinuity set returned may not be minimal:
FunctionDiscontinuities[UnitStep[x - 1] UnitStep[-x], x]The function is identically zero, hence it has no discontinuities:
PiecewiseExpand[UnitStep[x - 1] UnitStep[-x]]When some discontinuity information is missing, an error message is given and the known discontinuities are returned:
FunctionDiscontinuities[f[x] + Tan[x], x]
Text
Wolfram Research (2020), FunctionDiscontinuities, Wolfram Language function, https://reference.wolfram.com/language/ref/FunctionDiscontinuities.html.
CMS
Wolfram Language. 2020. "FunctionDiscontinuities." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FunctionDiscontinuities.html.
APA
Wolfram Language. (2020). FunctionDiscontinuities. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FunctionDiscontinuities.html