WOLFRAM

Wolfram Language & System Documentation Center

HeunC[q,α,γ,δ,ϵ,z]

gives the confluent Heun function.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

HeunC

HeunC[q,α,γ,δ,ϵ,z]

gives the confluent Heun function.

Details

  • HeunC belongs to the Heun class of functions and occurs in quantum mechanics, mathematical physics and applications.
  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • HeunC[q,α,γ,δ,ϵ,z] satisfies the confluent Heun differential equation .
  • The HeunC function is the regular solution of the confluent Heun equation that satisfies the condition HeunC[q,α,γ,δ,ϵ,0]1.
  • HeunC has a branch cut discontinuity in the complex plane running from to .
  • For certain special arguments, HeunC automatically evaluates to exact values.
  • HeunC can be evaluated for arbitrary complex parameters.
  • HeunC can be evaluated to arbitrary numerical precision.
  • HeunC automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: HeunC[4, -0.6, -0.7 , -0.18, 0.3 , 0.12]

Plot the HeunC function:

Wolfram Language code: Plot[HeunC[4, -0.6, -0.7 , -0.18, 0.3 , x], {x, -3 / 10, 9 / 10}]

Series expansion of HeunC:

Wolfram Language code: Series[HeunC[q, α, γ, δ, ϵ, z], {z, 0, 2}]

Scope  (26)

Numerical Evaluation  (8)

Evaluate to high precision:

Wolfram Language code: N[HeunC[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 1 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: HeunC[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 0.10000000000000000001]

HeunC can take one or more complex number parameters:

Wolfram Language code: HeunC[1.2 + I, -1.4, 0.12, 0.03, -0.2, 0.1]
Wolfram Language code: HeunC[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1]

HeunC can take complex number arguments:

Wolfram Language code: HeunC[1.2, -1.4, 0.12, 0.03, -0.2, 0.1 + I]

Finally, HeunC can take all complex number input:

Wolfram Language code: HeunC[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1 + I]

Evaluate HeunC efficiently at high precision:

Wolfram Language code: HeunC[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7`100]//Timing
Wolfram Language code: HeunC[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7 + I / 2`100]//Timing

Lists and matrices:

Wolfram Language code: HeunC[1.2, -1.4, 0.12, 0.03, -0.2, {0.15, 0.1 + I, I, 4}]
Wolfram Language code: HeunC[-0.01, {1.3, -0.4}, 0.12, -0.14, 4.32, -1.4]
Wolfram Language code: HeunC[1.2, -1.4, 0.12, 0.03, -0.2, (| | | | :- | :---- | | π | u | | v | (π/2) |) ]

Evaluate HeunC for points at branch cut to :

Wolfram Language code: HeunC[4.3 + I, 1.3, 0.12, 1, 4.32, 11]

Specific Values  (3)

Value of HeunC at origin:

Wolfram Language code: HeunC[q, α, γ, δ, ϵ, 0]

Value of HeunC at regular singular point is indeterminate:

Wolfram Language code: HeunC[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 1]

Values of HeunC in "logarithmic" cases, i.e. for nonpositive integer , are not determined:

Wolfram Language code: HeunC[12 / 10, -14 / 10, -3, 3 / 100, -2 / 10, 2 / 10]
Wolfram Language code: HeunC[12 / 10, -14 / 10, 0, 3 / 100, -2 / 10, 2 / 10]
Wolfram Language code: HeunC[12 / 10, -14 / 10, 1., 3 / 100, -2 / 10, 2 / 10]

Visualization  (5)

Plot the HeunC function:

Wolfram Language code: Plot[HeunC[4, -0.6, -0.7 , -0.18, 0.3 , z], {z, -3 / 10, 9 / 10}]

Plot the absolute value of the HeunC function for complex parameters:

Wolfram Language code: Plot[Abs[HeunC[4 + I, -0.6 + 0.9 I, -0.7 I, -0.18 - 0.03 I, 0.3  + 0.6 I, z]], {z, -3 / 10, 9 / 10}]

Plot HeunC as a function of its second parameter :

Wolfram Language code: Plot[HeunC[4, α, -0.7, -0.18, 0.3 , z] /. α -> {-2, Sqrt[20], 1 / 10}//Evaluate, {z, -3 / 10, 9 / 10}]

Plot HeunC as a function of and :

Wolfram Language code: {q, γ, ϵ, δ} = {0.2 + I, -0.6 + 0.9 I, -0.7 I, 0.3  + 0.6 I};
Wolfram Language code: Plot3D[Abs[HeunC[q, α, γ, δ, ϵ, z]], {α, -10, 2}, {z, 1 / 10, 9 / 10}, ColorFunction -> Function[{q, z, HC}, Hue[HC]], PlotRange -> All]

Plot the family of HeunC functions for different accessory parameter :

Wolfram Language code: {α, γ, δ, ϵ} = {0.7  - 0.9 I, 0.3 - 0.5 I, -0.4 + 0.8 I, -0.3 - 0.6 I};
Wolfram Language code: Plot[Evaluate[Table[Abs[HeunC[q, α, γ, δ, ϵ, z]], {q, -16, 12, 3}]], {z, -8, 99 / 100}, PlotStyle -> Table[{Hue[i / 10], Thickness[0.002]}, {i, 20}], PlotRange -> {1 / 2, 4}, Frame -> True, Axes -> False]

Function Properties  (1)

HeunC can be simplified to Hypergeometric1F1 function in the following case:

Wolfram Language code: HeunC[-a, -a, b, 0, -1, z]

Differentiation  (2)

The -derivative of HeunC is HeunCPrime:

Wolfram Language code: D[HeunC[q, α, γ, δ, ϵ, z], z]

Higher derivatives of HeunC are calculated using HeunCPrime:

Wolfram Language code: D[HeunC[q, α, γ, δ, ϵ, z], {z, 2}]//Simplify

Integration  (3)

Indefinite integrals of HeunC are not expressed in elementary or other special functions:

Wolfram Language code: Integrate[HeunC[q, α, γ, δ, ϵ, z], z]

Definite numerical integral of HeunC:

Wolfram Language code: NIntegrate[HeunC[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, 0, 1 / 3}]

More integrals with HeunC:

Wolfram Language code: NIntegrate[z ^ 2 HeunC[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, -1, 1 / 3}]
Wolfram Language code: NIntegrate[Sin[Sqrt[z]] ^ 2 HeunC[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, -1, 1 / 3}]

Series Expansions  (4)

Taylor expansion for HeunC at regular singular origin:

Wolfram Language code: Series[HeunC[q, α, γ, δ, ϵ, z], {z, 0, 2}]

Coefficient of the first term in the series expansion of HeunC at :

Wolfram Language code: SeriesCoefficient[HeunC[q, α, γ, δ, ϵ, z], {z, 0, 1}]

Plot the first three approximations for HeunC around :

Wolfram Language code: {q, α, γ, δ, ϵ} = {-10, -1 / 3, -1 / 4, -1 / 7, 3 / 2};
Wolfram Language code: terms = Normal@Table[Series[HeunC[q, α, γ, δ, ϵ, z], {z, 0, m}], {m, 1, 7, 2}];
Wolfram Language code: Plot[{HeunC[q, α, γ, δ, ϵ, z], terms}, {z, -1, 1 / 2}, PlotRange -> {-100, 100}, PlotLegends -> {"HeunC[q, α, γ, δ, ϵ, z]", "1st approximation", "2nd approximation", "3rd approximation", "4th approximation"}]

Series expansion for HeunC at any ordinary complex point:

Wolfram Language code: Series[HeunC[q, α, γ, δ, ϵ, z], {z, 1 / 2, 1}]//FullSimplify

Applications  (4)

Solve the confluent Heun differential equation using DSolve:

Wolfram Language code: sol = DSolve[ y''[z] + ((γ/z) + (δ/z - 1) + ϵ)y'[z] + (α z - q/z(z - 1))y[z] == 0, y[z], z]

Plot the solution:

Wolfram Language code: {q, α, γ, δ, ϵ} = {4, -0.6, -0.7 , -0.18, 0.3  };
Wolfram Language code: Plot[Abs[y[z]] /. sol /. {{C[1] -> 1, C[2] -> 0}, {C[1] -> 0, C[2] -> 10}, {C[1] -> 1 / 3, C[2] -> 1}}//Evaluate, {z, -1 / 3, 1 / 2}]

Solve the initial value problem for the confluent Heun differential equation:

Wolfram Language code: ClearAll[α, γ, δ, ϵ]
Wolfram Language code: sol = DSolveValue[ {y''[z] + ((γ/z) + (δ/z - 1) + ϵ)y'[z] + (α z - q/z(z - 1))y[z] == 0, y[0] == 1, y'[0] == -(q/γ)}, y[z], z]

Plot the solution for different values of the accessory parameter q:

Wolfram Language code: {α, γ, δ, ϵ} = {-3 / 5, -17 / 10, 2 / 3, -1 / 3 };
Wolfram Language code: Plot[sol /. q -> {0, 2, 4, 6}//Evaluate, {z, -1 / 2, 9 / 10}]

Directly solve the confluent Heun differential equation:

Wolfram Language code: y[z_] := HeunC[q, α, γ, δ, ϵ, z]
Wolfram Language code: Simplify[y''[z] + ((γ/z) + (δ/z - 1) + ϵ)y'[z] + (α z - q/z(z - 1))y[z] == 0]

HeunC with specific parameters solves the Mathieu equation:

Wolfram Language code: y[z_] := HeunC[(a/4) - (q/2), -q, (1/2), (1/2), 0, Sin[z]^2]
Wolfram Language code: y''[z] + (a - 2q Cos[2z])y[z] == 0//Simplify

Construct the general solution of the Mathieu equation in terms of HeunC functions:

Wolfram Language code: y[z_] := C[1] HeunC[(a/4) - (q/2), -q, (1/2), (1/2), 0, Sin[z]^2] + C[2] Sin[z] HeunC[(a/4) - (q/2) - (1/4), -q, (3/2), (1/2), 0, Sin[z]^2]
Wolfram Language code: y''[z] + (a - 2q Cos[2z])y[z] == 0//Simplify

Properties & Relations  (3)

HeunC is analytic at the origin:

Wolfram Language code: Series[HeunC[q, α, γ, δ, ϵ, z], {z, 0, 2}]

is a singular point of the HeunC function:

Wolfram Language code: HeunC[q, α, γ, δ, ϵ, 1]

Except for this singular point, HeunC can be calculated at any finite complex :

Wolfram Language code: HeunC[4 + I, -1 / 2, 1 / 4, -7 / 5, 2, z] /. z -> RandomComplex[{-5 - I, 5 + I}, 5]

The derivative of HeunC is HeunCPrime:

Wolfram Language code: D[HeunC[q, α, γ, δ, ϵ, z], z]

Possible Issues  (1)

HeunC cannot be evaluated if is a nonpositive integer (so-called logarithmic cases):

Wolfram Language code: HeunC[4.3 + I, 1.3, 1, 0.12, 4.32, 4.3 + 0.5I]
Wolfram Language code: HeunC[4.3 + I, 1.3, -1, 0.12, 4.32, 4.3 + 0.5I]
Wolfram Language code: HeunC[4.3 + I, 1.3, -3, 0.12, 4.32, 4.3 + 0.5I]

Neat Examples  (2)

Create a table of some special cases for HeunC :

Wolfram Language code: flist = Inactivate[{HeunC[q, 0, γ, δ, 0, z], HeunC[-a, -a, b, 0, -1, z], HeunC[(a/4) - (q/2), -q, (1/2), (1/2), 0, z], HeunC[-(1/2), -(1/2), 1, 0, -1, z]}, HeunC];
Wolfram Language code: Grid[Join[{{Text["Special case of HeunC"], Text["Simpler Special function"]}}, Transpose[{flist, Activate[flist]}]], IconizedObject[«Grid options»]]//TraditionalForm

Solve the spheroidal wave equation in its general form in terms of HeunC:

Wolfram Language code: sol = DSolve[(1 - z^2)y''[z] - 2z y'[z] + (λ + γ^2(1 - z^2) - (m^2/1 - z^2))y[z] == 0, y[z], z, Assumptions -> {m > 0 , γ > 0}]

Plot the absolute value of the general solution for different values of λ:

Wolfram Language code: {m, γ} = {4 / 3, 7 / 2};
Wolfram Language code: Plot[Abs[y[z]] /. sol /. {C[1] -> 1 / 3, C[2] -> 1 / 3} /. λ -> {-2, -1, 0, 1, 2}//Evaluate, {z, -3 / 4, 3 / 4}]
Wolfram Research (2020), HeunC, Wolfram Language function, https://reference.wolfram.com/language/ref/HeunC.html.

Text

Wolfram Research (2020), HeunC, Wolfram Language function, https://reference.wolfram.com/language/ref/HeunC.html.

CMS

Wolfram Language. 2020. "HeunC." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HeunC.html.

APA

Wolfram Language. (2020). HeunC. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HeunC.html

BibTeX

@misc{reference.wolfram_2026_heunc, author="Wolfram Research", title="{HeunC}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/HeunC.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_heunc, organization={Wolfram Research}, title={HeunC}, year={2020}, url={https://reference.wolfram.com/language/ref/HeunC.html}, note=[Accessed: 12-June-2026]}