WOLFRAM

Wolfram Language & System Documentation Center

HeunD[q,α,γ,δ,ϵ,z]

gives the double-confluent Heun function.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Differentiation  
Integration  
Series Expansions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
Related Links
History
Cite this Page

HeunD

HeunD[q,α,γ,δ,ϵ,z]

gives the double-confluent Heun function.

Details

  • HeunD belongs to the Heun class of functions and occurs in quantum mechanics, mathematical physics and applications.
  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • HeunD[q,α,γ,δ,ϵ,z] satisfies the double-confluent Heun differential equation .
  • The HeunD function is the power-series solution of the double-confluent Heun equation that satisfies the conditions and .
  • For certain special arguments, HeunD automatically evaluates to exact values.
  • HeunD can be evaluated for arbitrary complex parameters.
  • HeunD can be evaluated to arbitrary numerical precision.
  • HeunD automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: HeunD[4, -0.6, -0.7 , -0.18, 0.3 , 0.12]

Plot the double-confluent Heun function:

Wolfram Language code: Plot[HeunD[4, -0.6, -0.7 , -0.18, 0.3 , x], {x, 3 / 10, 2}]

Series expansion of HeunD:

Wolfram Language code: Series[HeunD[q, α, γ, δ, ϵ, z], {z, 1, 2}]

Scope  (25)

Numerical Evaluation  (9)

Evaluate to high precision:

Wolfram Language code: N[HeunD[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 1 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: HeunD[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 0.10000000000000000001]

HeunD can take one or more complex number parameters:

Wolfram Language code: HeunD[1.2 + I, -1.4, 0.12, 0.03, -0.2, 0.1]
Wolfram Language code: HeunD[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1]

HeunD can take complex number arguments:

Wolfram Language code: HeunD[1.2, -1.4, 0.12, 0.03, -0.2, 0.1 + I]

Finally, HeunD can take all complex number input:

Wolfram Language code: HeunD[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1 + I]

Evaluate HeunD efficiently at high precision:

Wolfram Language code: HeunD[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7`100]//Timing
Wolfram Language code: HeunD[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7 + I / 2`100]//Timing

Lists and matrices:

Wolfram Language code: HeunD[1.2, -1.4, 0.12, 0.03, -0.2, {0.1, 0.1 + I, I, 4}]
Wolfram Language code: HeunD[1.2, -1.4, 0.12, 0.03, -0.2, (| | | | :- | :---- | | π | u | | v | (π/2) |) ]

Evaluate HeunD for points on the real negative axis, bypassing irregular singular origin:

Wolfram Language code: HeunD[-0.2 + I, -0.3, 0.12, 0.12, -0.32, -1.1]

Compute the elementwise values of an array:

Wolfram Language code: HeunD[.1 + I, I, 0.12, 0, -0.32, {{1 / 2, -1}, {1, 1 / 2}}]

Or compute the matrix HeunD function using MatrixFunction:

Wolfram Language code: MatrixFunction[HeunD[.1 + I, I, 0.12, 0, -0.32, #]&, {{1 / 2, -1}, {0, 1 / 2}}]

Specific Values  (2)

Value of HeunD at unit point:

Wolfram Language code: HeunD[q, α, γ, δ, ϵ, 1]

Value of HeunD at irregular singular origin is undetermined:

Wolfram Language code: HeunD[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 0]

Visualization  (5)

Plot the HeunD function:

Wolfram Language code: Plot[HeunD[4, -0.6, -0.7 , -0.18, 0.3 , z], {z, 3 / 10, 19 / 10}]

Plot the absolute value of the HeunD function for complex parameters:

Wolfram Language code: Plot[Abs[HeunD[4 + I, -0.6 + 0.9 I, -0.7 I, -0.18 - 0.03 I, 0.3  + 0.6 I, z]], {z, 3 / 10, 19 / 10}]

Plot HeunD as a function of its second parameter :

Wolfram Language code: Plot[HeunD[4, α, -0.7, -0.18, 0.3 , z] /. α -> {-2, Sqrt[20], 1 / 10}//Evaluate, {z, 3 / 10, 19 / 10}]

Plot HeunD as a function of and :

Wolfram Language code: {α, γ, ϵ, δ} = {0.2 + I, -0.6 + 0.9 I, -0.7 I, 0.3  + 0.6 I};
Wolfram Language code: Plot3D[Abs[HeunD[q, α, γ, δ, ϵ, z]], {q, -20, 2}, {z, 1 / 2, 2}, ColorFunction -> Function[{q, z, HD}, Hue[HD]], PlotRange -> All]

Plot the family of HeunD functions for different accessory parameter :

Wolfram Language code: {α, γ, δ, ϵ} = {0.8 + 0.7 I, 0.9  - 0.6I, 0.2 - 0.7 I, -0.7 - 0.8I};
Wolfram Language code: Plot[Evaluate[Table[Abs[HeunD[q, α, γ, δ, ϵ, z]], {q, -10, 4, 1}]], {z, 1 / 10, 19 / 10}, PlotStyle -> Table[{Hue[i / 20], Thickness[0.002]}, {i, 20}], PlotRange -> {0, 3}, Frame -> True, Axes -> False]

Differentiation  (2)

The -derivative of HeunD is HeunDPrime:

Wolfram Language code: D[HeunD[q, α, γ, δ, ϵ, z], z]

Higher derivatives of HeunD are calculated using HeunDPrime:

Wolfram Language code: D[HeunD[q, α, γ, δ, ϵ, z], {z, 2}]//Simplify

Integration  (3)

Indefinite integrals of HeunD are not expressed in elementary or other special functions:

Wolfram Language code: Integrate[HeunD[q, α, γ, δ, ϵ, z], z]

Definite numerical integral of HeunD:

Wolfram Language code: NIntegrate[HeunD[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, 1 / 3, 1}]

More integrals with HeunD:

Wolfram Language code: NIntegrate[z ^ 2 HeunD[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, 1 / 3, 1}]
Wolfram Language code: NIntegrate[Sin[Sqrt[z]] ^ 2 HeunD[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, 1 / 3, 1}]

Series Expansions  (4)

Taylor expansion for HeunD at regular point :

Wolfram Language code: Series[HeunD[q, α, γ, δ, ϵ, z], {z, 1, 2}]

Coefficient of the second term in the series expansion of HeunD at :

Wolfram Language code: SeriesCoefficient[HeunD[q, α, γ, δ, ϵ, z], {z, 1, 2}]

Plot the first three approximations for HeunD around :

Wolfram Language code: {q, α, γ, δ, ϵ} = {2, 9 / 10, 1 / 10, 1 / 10, 3 / 2};
Wolfram Language code: terms = Normal@Table[Series[HeunD[q, α, γ, δ, ϵ, z], {z, 1, m}], {m, 1, 3}];
Wolfram Language code: Plot[{HeunD[q, α, γ, δ, ϵ, z], terms}, {z, 1 / 3, 3}, PlotLegends -> {"HeunD[q, α, γ, δ, ϵ, z]", "1st approximation", "2nd approximation", "3rd approximation"}]

Series expansion for HeunD at any ordinary complex point:

Wolfram Language code: Series[HeunD[q, α, γ, δ, ϵ, z], {z, 1 / 2, 1}]//FullSimplify

Applications  (3)

Solve the double-confluent Heun differential equation using DSolve:

Wolfram Language code: sol = DSolve[ y''[z] + ((γ/z^2) + (δ/z) + ϵ)y'[z] + (α z - q/z^2)y[z] == 0, y[z], z]

Plot the solution:

Wolfram Language code: {q, α, γ, δ, ϵ} = {4, -2, -7 / 10, -1 / 5, 1 / 3 };
Wolfram Language code: Plot[Abs[y[z]] /. sol /. {{C[1] -> 1, C[2] -> 0}, {C[1] -> 0, C[2] -> 10}, {C[1] -> 1 / 3, C[2] -> 1}}//Evaluate, {z, 1 / 10, 19 / 10}, PlotRange -> {0, 3}]

Solve the initial value problem for the double-confluent Heun differential equation:

Wolfram Language code: sol = DSolveValue[ {y''[z] + ((γ/z^2) + (δ/z) + ϵ)y'[z] + (α z - q/z^2)y[z] == 0, y[1] == 1, y'[1] == 0}, y[z], z]

Plot the solution for different values of the accessory parameter q:

Wolfram Language code: {α, γ, δ, ϵ} = {-3 / 5, -17 / 10, 5, -1 / 3 };
Wolfram Language code: Plot[sol /. q -> {-2, -1, 0, 1, 2}//Evaluate, {z, 1 / 10, 2}, PlotRange -> {{1 / 10, 2}, {-1, 8}}]

Directly solve the double-confluent Heun differential equation:

Wolfram Language code: y[z_] := HeunD[q, α, γ, δ, ϵ, z]
Wolfram Language code: Simplify[y''[z] + ((γ/z^2) + (δ/z) + ϵ)y'[z] + (α z - q/z^2)y[z] == 0]

Properties & Relations  (3)

HeunD is analytic at the point :

Wolfram Language code: Series[HeunD[q, α, γ, δ, ϵ, z], {z, 1, 2}]

Origin is a singular point of the HeunD function:

Wolfram Language code: HeunD[q, α, γ, δ, ϵ, 0]

Except for this singular point, HeunD can be calculated at any finite complex :

Wolfram Language code: HeunD[4 + I, -1 / 2, 1 / 4, -7 / 5, 2, z] /. z -> RandomComplex[{-5 - I, 5 + I}, 5]

The derivative of HeunD is HeunDPrime:

Wolfram Language code: D[HeunD[q, α, γ, δ, ϵ, z], z]

Possible Issues  (1)

HeunD diverges for big arguments:

Wolfram Language code: HeunD[4.3 + I, 1.3, 1, 0.12, 4.32, 1000]
Wolfram Research (2020), HeunD, Wolfram Language function, https://reference.wolfram.com/language/ref/HeunD.html.

Text

Wolfram Research (2020), HeunD, Wolfram Language function, https://reference.wolfram.com/language/ref/HeunD.html.

CMS

Wolfram Language. 2020. "HeunD." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HeunD.html.

APA

Wolfram Language. (2020). HeunD. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HeunD.html

BibTeX

@misc{reference.wolfram_2026_heund, author="Wolfram Research", title="{HeunD}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/HeunD.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_heund, organization={Wolfram Research}, title={HeunD}, year={2020}, url={https://reference.wolfram.com/language/ref/HeunD.html}, note=[Accessed: 12-June-2026]}