WOLFRAM

Wolfram Language & System Documentation Center

InverseBetaRegularized[s,a,b]

gives the inverse of the regularized incomplete beta function.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

InverseBetaRegularized

InverseBetaRegularized[s,a,b]

gives the inverse of the regularized incomplete beta function.

Details

Examples

open all close all

Basic Examples  (2)

Evaluate numerically:

Wolfram Language code: InverseBetaRegularized[0.8, 1, 2]

Plot over a subset of the reals:

Wolfram Language code: Plot[InverseBetaRegularized[s, 2, 3], {s, 0, 1}]

Scope  (17)

Numerical Evaluation  (4)

Evaluate numerically:

Wolfram Language code: InverseBetaRegularized[0.5, 2, 7]
Wolfram Language code: InverseBetaRegularized[0, 47, 5.2]

Evaluate to high precision:

Wolfram Language code: N[InverseBetaRegularized[15 / 157, 5, 2], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: InverseBetaRegularized[0.455555555555555666666666, 5, 1]

Evaluate efficiently at high precision:

Wolfram Language code: InverseBetaRegularized[23 / 417, 5, 1`100]//Timing
Wolfram Language code: InverseBetaRegularized[15 / 751, 5, 1`1000000];//Timing

Compute the elementwise values of an array using automatic threading:

Wolfram Language code: InverseBetaRegularized[{{1 / 2, 1}, {0, 1 / 2}}, 3, 3]

Or compute the matrix InverseBetaRegularized function using MatrixFunction:

Wolfram Language code: MatrixFunction[InverseBetaRegularized[#, 3, 3]&, {{1 / 2, 1}, {0, 1 / 2}}]//FullSimplify

Specific Values  (4)

Values of InverseBetaRegularized at fixed points:

Wolfram Language code: Table[InverseBetaRegularized[1 / z, 1, 2], {z, 2, 4}]

Values at zero:

Wolfram Language code: InverseBetaRegularized[0, 1, 2 ]

Find a value of z for which the InverseBetaRegularized[z,1,2]=0.5:

Wolfram Language code: zval = z /. FindRoot[InverseBetaRegularized[z, 1, 2] == 0.5, {z, 0.2}]
Wolfram Language code: Plot[InverseBetaRegularized[z, 1, 2], {z, 0, 1}, Epilog -> Style[Point[{zval, InverseBetaRegularized[zval, 1, 2]}], PointSize[Large], Red]]

TraditionalForm formatting:

Wolfram Language code: InverseBetaRegularized[s, a, b] // TraditionalForm

Visualization  (2)

Plot the InverseBetaRegularized function for different values of parameter a:

Wolfram Language code: Plot[Evaluate[Table[InverseBetaRegularized[z, a, 2], {a, 3}]], {z, 0, 1}]

Plot the InverseBetaRegularized function for different values of parameter b:

Wolfram Language code: Plot[Evaluate[Table[InverseBetaRegularized[z, 2, b], {b, 3}]], {z, 0, 1}]

Function Properties  (5)

TemplateBox[{x, 3, 2}, InverseBetaRegularized] is analytic on the open interval :

Wolfram Language code: FunctionAnalytic[{InverseBetaRegularized[x, 3, 2], 0 < x < 1}, x]

It has both singularities and discontinuities at the endpoints 0 or at 1:

Wolfram Language code: FunctionSingularities[InverseBetaRegularized[x, 3, 2], x]//Quiet
Wolfram Language code: FunctionDiscontinuities[InverseBetaRegularized[x, 3, 2], x]//Quiet

TemplateBox[{x, 3, 2}, InverseBetaRegularized] is non-negative on the unit interval:

Wolfram Language code: FunctionSign[{InverseBetaRegularized[x, 3, 2], 0 <= x <= 1}, x]

TemplateBox[{x, 3, 2}, InverseBetaRegularized] is injective:

Wolfram Language code: FunctionInjective[InverseBetaRegularized[x, 3, 2], x]
Wolfram Language code: Plot[{InverseBetaRegularized[x, 3, 2], .3}, {x, 0, 1}]

TemplateBox[{x, 3, 2}, InverseBetaRegularized] is nondecreasing on the unit interval:

Wolfram Language code: FunctionMonotonicity[{InverseBetaRegularized[x, 3, 2], 0 <= x <= 1}, x]

TemplateBox[{x, 3, 2}, InverseBetaRegularized] is neither convex nor concave on the unit interval:

Wolfram Language code: FunctionConvexity[{InverseBetaRegularized[x, 3, 2], 0 <= x <= 1}, x]

Differentiation  (2)

First derivative with respect to s when a=2 and b=3:

Wolfram Language code: D[InverseBetaRegularized[s, 2, 3], s]

First derivative with respect to a when b=2:

Wolfram Language code: D[InverseBetaRegularized[s, a, 2], a]// FullSimplify

First derivative with respect to b when a=2:

Wolfram Language code: D[InverseBetaRegularized[s, 2, b], b]// FullSimplify

Higher derivatives with respect to s when a=2 and b=3:

Wolfram Language code: Table[D[InverseBetaRegularized[s, 2, 3], {s, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to s when a=2 and b=3:

Wolfram Language code: Plot[%, {s, .1, .8}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Generalizations & Extensions  (2)

InverseBetaRegularized threads elementwise over lists:

Wolfram Language code: InverseBetaRegularized[.4, {2, 3, 5, 7, 11}, {1, 2, 3, 4, 5}]

Evaluate the 4-argument generalized case:

Wolfram Language code: InverseBetaRegularized[0.6, 0.2, 4, 2]

Applications  (2)

Model the PDF of the beta distribution through uniformly distributed random numbers:

Wolfram Language code: pmod[a_, b_, n_] := InverseBetaRegularized[RandomReal[{0, 1}, n], a, b]

Compare binned modeled distribution with exact distribution:

Wolfram Language code: With[{a = 3, b = 2, n = 2000, s = 0.1}, Show[{ListPlot[{First[#], Length[#] / n / s}& /@ Split[Sort[Round[pmod[a, b, n], s]]]], Plot[(1 - x) ^ (b - 1)x ^ (a - 1) / Beta[a, b] , {x, 0, 1}]}]]

A multivariate Student copula:

Wolfram Language code: 𝒟 = CopulaDistribution[{"MultivariateT", {{1, 2 / 3}, {2 / 3, 5}}, 2}, {UniformDistribution[], UniformDistribution[]}];

Probability density function:

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.1, 1.1}, {y, -0.1, 1.1}, Exclusions -> {{x(1 - x) == 0, 0 ≤ y ≤ 1}, {y(1 - y) == 0, 0 ≤ x ≤ 1}}]
Wolfram Language code: PDF[𝒟, {1 / 3, 2 / 3}] == (492 Sqrt[205]) / (π InverseBetaRegularized[(2/3), 1, (1/2)] (-6 (15 + 2 Sqrt[5]) + (49 + 12 Sqrt[5]) InverseBetaRegularized[(2/3), 1, (1/2)])^2)//Simplify

Properties & Relations  (2)

InverseBetaRegularized is the inverse of BetaRegularized:

Wolfram Language code: InverseBetaRegularized[0.66, 3.5, 4]
Wolfram Language code: BetaRegularized[%, 3.5, 4]

Solve a transcendental equation:

Wolfram Language code: Solve[InverseBetaRegularized[x, a, b] ^ 2 + 2InverseBetaRegularized[x, a, b] == 1, x]

Possible Issues  (2)

InverseBetaRegularized evaluates numerically only for :

Wolfram Language code: InverseBetaRegularized[1.2, 1, 3]

In TraditionalForm, is not automatically interpreted as an inverse regularized beta function:

Wolfram Language code: Subsuperscript[I, z, -1](a, b)
Wolfram Research (1996), InverseBetaRegularized, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseBetaRegularized.html.

Text

Wolfram Research (1996), InverseBetaRegularized, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseBetaRegularized.html.

CMS

Wolfram Language. 1996. "InverseBetaRegularized." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/InverseBetaRegularized.html.

APA

Wolfram Language. (1996). InverseBetaRegularized. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseBetaRegularized.html

BibTeX

@misc{reference.wolfram_2026_inversebetaregularized, author="Wolfram Research", title="{InverseBetaRegularized}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/InverseBetaRegularized.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_inversebetaregularized, organization={Wolfram Research}, title={InverseBetaRegularized}, year={1996}, url={https://reference.wolfram.com/language/ref/InverseBetaRegularized.html}, note=[Accessed: 12-June-2026]}