WOLFRAM

Wolfram Language & System Documentation Center

Hypergeometric0F1[a,z]

is the confluent hypergeometric function TemplateBox[{a, z}, Hypergeometric0F1].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Function Identities and Simplifications  
Function Representations  
Applications  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Hypergeometric0F1

Hypergeometric0F1[a,z]

is the confluent hypergeometric function TemplateBox[{a, z}, Hypergeometric0F1].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • The function has the series expansion TemplateBox[{a, z}, Hypergeometric0F1]=sum_(k=0)^(infty)1/TemplateBox[{a, k}, Pochhammer] z^k/k!, where TemplateBox[{a, k}, Pochhammer] is the Pochhammer symbol.
  • For certain special arguments, Hypergeometric0F1 automatically evaluates to exact values.
  • Hypergeometric0F1 can be evaluated to arbitrary numerical precision.
  • Hypergeometric0F1 automatically threads over lists.
  • Hypergeometric0F1 can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (5)

Evaluate numerically:

Wolfram Language code: Hypergeometric0F1[1, 1.5]

Plot over a subset of the reals:

Wolfram Language code: Plot[Hypergeometric0F1[Sqrt[2], x], {x, -5, 5}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[Hypergeometric0F1[Sqrt[2], z ^ 2], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[Hypergeometric0F1[a, x], {x, 0, 4}]

Series expansion at Infinity:

Wolfram Language code: Series[Hypergeometric0F1[a, x], {x, ∞, 1}]//Normal//FullSimplify

Scope  (38)

Numerical Evaluation  (5)

Evaluate to high precision:

Wolfram Language code: N[Hypergeometric0F1[1, -2], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: Hypergeometric0F1[1, -2.00000000000000000000000000000]

Evaluate for complex arguments and parameters:

Wolfram Language code: Hypergeometric0F1[1 + I, 1.5 - I]

Evaluate Hypergeometric0F1 efficiently at high precision:

Wolfram Language code: Hypergeometric0F1[1 / 2, 3`500]//Timing
Wolfram Language code: Hypergeometric0F1[1 / 2, 3`50000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: Hypergeometric0F1[3, Interval[{2.1, 2.2}]]
Wolfram Language code: Hypergeometric0F1[3, CenteredInterval[2, 1 / 10]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: Hypergeometric0F1[1, Around[1 / 2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: Hypergeometric0F1[1 / 2, {{1, 0}, {0, 1}}]

Or compute the matrix Hypergeometric0F1 function using MatrixFunction:

Wolfram Language code: MatrixFunction[Hypergeometric0F1[1 / 2, #]&, {{1, 0}, {0, 1}}]

Specific Values  (4)

Evaluate symbolically for half-integer parameters:

Wolfram Language code: {Hypergeometric0F1[1 / 2, x], Hypergeometric0F1[3 / 2, x], Hypergeometric0F1[5 / 2, x]}

Limiting value at infinity:

Wolfram Language code: Limit[Hypergeometric0F1[a, x], x -> Infinity]

Find a zero of TemplateBox[{{sqrt(, 2, )}, x}, Hypergeometric0F1]:

Wolfram Language code: xzero = Solve[Hypergeometric0F1[Sqrt[2], x] == 0 && -3.0 < x < -1.0, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[Hypergeometric0F1[Sqrt[2], x], {x, -5, 1}, Epilog -> Style[Point[{xzero, Hypergeometric0F1[Sqrt[2], xzero]}], PointSize[Large], Red]]

Heun functions can be reduced to hypergeometric functions:

Wolfram Language code: Hypergeometric0F1[a, z] == HeunB[1, 0, a, 0, 0, z]

Visualization  (3)

Plot the Hypergeometric0F1 function for various values of parameter :

Wolfram Language code: Plot[{Hypergeometric0F1[Sqrt[2], x], Hypergeometric0F1[Sqrt[3], x], Hypergeometric0F1[Sqrt[5], x]}, {x, -4, 4}]

Plot Hypergeometric0F1 as a function of its first parameter :

Wolfram Language code: Plot[{Hypergeometric0F1[a, 1], Hypergeometric0F1[a, 2], Hypergeometric0F1[a, 3]}, {a, -3, 3}]

Plot the real part of TemplateBox[{{sqrt(, 2, )}, z}, Hypergeometric0F1]:

Wolfram Language code: ComplexContourPlot[Re[Hypergeometric0F1[Sqrt[2], z]], {z, -5 - 5I, 5 + 5I}, Contours -> 24]

Plot the imaginary part of TemplateBox[{{sqrt(, 2, )}, z}, Hypergeometric0F1]:

Wolfram Language code: ComplexContourPlot[Im[Hypergeometric0F1[Sqrt[2], z]], {z, -5 - 5I, 5 + 5I}, IconizedObject[«PlotOptions»]]

Function Properties  (9)

Real domain of TemplateBox[{a, z}, Hypergeometric0F1]:

Wolfram Language code: FunctionDomain[Hypergeometric0F1[a, z], {a, z}]

Complex domain:

Wolfram Language code: FunctionDomain[Hypergeometric0F1[a, z], z, ℂ]

TemplateBox[{a, z}, Hypergeometric0F1] is an analytic function when :

Wolfram Language code: FunctionAnalytic[Hypergeometric0F1[a, z], z, Assumptions -> a > 0]

For negative values of , it may or may not be analytic:

Wolfram Language code: FunctionAnalytic[Hypergeometric0F1[-1, z], z]
Wolfram Language code: FunctionAnalytic[Hypergeometric0F1[-Sqrt[2], z], z]

TemplateBox[{1, z}, Hypergeometric0F1] is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[Hypergeometric0F1[1, z], z]

TemplateBox[{1, z}, Hypergeometric0F1] is not injective:

Wolfram Language code: FunctionInjective[Hypergeometric0F1[1, z], z]
Wolfram Language code: Plot[{Hypergeometric0F1[1, z], -.2}, {z, -7, 2}]

TemplateBox[{1, z}, Hypergeometric0F1] is not surjective:

Wolfram Language code: FunctionSurjective[Hypergeometric0F1[1, z], z]

TemplateBox[{{1, /, 3}, z}, Hypergeometric0F1] is surjective:

Wolfram Language code: FunctionSurjective[Hypergeometric0F1[1 / 3, z], z]

Note that the latter function grows very slowly as :

Wolfram Language code: Plot[{Hypergeometric0F1[1, z], Hypergeometric0F1[1 / 3, z], -2}, {z, -100, 0}]

Hypergeometric0F1 is neither non-negative nor non-positive:

Wolfram Language code: Table[FunctionSign[Hypergeometric0F1[a, z], z], {a, 4}]

TemplateBox[{1, z}, Hypergeometric0F1] has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[Hypergeometric0F1[1, z], z]
Wolfram Language code: FunctionDiscontinuities[Hypergeometric0F1[1, z], z]

TemplateBox[{{1, /, 2}, z}, Hypergeometric0F1] is neither convex nor concave:

Wolfram Language code: FunctionConvexity[Hypergeometric0F1[1 / 2, z], z]

TraditionalForm formatting:

Wolfram Language code: Hypergeometric0F1[a, z]//TraditionalForm

Differentiation  (3)

First derivative:

Wolfram Language code: D[Hypergeometric0F1[a, x], x]

Higher derivatives:

Wolfram Language code: derivs = Table[D[Hypergeometric0F1[a, x], {x, n}], {n, 1, 4}]

Plot higher derivatives for :

Wolfram Language code: Plot[Evaluate[derivs /. a -> Sqrt[2 / 5]], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Formula for the ^(th) derivative:

Wolfram Language code: D[Hypergeometric0F1[a, x], {x, n}]

Integration  (3)

Indefinite integral of Hypergeometric0F1:

Wolfram Language code: Integrate[Hypergeometric0F1[a, x], x]

Definite integral:

Wolfram Language code: Integrate[Hypergeometric0F1[Sqrt[2], x], {x, 0, 1}]

Integral involving a power function:

Wolfram Language code: Integrate[t ^ (α - 1)Hypergeometric0F1[a, t], {t, 0, 1}, Assumptions -> Re[α] > 0]

Series Expansions  (3)

Taylor expansion for Hypergeometric0F1:

Wolfram Language code: Series[Hypergeometric0F1[a, x], {x, 0, 3}]

Plot the first three approximations for TemplateBox[{1, x}, Hypergeometric0F1] around :

Wolfram Language code: terms = Normal@Table[Series[Hypergeometric0F1[1, x], {x, 0, m}], {m, 1, 3}]; Plot[{Hypergeometric0F1[1, x], terms}, {x, -4, 4}]

General term in the series expansion of Hypergeometric0F1:

Wolfram Language code: SeriesCoefficient[Hypergeometric0F1[a, x], {x, 0, n}]

Series expansion for TemplateBox[{1, x}, Hypergeometric0F1] at infinity:

Wolfram Language code: Series[Hypergeometric0F1[1, x], {x, Infinity, 2}]

Function Identities and Simplifications  (3)

Product of the Hypergeometric0F1 functions:

Wolfram Language code: Hypergeometric0F1[a, z] Hypergeometric0F1[b, z] == HypergeometricPFQ[{(a + b/2), (a + b - 1/2)}, {a, b, a + b - 1}, 4z]//FullSimplify

Recurrence relation:

Wolfram Language code: (1 - a) a Hypergeometric0F1[a - 1, z] + a (a - 1) Hypergeometric0F1[a, z] + z Hypergeometric0F1[a + 1, z] == 0//FullSimplify

Use FunctionExpand to express Hypergeometric0F1 through other functions:

Wolfram Language code: Hypergeometric0F1[a, x]//FunctionExpand

Function Representations  (5)

Series representation:

Wolfram Language code: Underoverscript[∑, k = 0, ∞](z^k/Pochhammer[b, k] k!)

Relation to Hypergeometric1F1 function:

Wolfram Language code: E^-2Sqrt[z]Hypergeometric1F1[a - (1/2), 2a - 1, 4Sqrt[z]]//FullSimplify

Hypergeometric0F1 can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[Hypergeometric0F1[b, x], x]

Hypergeometric0F1 can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[Hypergeometric0F1[b, x], x]
Wolfram Language code: Activate[%]//FullSimplify

TraditionalForm formatting:

Wolfram Language code: Hypergeometric0F1[a, z]//TraditionalForm

Applications  (2)

Solve the 1+1-dimensional Dirac equation:

Wolfram Language code: χ[x_, t_] = {I m / 2(t + x) Hypergeometric0F1[2, m ^ 2(x ^ 2 - t ^ 2) / 4], Hypergeometric0F1[1, m ^ 2(x ^ 2 - t ^ 2) / 4] };
Wolfram Language code: Subscript[σ, 3] = (⁠| | | | :- | :- | | 1 | 0 | | 0 | -1 |⁠); Subscript[σ, 1] = (⁠| | | | :- | :- | | 0 | 1 | | 1 | 0 |⁠);
Wolfram Language code: (I D[χ[x, t], t] == -I Subscript[σ, 3].D[χ[x, t], x] - m Subscript[σ, 1].χ[x, t])//FullSimplify

Plot the solution:

Wolfram Language code: ContourPlot[Abs[Norm[χ[x, t]] /. m -> 1], {x, -1, 1}, {t, -1, 1}]

Hypergeometric0F1 has the following infinite series:

Wolfram Language code: FullSimplify[Hypergeometric0F1[b, z] == Sum[1 / Pochhammer[b, k] z ^ k / k!, {k, 0, Infinity}]]

Properties & Relations  (2)

Use FunctionExpand to expand in terms of Bessel functions:

Wolfram Language code: FunctionExpand[Hypergeometric0F1[a, x ^ 2]]
Wolfram Language code: FunctionExpand[Hypergeometric0F1[a, -x ^ 2]]

Hypergeometric0F1 can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[Hypergeometric0F1[k + x, z], k]

Neat Examples  (1)

Continued fraction with arithmetic progression terms:

Wolfram Language code: ContinuedFraction[2Hypergeometric0F1[2 / 3, 1 / 9] / Hypergeometric0F1[5 / 3, 1 / 9], 20]
Wolfram Research (1988), Hypergeometric0F1, Wolfram Language function, https://reference.wolfram.com/language/ref/Hypergeometric0F1.html (updated 2022).

Text

Wolfram Research (1988), Hypergeometric0F1, Wolfram Language function, https://reference.wolfram.com/language/ref/Hypergeometric0F1.html (updated 2022).

CMS

Wolfram Language. 1988. "Hypergeometric0F1." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/Hypergeometric0F1.html.

APA

Wolfram Language. (1988). Hypergeometric0F1. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Hypergeometric0F1.html

BibTeX

@misc{reference.wolfram_2026_hypergeometric0f1, author="Wolfram Research", title="{Hypergeometric0F1}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/Hypergeometric0F1.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_hypergeometric0f1, organization={Wolfram Research}, title={Hypergeometric0F1}, year={2022}, url={https://reference.wolfram.com/language/ref/Hypergeometric0F1.html}, note=[Accessed: 12-June-2026]}