Wolfram Language & System Documentation Center

FunctionContinuous

FunctionContinuous[f,x]

tests whether is a real-valued continuous function for x∈Reals.

FunctionContinuous[f,x,dom]

tests whether is a continuous function for x∈dom.

FunctionContinuous[{f₁,f₂,…},{x₁,x₂,…},dom]

tests whether are continuous functions for x₁,x₂,…∈dom.

FunctionContinuous[{funs,cons},xvars,dom]

tests whether are continuous functions for xvars∈dom restricted by the constraints cons.

FunctionContinuous

FunctionContinuous[f,x]

tests whether is a real-valued continuous function for x∈Reals.

FunctionContinuous[f,x,dom]

tests whether is a continuous function for x∈dom.

FunctionContinuous[{f₁,f₂,…},{x₁,x₂,…},dom]

tests whether are continuous functions for x₁,x₂,…∈dom.

FunctionContinuous[{funs,cons},xvars,dom]

tests whether are continuous functions for xvars∈dom restricted by the constraints cons.

Details and Options

A function is continuous in a set if for all and for all there is a such that for all , implies .
A function is continuous in a set if for all and for all there is a such that for all , $TemplateBox[{{{, {{{x, _, 1}, -, {y, _, 1}}, ,, ..., ,, {{x, _, n}, -, {y, _, n}}}, }}}, Norm]<delta({x_1,...,x_n},epsilon)$ implies $TemplateBox[{{{f, (, {{, {{x, _, 1}, ,, ..., ,, {x, _, n}}, }}, )}, -, {f, (, {{, {{y, _, 1}, ,, ..., ,, {y, _, n}}, }}, )}}}, Abs]<epsilon$ .
If funs contains parameters other than xvars, the result is typically a ConditionalExpression.
Possible values for dom are Reals and Complexes. The default is Reals.
If dom is Reals, then all variables, parameters, constants and function values are restricted to be real.
cons can contain equations, inequalities or logical combinations of these.
The functions funs need to be defined for all values that satisfy the constraints cons.
The following options can be given:

Assumptions	$Assumptions	assumptions on parameters
GenerateConditions	True	whether to generate conditions on parameters
PerformanceGoal	$PerformanceGoal	whether prioritize speed or quality

Possible settings for GenerateConditions include:
Automatic nongeneric conditions only

True all conditions

False no conditions

None return unevaluated if conditions are needed
Possible settings for PerformanceGoal are "Speed" and "Quality".

Examples

open all close all

Basic Examples (4)

Test continuity of real functions:

Wolfram Language code: FunctionContinuous[Sin[x], x]

Test continuity of complex functions:

Wolfram Language code: FunctionContinuous[Sqrt[x], x, Complexes]

Test continuity over restricted domains:

Wolfram Language code: FunctionContinuous[{Log[x], x > 0}, x]

Test continuity of multivariate functions:

Wolfram Language code: FunctionContinuous[Gamma[x ^ 2 + y ^ 2 + 1, E ^ (x y)], {x, y}]

Scope (6)

Real univariate functions:

Wolfram Language code: FunctionContinuous[Tanh[x], x]

Wolfram Language code: FunctionContinuous[Floor[x], x]

Wolfram Language code: Plot[{Tanh[x], Floor[x]}, {x, -3, 3}]

Complex univariate functions:

Wolfram Language code: FunctionContinuous[Exp[z], z, Complexes]

Wolfram Language code: FunctionContinuous[Log[z], z, Complexes]

Wolfram Language code: GraphicsRow[ComplexPlot[#, {z, -2 - 2I, 2 + 2I}]& /@ {Exp[z], Log[z]}, ImageSize -> Medium]

Functions with restricted domains:

Wolfram Language code: FunctionContinuous[{Tan[x], -Pi / 2 < x < Pi / 2}, x]

Wolfram Language code: FunctionContinuous[{Log[z], Im[z] ≠ 0}, z]

Real multivariate functions:

Wolfram Language code: FunctionContinuous[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + 1)], {x, y}]

Wolfram Language code: FunctionContinuous[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 - 1)], {x, y}]

Wolfram Language code: GraphicsRow[Plot3D[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + #)], {x, -2, 2}, {y, -2, 2}]& /@ {1, -1}, ImageSize -> Medium]

Complex multivariate functions:

Wolfram Language code: FunctionContinuous[LaguerreL[E ^ (x + z), Sin[y z]], {x, y, z}, Complexes]

Wolfram Language code: FunctionContinuous[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + 1)], {x, y}, Complexes]

Wolfram Language code: FunctionContinuous[{Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + 1)], x ^ 2 + y ^ 2 ≠ -1}, {x, y}, Complexes]

Functions with symbolic parameters:

Wolfram Language code: FunctionContinuous[Gamma[x ^ 2 + a], x]

Wolfram Language code: FunctionContinuous[Sin[x y] / (x ^ 2 + a x y + y ^ 2 + b), {x, y}]

Options (4)

Assumptions (1)

FunctionContinuous cannot find the answer for arbitrary values of the parameter :

Wolfram Language code: FunctionContinuous[Sin[x + y] / (Exp[x y] + a), {x, y}]

With the assumption that , FunctionContinuous succeeds:

Wolfram Language code: FunctionContinuous[Sin[x + y] / (Exp[x y] + a), {x, y}, Assumptions -> a > 0]

GenerateConditions (2)

By default, FunctionContinuous may generate conditions on symbolic parameters:

Wolfram Language code: FunctionContinuous[Log[x ^ 2 + a], x]

With GenerateConditionsNone, FunctionContinuous fails instead of giving a conditional result:

Wolfram Language code: FunctionContinuous[Log[x ^ 2 + a], x, GenerateConditions -> None]

This returns a conditionally valid result without stating the condition:

Wolfram Language code: FunctionContinuous[Log[x ^ 2 + a], x, GenerateConditions -> False]

By default, all conditions are reported:

Wolfram Language code: FunctionContinuous[Cos[x y] / a, {x, y}]

With GenerateConditionsAutomatic, conditions that are generically true are not reported:

Wolfram Language code: FunctionContinuous[Cos[x y] / a, {x, y}, GenerateConditions -> Automatic]

PerformanceGoal (1)

Use PerformanceGoal to avoid potentially expensive computations:

Wolfram Language code: FunctionContinuous[1 / (x ^ 4 + a x ^ 3 y + b x y ^ 3 + y ^ 4 + c), {x, y}, PerformanceGoal -> "Speed"]

The default setting uses all available techniques to try to produce a result:

Wolfram Language code: FunctionContinuous[1 / (x ^ 4 + a x ^ 3 y + b x y ^ 3 + y ^ 4 + c), {x, y}]

Applications (14)

Classes of Continuous Functions (6)

Polynomials are continuous:

Wolfram Language code: {FunctionContinuous[x, x], FunctionContinuous[x^2 + 1, x], FunctionContinuous[x^3 - 2 x^2 - 5 x + 6, x]}

Sin, Cos and Exp are continuous:

Wolfram Language code: {FunctionContinuous[Sin[x], x], FunctionContinuous[Cos[x], x], FunctionContinuous[Exp[x], x]}

Visualize these functions:

Wolfram Language code: Grid[Partition[Table[Plot[f, {x, -5, 5}], {f, {x, x^2 + 1, x^3 - 2 x^2 - 5 x + 6, Sin[x], Cos[x], Exp[x]}}], 3]]

These functions are continuous in the complex plane as well:

Wolfram Language code: Table[FunctionContinuous[f, x, Complexes], {f, {x, x^2 + 1, x^3 - 2 x^2 - 5 x + 6, Sin[x], Cos[x], Exp[x]}}]

Visualize these functions over :

Wolfram Language code: Grid[Partition[Table[ComplexPlot3D[f, {x, 5}], {f, {x, x^2 + 1, x^3 - 2 x^2 - 5 x + 6, Sin[x], Cos[x], Exp[x]}}], 3]]

The reciprocal of a continuous function is continuous wherever :

Wolfram Language code: FunctionContinuous[{(1/x), x ≠ 0}, x]

Thus, rational functions may or may not be continuous over the reals:

Wolfram Language code: FunctionContinuous[(4/x^2 + 4), x]

Wolfram Language code: FunctionContinuous[(1/x^2 - 4), x]

Wolfram Language code: Plot[{(4/x^2 + 4), (1/x^2 - 4)}, {x, -4, 4}, PlotTheme -> {"DashedLines", "Detailed"}]

However, as every nonconstant polynomial has a root in the plane, rational functions are never continuous on :

Wolfram Language code: FunctionContinuous[(4/x^2 + 4), x, Complexes]

Visualizing the function in the complex plane shows the blowup at :

Wolfram Language code: ComplexPlot3D[(4/x^2 + 4), {x, 4}]

As Cot and Csc are rational functions of Sin and Cos, they are continuous when sine is nonzero:

Wolfram Language code: {FunctionContinuous[{Cot[x], (x/π)∉ℤ}, x], FunctionContinuous[{Csc[x], (x/π)∉ℤ}, x]}

Visualize the functions along with sine:

Wolfram Language code: Plot[{Cot[x], Csc[x], Sin[x]}, {x, -3π, 3π}, PlotLegends -> "Expressions", PlotTheme -> "DashedLines"]

Similarly, Tan and Sec are continuous when cosine is nonzero:

Wolfram Language code: {FunctionContinuous[{Tan[x], (x/π) - (1/2)∉ℤ}, x], FunctionContinuous[{Sec[x], (x/π) - (1/2)∉ℤ}, x]}

Wolfram Language code: Plot[{Tan[x], Sec[x], Cos[x]}, {x, -3π, 3π}, PlotLegends -> "Expressions", PlotTheme -> "DashedLines"]

This same principle applies to the hyperbolic trigonometric functions Coth and Csch:

Wolfram Language code: {FunctionContinuous[{Coth[x], x ≠ 0}, x], FunctionContinuous[{Csch[x], x ≠ 0}, x]}

Visualize the functions along with Sinh:

Wolfram Language code: Plot[{Coth[x], Csch[x], Sinh[x]}, {x, -3, 3}, PlotLegends -> "Expressions", PlotTheme -> "DashedLines"]

As Cosh is never zero, the remaining two functions, Tanh and Sech, are continuous:

Wolfram Language code: Reduce[Cosh[x] == 0, x, Reals]

Wolfram Language code: {FunctionContinuous[Tanh[x], x], FunctionContinuous[Sech[x], x]}

The compositions of continuous functions are continuous:

Wolfram Language code: FunctionContinuous[Sin[x ^ 2 + 3x + 2], x]

Wolfram Language code: FunctionContinuous[Exp[Sin[x]], x]

Wolfram Language code: FunctionContinuous[Cos[Sin[x]]^2 + Sin[x]Cos[x] + Exp[-x], x]

A composition of a discontinuous function and a continuous function will be continuous as long as maps the domain into a continuous subdomain of . Let, for example, be Sqrt. Sqrt is discontinuous on the reals:

Wolfram Language code: FunctionContinuous[Sqrt[x], x]

However, it is continuous on :

Wolfram Language code: FunctionContinuous[{Sqrt[x], x > 0}, x]

Exp maps :

Wolfram Language code: FunctionRange[E^x, x, y]

Thus, the composition of Sqrt with Exp is continuous on :

Wolfram Language code: FunctionContinuous[Sqrt[E^x], x]

Wolfram Language code: FunctionContinuous[x ^ (3 / 2), x]

Multivariate polynomials are continuous over the reals and complexes:

Wolfram Language code: {FunctionContinuous[x ^ 2 + 3x y - 7y ^ 2, {x, y}], FunctionContinuous[x ^ 2 + 3x y - 7y ^ 2, {x, y}, ℂ]}

Rational multivariate functions may or may not be continuous over the reals:

Wolfram Language code: {FunctionContinuous[(x^2 - y^2/x^2 + y^2 + 1), {x, y}], FunctionContinuous[(x^2 - y^2 + 1/x^2 - y), {x, y}]}

They are always discontinuous over the complexes:

Wolfram Language code: FunctionContinuous[(x^2 - y^2/x^2 + y^2 + 1), {x, y}, ℂ]

Sometimes a discontinuous rational function can be extended to a continuous one:

Wolfram Language code:

f[x_, y_] := ( -6 + 8 x - 2 x^2 + 5 y - 6 x y + x^2 y - y^2 + x y^2/5 - 2 x + x^2 - 4 y + y^2)
g[x_, y_] := Piecewise[{{0, x == 1 && y == 2}, {f[x, y], True}}]

Wolfram Language code: {FunctionContinuous[f[x, y], {x, y}], FunctionContinuous[g[x, y], {x, y}]}

By composing with continuous univariate functions, many more continuous functions can be generated:

Wolfram Language code:

{FunctionContinuous[ArcTan[x ^ 2 + 3x y - 7y ^ 2], {x, y}], FunctionContinuous[Cos[(x^2 - y^2/x^2 + y^2 + 1)], {x, y}], FunctionContinuous[Sin[(x^2 - y^2/Exp[x^2 - y])], {x, y}]}

Visualize the continuous functions:

Wolfram Language code:

Grid[Partition[Table[Plot3D[f, {x, -5, 5}, {y, -5, 5}, PlotRange -> All, Exclusions -> None, ImageSize -> 165], {f, {x ^ 2 + 3x y + 7y ^ 2, (x^2 - y^2/x^2 + y^2 + 1), g[x, y], ArcTan[x ^ 2 + 3x y - 7y ^ 2], Cos[(x^2 - y^2/x^2 + y^2 + 1)], Sin[(x^2 - y^2 + 1/Exp[x^2 - y])]}}], 3]]

Calculus (5)

For continuous functions, limits can be computed by substitution:

Wolfram Language code: {FunctionContinuous[Cosh[x], x], Underscript[, x -> 0]Cosh[x], Cosh[0]}

Wolfram Language code: {FunctionContinuous[ArcTan[x], x], Underscript[, x -> 1]ArcTan[x], ArcTan[1]}

Wolfram Language code: {FunctionContinuous[BesselJ[1, x], x], Underscript[, x -> 1]BesselJ[1, 0], BesselJ[1, 0]}

The functions and agree on the real line except at zero:

Wolfram Language code: Reduce[(Sin[x]/x) == Sinc[x], x, Reals]

Sinc is continuous:

Wolfram Language code: FunctionContinuous[Sinc[x], x]

Wolfram Language code: {Sinc[0], Underscript[, x -> 0]Sinc[x]}

The function is not continuous:

Wolfram Language code: FunctionContinuous[(Sin[x]/x), x]

In particular, it is discontinuous at the origin, so its limit there cannot be computed by substitution:

Wolfram Language code: FunctionDiscontinuities[(Sin[x]/x), x]

Since the two functions are equal for , they have the same limit there:

Wolfram Language code: Underscript[, x -> 0](Sin[x]/x) == Underscript[, x -> 0]Sinc[x]

The following function is discontinuous:

Wolfram Language code: f[x_] := Exp[-(1/x^2)]

Wolfram Language code: FunctionContinuous[f[x], x]

Its only discontinuity is at the origin:

Wolfram Language code: FunctionDiscontinuities[f[x], x]

The discontinuity results from being undefined there:

Wolfram Language code: f[0]

However, has a limit as :

Wolfram Language code: Limit[f[x], x -> 0]

Define as an extension of to the origin:

Wolfram Language code: g[x_] := Piecewise[{{f[x], x != 0}, {0, x == 0}}]

This extension is a continuous function:

Wolfram Language code: FunctionContinuous[g[x], x]

Visualize :

Wolfram Language code: Plot[g[x], {x, -10, 10}, PlotRange -> All]

The function is continuous:

Wolfram Language code: h[x_] := Piecewise[{{x*Sin[1/x], x != 0}, {0, x == 0}}]

Wolfram Language code: FunctionContinuous[h[x], x]

However, its first derivative is not continuous:

Wolfram Language code: FunctionContinuous[h'[x], x]

Therefore, is not analytic:

Wolfram Language code: FunctionAnalytic[h[x], x]

While goes smoothly to zero, its derivative oscillates wildly at the origin:

Wolfram Language code: {MinLimit[h'[x], x -> 0], MaxLimit[h'[x], x -> 0]}

Visualize and its first derivative:

Wolfram Language code: Plot[{h[x], h'[x]}, {x, -1, 1}, PlotRange -> {-4, 4}, PlotTheme -> "DashedLines"]

The definite integral of a bounded function is continuous, even if is discontinuous. Consider the following :

Wolfram Language code: f[x_] := Piecewise[{{-x + 1, x < 0}, {x, 0 < x < 1}, {x ^ 2, True}}]

It is discontinuous:

Wolfram Language code: FunctionContinuous[f[x], x]

Define to be its definite integral from the origin to an arbitrary real value:

Wolfram Language code: g[x_] = Integrate[f[t], {t, 0, x}, Assumptions -> x∈Reals];

The function is continuous

Wolfram Language code: FunctionContinuous[g[x], x]

Visualize the function and its integral:

Wolfram Language code: Plot[{f[x], g[x]}, {x, -2, 2}, PlotTheme -> {"Detailed", "DashedLines"}]

Probability (3)

The CDF of a continuous probability distribution is continuous:

Wolfram Language code:

cdf1 = CDF[NormalDistribution[], x];
cdf2 = CDF[BetaDistribution[3, 1], x];
cdf3 = CDF[BinormalDistribution[0], {x, y}];

Wolfram Language code: {FunctionContinuous[cdf1, x], FunctionContinuous[cdf2, x], FunctionContinuous[cdf3, {x, y}]}

Visualize the functions:

Wolfram Language code: Grid[{{Plot[cdf1, {x, -5, 5}], Plot[cdf2, {x, -5, 5}], Plot3D[cdf3, {x, -5, 5}, {y, -5, 5}]}}]

The CDF of a discrete distribution is discontinuous:

Wolfram Language code: cdfs = {CDF[PoissonDistribution[1], n], CDF[BernoulliDistribution[(1/2)], n], CDF[GeometricDistribution[1 / 2], n]};

Wolfram Language code: Table[FunctionContinuous[cdf, n], {cdf, cdfs}]

These distributions have piecewise-constant cumulative distribution functions:

Wolfram Language code: Table[Plot[cdf, {n, -5, 5}, ExclusionsStyle -> Dashed], {cdf, cdfs}]

The CDF of a mixed distribution is discontinuous:

Wolfram Language code:

cdf1 = CDF[CensoredDistribution[{-1, 2}, CauchyDistribution[0, 1]], x];
cdf2 = CDF[CensoredDistribution[{-1, 1}, NormalDistribution[]], x];
cdf3 = CDF[CensoredDistribution[{{-∞, 1 / 2}, {1 / 3, 3 / 5}}, BinormalDistribution[0]], {x, y}];

Wolfram Language code: {FunctionContinuous[cdf1, x], FunctionContinuous[cdf2, x], FunctionContinuous[cdf3, {x, y}]}

These distributions have piecewise, but nonconstant, cumulative distribution functions:

Wolfram Language code:

Grid[{{Plot[cdf1, {x, -5, 5}, ExclusionsStyle -> ColorData[106][2]], Plot[cdf2, {x, -5, 5}, ExclusionsStyle -> ColorData[106][2]], Plot3D[cdf3, {x, -5, 5}, {y, -5, 5}]}}]

Properties & Relations (3)

At each point of the domain, the limit of a continuous function is equal to its value:

Wolfram Language code: f = Sin[2 ^ x] ^ 2 + x / 3;

Wolfram Language code: FunctionContinuous[f, x]

Use Limit to compute limits:

Wolfram Language code: Limit[f, x -> 1] == (f /. x -> 1)

A function continuous in an interval attains each value between its minimum and maximum:

Wolfram Language code: f = Log[Cos[3x E ^ x] ^ 2 + 2x];

Wolfram Language code: FunctionContinuous[{f, 0 ≤ x ≤ 1}, x]

Use Minimize and Maximize to find minima and maxima:

Wolfram Language code: {min, pmin} = Minimize[{f, 0 ≤ x ≤ 1}, x]

Wolfram Language code: {max, pmax} = Maximize[{f, 0 ≤ x ≤ 1}, x]

Check that is between the minimum and the maximum:

Wolfram Language code: min < 1 / 2 < max

Use Solve to find the points where attains the value :

Wolfram Language code: sols = Solve[f == 1 / 2 && 0 ≤ x ≤ 1, x]

Illustrate the property:

Wolfram Language code: Plot[{f, 1 / 2}, {x, 0, 1}, Rule[...]]

Use FunctionAnalytic to check whether a function is analytic:

Wolfram Language code: f = 2 ^ Sin[x ^ 2 + 7] - x;

Wolfram Language code: FunctionAnalytic[f, x]

Analytic functions are continuous:

Wolfram Language code: FunctionContinuous[f, x]

Continuous functions may not be analytic:

Wolfram Language code: FunctionContinuous[Abs[x], x]

Wolfram Language code: FunctionAnalytic[Abs[x], x]

Possible Issues (2)

A function needs to be defined everywhere to be continuous:

Wolfram Language code: FunctionContinuous[Sin[x] / x, x]

Wolfram Language code: FunctionContinuous[{Sin[x] / x, x ≠ 0}, x]

Wolfram Language code: FunctionContinuous[Sinc[x], x]

A function needs to be real valued to be continuous over the real domain:

Wolfram Language code: FunctionContinuous[Sqrt[x], x]

Wolfram Language code: FunctionContinuous[{Sqrt[x], x ≥ 0}, x]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

FunctionContinuous

Details and Options

Examples

Basic Examples (4)

Scope (6)

Options (4)

Assumptions (1)

GenerateConditions (2)

PerformanceGoal (1)

Applications (14)

Classes of Continuous Functions (6)

Calculus (5)

Probability (3)

Properties & Relations (3)

Possible Issues (2)

Text

CMS

APA

BibTeX

BibLaTeX

FunctionContinuous

Details and Options

Examples

Basic Examples (4)

Scope (6)

Options (4)

Assumptions (1)

GenerateConditions (2)

PerformanceGoal (1)

Applications (14)

Classes of Continuous Functions (6)

Calculus (5)

Probability (3)

Properties & Relations (3)

Possible Issues (2)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX