Wolfram Language & System Documentation Center

Beta

Beta[a,b]

gives the Euler beta function .

Beta[z,a,b]

gives the incomplete beta function .

Details

Beta is a mathematical function, suitable for both symbolic and numerical manipulation.
$TemplateBox[{a, b}, Beta]=TemplateBox[{a}, Gamma]TemplateBox[{b}, Gamma]/TemplateBox[{{a, +, b}}, Gamma]=int_0^1t^(a-1)(1-t)^(b-1)dt$ .
$TemplateBox[{z, a, b}, Beta3]=int_0^zt^(a-1)(1-t)^(b-1)dt$ .
Beta[z,a,b] has a branch cut discontinuity in the complex plane running from to .
Beta[z₀,z₁,a,b] gives the generalized incomplete beta function .
Note that the arguments in the incomplete form of Beta are arranged differently from those in the incomplete form of Gamma.
For certain special arguments, Beta automatically evaluates to exact values.
Beta can be evaluated to arbitrary numerical precision.
Beta automatically threads over lists.
In TraditionalForm, Beta is output using \[CapitalBeta].
Beta can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (6)

Exact values:

Wolfram Language code: Beta[5, 4]

Wolfram Language code: Beta[5 / 2, 7 / 2]

Evaluate numerically:

Wolfram Language code: Beta[2.3, 3.2]

Plot over a subset of the reals:

Wolfram Language code: Plot[Beta[1 / 2, x], {x, -2, 3}]

Plot the incomplete beta function over a subset of the reals:

Wolfram Language code: Plot[Beta[x, 1 / 2, 1 / 2], {x, 0, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[Beta[1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[Beta[1 / 2, x], {x, 0, 2}]//Normal//FullSimplify

Series expansion at Infinity:

Wolfram Language code: Series[Beta[-1 / 2, x], {x, ∞, 4}]//Normal

Scope (42)

Numerical Evaluation (8)

Evaluate numerically:

Wolfram Language code: Beta[1.1, 2.1]

Evaluate symbolically in special cases:

Wolfram Language code: {Beta[0, b], Beta[a, 0]}

Evaluate to high precision:

Wolfram Language code: N[Beta[22 / 10, 33 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: Beta[2.200000000000000000000000, 33 / 10]

Wolfram Language code: Beta[22 / 10, 3.300000000000000000000000]

Evaluate for large arguments:

Wolfram Language code: Beta[100000, 100000]//Short

Wolfram Language code: Beta[10. ^ 5, 10. ^ 5]

Evaluate for complex arguments:

Wolfram Language code: Beta[2.5 + I, 1 - I]

Evaluate Beta efficiently at high precision:

Wolfram Language code: Beta[1.1`200, 2.2`200]//Timing

Wolfram Language code: Beta[1.1`1000, 2.2`1000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: Beta[2, Interval[{1.2, 2.1}]]

Wolfram Language code: Beta[2, CenteredInterval[2, 1 / 8]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: Beta[ Around[1.2, 0.01], 1, 2]

Compute the elementwise values of an array:

Wolfram Language code: Beta[{{1 / 2, -1}, {0, 1 / 2}}, 1, 2]

Or compute the matrix Beta function using MatrixFunction:

Wolfram Language code: MatrixFunction[Beta[#, 1, 2]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplify

Specific Values (4)

Values at infinity:

Wolfram Language code: Beta[Infinity, 0]

Wolfram Language code: Beta[0, Infinity]

Find a zero of :

Wolfram Language code: xmin = Solve[Beta[x, -1 / 2] == 0 && 0 < x < 1, x, Reals][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[Beta[x, -1 / 2], {x, -1, 3}, Epilog -> Style[Point[{xmin, Beta[xmin, -1 / 2]}], PointSize[Large], Red]]

Evaluate the incomplete beta function symbolically at integer and half‐integer orders:

Wolfram Language code: Beta[z, 3, b] // FunctionExpand

Wolfram Language code: Beta[13 / 2, 7 / 2, 9 / 2] // FunctionExpand//Simplify

Evaluate the generalized incomplete beta symbolically:

Wolfram Language code: Beta[1 / 4, 1 / 3, 1 / 2, 3 / 2]//FunctionExpand//Simplify

Visualization (2)

Plot :

Wolfram Language code: Plot[Beta[1 / 2, b], {b, -2, 2}]

Contour plot of :

Wolfram Language code: ContourPlot[Beta[a, b], {a, -3, 3}, {b, -3, 3}, IconizedObject[«PlotOptions»]]

Function Properties (11)

Real domain of the complete Euler beta function:

Wolfram Language code: FunctionDomain[Beta[a, b], {a, b}]

Complex domain:

Wolfram Language code: FunctionDomain[Beta[az, bz], {az, bz}, Complexes]

Permutation symmetry:

Wolfram Language code: Beta[a, b] == Beta[b, a]//FullSimplify

Euler beta function has the mirror property :

Wolfram Language code: FullSimplify[Beta[Conjugate[a], Conjugate[b]] == Conjugate[Beta[a, b]]]

The complete beta function is not an analytic function:

Wolfram Language code: FunctionAnalytic[Beta[a, b], {a, b}]

However, it is meromorphic:

Wolfram Language code: FunctionMeromorphic[Beta[a, b], {a, b}]

Its singularities and discontinuities are restricted to the non-positive integers:

Wolfram Language code: FunctionSingularities[Beta[a, b], {a, b}]

Wolfram Language code: FunctionDiscontinuities[Beta[a, b], {a, b}]

The incomplete beta function is an analytic function of for positive integer :

Wolfram Language code: FunctionAnalytic[Beta[x, a, 1], x, Assumptions -> a > 0 && a∈ℤ]

Thus, any such function will have no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[Beta[x, 1, 1], x]

Wolfram Language code: FunctionDiscontinuities[Beta[x, 1, 1], x]

For other values of , is neither analytic nor meromorphic:

Wolfram Language code: FunctionAnalytic[Beta[x, 1 / 2, 1], x]

Wolfram Language code: FunctionMeromorphic[Beta[x, 1 / 2, 1], x]

is neither non-increasing nor non-decreasing:

Wolfram Language code: FunctionMonotonicity[Beta[x, 1, 2], x]

is injective for positive odd but not positive even :

Wolfram Language code: FunctionInjective[Beta[x, 2k, 1], x, Assumptions -> k > 0 && k∈ℤ]

Wolfram Language code: FunctionInjective[Beta[x, 2k + 1, 1], x, Assumptions -> k > 0 && k∈ℤ]

Wolfram Language code: Plot[{Beta[x, 3, 1], Beta[x, 4, 1], 1}, {x, -2, 2}]

is surjective for positive odd but not positive even :

Wolfram Language code: Table[FunctionSurjective[Beta[x, a, 1], x], {a, 5}]

Wolfram Language code: Plot[{Beta[x, 3, 1], Beta[x, 4, 1], -1}, {x, -2, 2}]

is non-negative for positive even but indefinite for odd :

Wolfram Language code: Table[FunctionSign[Beta[x, a, 1], x], {a, 5}]

is convex for positive even :

Wolfram Language code: FunctionConvexity[Beta[x, 2k, 1], x, Assumptions -> k > 0 && k∈ℤ]

TraditionalForm formatting:

Wolfram Language code: Beta[a, b]//TraditionalForm

Differentiation (2)

First derivative of the beta function:

Wolfram Language code: D[Beta[a, b], a]

Wolfram Language code: D[Beta[a, b], b]

Higher derivatives of the beta function:

Wolfram Language code: derivs = Table[D[Beta[a, b], {b, n}], {n, 1, 3}]

Plot higher derivatives for :

Wolfram Language code:

Plot[Evaluate[derivs /. a -> 1 / 2], {b, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Series Expansions (5)

The beta function series expansion at poles:

Wolfram Language code: Series[Beta[z, -2z], {z, -5, 3}] // FullSimplify

The first term in the beta function series expansion around :

Wolfram Language code: Series[Beta[a, b], {a, 0, 1}]

Asymptotic expansion of the beta function:

Wolfram Language code: Series[Beta[a, b], {a, Infinity, 2}]

Incomplete beta function series expansion at any point:

Wolfram Language code: Series[Beta[z, a, b], {z, z0, 2}]

Wolfram Language code: Series[Beta[z, a, b], {a, a0, 1}]

Beta can be applied to power series:

Wolfram Language code: Beta[1 + x + (x^2/2) + O[x]^4, 3]//Simplify

Function Identities and Simplifications (4)

Generalized incomplete beta function is related to incomplete beta function:

Wolfram Language code: Beta[x, y, a, b]//FunctionExpand

Use FullSimplify to simplify beta functions:

Wolfram Language code: FullSimplify[Beta[2 a, 2 b]Beta[b, b] / (Beta[a, b] Beta[a + 1 / 2, b])]

Recurrence relationships:

Wolfram Language code: FullSimplify[Beta[a, b] == (a + b/a)Beta[a + 1, b]]

Wolfram Language code: FullSimplify[Beta[a, b] == Beta[a + 1, b] + Beta[a, b + 1]]

Product relation:

Wolfram Language code: FullSimplify[Beta[a, b]Beta[a + b, c] == Beta[b, c]Beta[b + c, a]]

Function Representations (6)

Primary definition in terms of Gamma function:

Wolfram Language code: FunctionExpand[Beta[a, b]]

Reduce the generalized incomplete beta function to incomplete beta functions:

Wolfram Language code: Beta[z1, z2, a, b]//FunctionExpand

Integral representation of the Euler beta function:

Wolfram Language code: Beta[a, b] == Integrate[x^a - 1(1 - x)^b - 1, {x, 0, 1}, Assumptions -> {Re[a] > 0, Re[b] > 0}]//FullSimplify

Integral representation of the incomplete beta function:

Wolfram Language code: Integrate[x^a - 1(1 - x)^b - 1, {x, 0, z}, Assumptions -> {Re[a] > 0 && z ≤ 1}]

Beta can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[Beta[x, a, b], x]

Wolfram Language code: Activate[%]//FullSimplify

Beta can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[Beta[x, a, b], x]

Generalizations & Extensions (6)

Euler Beta Function (2)

Evaluate symbolically in special cases:

Wolfram Language code: Beta[0, n]

Beta threads elementwise over lists:

Wolfram Language code: Beta[2, {2, 3, 4, 5}]

Incomplete Beta Function (2)

Evaluate symbolically at integer and half‐integer orders:

Wolfram Language code: Beta[z, 3, b] // FunctionExpand

Wolfram Language code: Beta[13 / 2, 7 / 2, 9 / 2] // FunctionExpand//Simplify

Series expansion at any point:

Wolfram Language code: Series[Beta[z, a, b], {z, z0, 2}]

Wolfram Language code: Series[Beta[z, a, b], {a, a0, 1}]

Generalized Incomplete Beta Function (2)

Generalized incomplete beta function is related to incomplete beta function:

Wolfram Language code: Beta[x, y, a, b]//FunctionExpand

Evaluate symbolically:

Wolfram Language code: Beta[1 / 4, 1 / 3, 1 / 2, 3 / 2]//FunctionExpand//Simplify

Applications (5)

Plot the beta function for real positive values:

Wolfram Language code: Plot3D[Beta[a, b], {a, 0, 2}, {b, 0, 2}]

Plot of the absolute value of Beta in the complex plane:

Wolfram Language code: Plot3D[Abs[Beta[x + I y, -3.1]], {x, -5, 2}, {y, -1, 1}]

Distribution of the average distance s of all pairs of points in a d‐dimensional hypersphere:

Wolfram Language code: p[d_, s_] := d s ^ (d - 1) Beta[1 - s ^ 2 / 4, (d + 1) / 2, 1 / 2] / Beta[(d + 1) / 2, 1 / 2]

Low‐dimensional distributions can be expressed in elementary functions:

Wolfram Language code: Table[FullSimplify[FunctionExpand[p[d, s]], s > 0], {d, 3}]

Plot distributions:

Wolfram Language code: Plot[Evaluate[Table[p[d, s], {d, 10}]], {s, 0, 2}]

The PDF for the beta distribution for random variable :

Wolfram Language code: PDF[BetaDistribution[α, β]][x]

Plot the PDF for various parameters:

Wolfram Language code:

Plot[Evaluate[Flatten[Table[PDF[BetaDistribution[α, β]][x], {α, {1, 2, 3, 4} / 4}, {β, {1, 2, 3, 4} / 4}]]], {x, 0, 1}]

Calculate the mean:

Wolfram Language code: Mean[BetaDistribution[α, β]]

The probability that more than (capacity) simultaneous service requests are made can be represented in terms of Gamma and Beta functions:

Wolfram Language code: Probability[x > c, xBinomialDistribution[n, p], Assumptions -> c∈Integers && 0 ≤ c ≤ n]

Properties & Relations (7)

Express the Euler beta function as a ratio of Euler gamma functions:

Wolfram Language code: FunctionExpand[Beta[a, b]]

Reduce the generalized incomplete beta function to incomplete beta functions:

Wolfram Language code: Beta[z1, z2, a, b]//FunctionExpand

Use FullSimplify to simplify beta functions:

Wolfram Language code: FullSimplify[Beta[2 a, 2 b]Beta[b, b] / (Beta[a, b] Beta[a + 1 / 2, b])]

Numerically find a root of a transcendental equation:

Wolfram Language code: FindRoot[Beta[1, z] - 4 Beta[2, z ^ 2] + z == 2, {z, 1}]

Sum expressions involving Beta:

Wolfram Language code: Underoverscript[∑, k = 1, n]Beta[k, k]

Wolfram Language code: Underoverscript[∑, k = 1, n](z^k/Beta[k, 2k])

Generating function:

Wolfram Language code: Underoverscript[∑, k = 1, ∞]Beta[k, b] x^k

Obtain as special cases of hypergeometric functions:

Wolfram Language code: z^aHypergeometric2F1[a, 1 - b, 1 + a, z]//FullSimplify

Beta can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[Beta[k, z], k]

Possible Issues (4)

Large arguments can give results too small to be computed explicitly:

Wolfram Language code: Beta[10 ^ 20., 10. ^ 20]

Machine‐number inputs can give high‐precision results:

Wolfram Language code: Beta[10. ^ 3, 10. ^ 3]

Wolfram Language code: MachineNumberQ[%]

Algorithmically generated results often use gamma and hypergeometric rather than beta functions:

Wolfram Language code: Underoverscript[∑, k = 0, ∞](Pochhammer[1 - b, k]/(a + k) k!)

Wolfram Language code: Integrate[t^a - 1 (1 - t)^b - 1, {t, 0, 1}, Assumptions -> Re[a] > 0∧Re[b] > 0]

Wolfram Language code: (1/a + b - 1)Underoverscript[∏, k = 1, ∞](k (a + b + k - 2)/(a + k - 1) (b + k - 1))

Wolfram Language code:

eq = z (1 - z) w''[z] + (1 - a + (a + b - 2) z)w'[z];
DSolve[eq == 0 , w[z], z]

The differential equation is satisfied by a sum of incomplete beta functions:

Wolfram Language code: eq /. w -> (Beta[#, a, b + 1] + Beta[#, a + 1, b]&)//Simplify

Beta functions are typically not generated by FullSimplify:

Wolfram Language code: Beta[a, b]//FunctionExpand

Wolfram Language code: FullSimplify[%]

Neat Examples (2)

Nest Beta over the complex plane:

Wolfram Language code: DensityPlot[Arg[Nest[Beta[#, #]&, x + I y, 3]], {x, -2, 4}, {y, -2, 2}, Exclusions -> {}]//Quiet

Define the beta matrix, whose entries are reciprocals of beta functions:

Wolfram Language code: betaMatrix[n_] := 1 / Array[Beta, {n, n}]

The determinant of the beta matrix is :

Wolfram Language code: Table[Det[betaMatrix[n]], {n, 10}]

Wolfram Language code: FindSequenceFunction[%, n]

The beta matrix is symmetric positive definite, and its Cholesky decomposition has entries of the form :

Wolfram Language code: Table[CholeskyDecomposition[betaMatrix[n]] == Array[Sqrt[#1]Binomial[#2, #1]&, {n, n}], {n, 10}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

Beta

Details

Examples

Basic Examples (6)

Scope (42)

Numerical Evaluation (8)

Specific Values (4)

Visualization (2)

Function Properties (11)

Differentiation (2)

Series Expansions (5)

Function Identities and Simplifications (4)

Function Representations (6)

Generalizations & Extensions (6)

Euler Beta Function (2)

Incomplete Beta Function (2)

Generalized Incomplete Beta Function (2)

Applications (5)

Properties & Relations (7)

Possible Issues (4)

Neat Examples (2)

Text

CMS

APA

BibTeX

BibLaTeX

Beta

Details

Examples

Basic Examples (6)

Scope (42)

Numerical Evaluation (8)

Specific Values (4)

Visualization (2)

Function Properties (11)

Differentiation (2)

Series Expansions (5)

Function Identities and Simplifications (4)

Function Representations (6)

Generalizations & Extensions (6)

Euler Beta Function (2)

Incomplete Beta Function (2)

Generalized Incomplete Beta Function (2)

Applications (5)

Properties & Relations (7)

Possible Issues (4)

Neat Examples (2)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX