WOLFRAM

Wolfram Language & System Documentation Center

KleinInvariantJ[τ]

gives the Klein invariant modular elliptic function TemplateBox[{tau}, KleinInvariantJ].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

KleinInvariantJ

KleinInvariantJ[τ]

gives the Klein invariant modular elliptic function TemplateBox[{tau}, KleinInvariantJ].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • The argument is the ratio of Weierstrass half‐periods .
  • KleinInvariantJ is given in terms of Weierstrass invariants by .
  • TemplateBox[{tau}, KleinInvariantJ] is invariant under any combination of the modular transformations and .
  • For certain special arguments, KleinInvariantJ automatically evaluates to exact values.
  • KleinInvariantJ can be evaluated to arbitrary numerical precision.
  • KleinInvariantJ can be used with CenteredInterval objects. »
  • KleinInvariantJ automatically threads over lists.

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: KleinInvariantJ[1 + 2.I]//Chop

Plot over a subset of the reals:

Wolfram Language code: Plot[Re[KleinInvariantJ[x + I]], {x, -2, 2}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[KleinInvariantJ[z + I], {z, -2 - I / 2, 2 + I / 2}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[KleinInvariantJ[x + I], {x, 0, 3}]//Normal//FullSimplify

Scope  (23)

Numerical Evaluation  (5)

Evaluate numerically:

Wolfram Language code: KleinInvariantJ[7.5 + I]//Quiet
Wolfram Language code: KleinInvariantJ[I]

Evaluate to high precision:

Wolfram Language code: N[KleinInvariantJ[1 / 9 + I], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: KleinInvariantJ[1.22222222222222222222 + I]

Evaluate efficiently at high precision:

Wolfram Language code: KleinInvariantJ[I + 1 / 5`100]//Timing
Wolfram Language code: KleinInvariantJ[I + 2 / 5`1000];//Timing

KleinInvariantJ can be used with CenteredInterval objects:

Wolfram Language code: KleinInvariantJ[CenteredInterval[2I, .2]]

Compute average-case statistical intervals using Around:

Wolfram Language code: KleinInvariantJ[ Around[ I , 0.001]]

Specific Values  (2)

Values at fixed points:

Wolfram Language code: KleinInvariantJ[I ]
Wolfram Language code: KleinInvariantJ[(-1 + I Sqrt[3]) / 2]//Quiet

Find the first positive maximum of the real part of KleinInvariantJ:

Wolfram Language code: xmax = x /. FindRoot[Re[D[KleinInvariantJ[x + I], x]] == 0, {x, 1}]
Wolfram Language code: Plot[Re[KleinInvariantJ[x + I]], {x, -1, 2}, Epilog -> Style[Point[{xmax, Re[KleinInvariantJ[xmax + I]]}], PointSize[Large], Red]]

Visualization  (2)

Plot the real part of KleinInvariantJ:

Wolfram Language code: Plot[Re[KleinInvariantJ[x + I]], {x, -2, 2}]

Plot the real part of J(τ) function:

Wolfram Language code: ComplexContourPlot[Re[KleinInvariantJ[z]], {z, -1 - 0.1 I, 1 + 3I}, Contours -> 20]

Plot the imaginary part of J(τ) function:

Wolfram Language code: ComplexContourPlot[Im[KleinInvariantJ[z]], {z, -1 - 0.1 I, 1 + 3 I}, Contours -> 20]

Function Properties  (10)

Complex domain of KleinInvariantJ:

Wolfram Language code: FunctionDomain[KleinInvariantJ[x], x, Complexes]

KleinInvariantJ is a periodic function:

Wolfram Language code: KleinInvariantJ[x + 1] == KleinInvariantJ[x]

KleinInvariantJ threads elementwise over lists:

Wolfram Language code: KleinInvariantJ[{0.2 + 2I, 0.3 + 2I, 0.4 + 2I}]

KleinInvariantJ is an analytic function on its domain of definition:

Wolfram Language code: FunctionAnalytic[{KleinInvariantJ[x], Im[x] > 0}, x, Complexes]

It has no singularities or discontinuities there:

Wolfram Language code: Simplify[FunctionSingularities[KleinInvariantJ[x], x, Complexes], Assumptions -> Im[x] > 0]
Wolfram Language code: Simplify[FunctionDiscontinuities[KleinInvariantJ[x], x, Complexes], Assumptions -> Im[x] > 0]

Re(TemplateBox[{{x, +, ⅈ}}, KleinInvariantJ]) is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[Re[KleinInvariantJ[x + I]], x]

KleinInvariantJ is not injective over the complexes:

Wolfram Language code: FunctionInjective[KleinInvariantJ[x], x, Complexes]

Re(TemplateBox[{{x, +, ⅈ}}, KleinInvariantJ]) is not surjective:

Wolfram Language code: FunctionSurjective[Re@KleinInvariantJ[x + I], x]
Wolfram Language code: Plot[{Re[KleinInvariantJ[x + I]], -1 / 2}, {x, -6, 6}]

Re(TemplateBox[{{x, +, ⅈ}}, KleinInvariantJ]) is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[Re[KleinInvariantJ[x + I]], x]

Re(TemplateBox[{{x, +, ⅈ}}, KleinInvariantJ]) is neither convex nor concave:

Wolfram Language code: FunctionConvexity[Re[KleinInvariantJ[x + I]], x]

TraditionalForm formatting:

Wolfram Language code: KleinInvariantJ[τ]//TraditionalForm

Differentiation  (2)

First derivative with respect to τ:

Wolfram Language code: D[KleinInvariantJ[τ], τ]

The first and second derivatives with respect to τ:

Wolfram Language code: Table[Re[D[KleinInvariantJ[τ + I], {τ, k}]], {k, 1, 2}]//FullSimplify

Plot the first and second derivatives with respect to τ:

Wolfram Language code: Plot[%, {τ, -1.5, 1.5}, PlotLegends -> {"First Derivative", "Second Derivative"}]

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[KleinInvariantJ[x + I], {x, 0, 3}]//Normal//FullSimplify

Plots of the first three approximations around :

Wolfram Language code: terms = Re@Normal@Table[Series[KleinInvariantJ[x + I], {x, 0, m}], {m, 1, 5, 2}]; Plot[{Re@KleinInvariantJ[x + I], terms}, {x, -2, 2}, PlotRange -> {-10, 10}]

Taylor expansion at a generic point:

Wolfram Language code: Series[KleinInvariantJ[x + I], {x, x0, 1}]//Normal// FullSimplify

Applications  (7)

Some modular properties of KleinInvariantJ are automatically applied:

Wolfram Language code: KleinInvariantJ[τ + 1]

Verify a more complicated identity numerically:

Wolfram Language code: KleinInvariantJ[τ / (1 - 2τ)] == KleinInvariantJ[τ] /. τ -> RandomComplex[{-3 + I / 10, 3 + 10 I}, {100}, WorkingPrecision -> 20]

Find values at quadratic irrationals:

Wolfram Language code: N[KleinInvariantJ[(-1 + I Sqrt[{7, 19, 163}]) / 2], 50]
Wolfram Language code: Rationalize[%]

KleinInvariantJ is a modular function. Make an ansatz for a modular equation:

Wolfram Language code: (ansatz = With[{u = KleinInvariantJ[z], v = KleinInvariantJ[2z]}, Sum[Subscript[c, i, j]u ^ i v ^ j, {i, 0, 3}, {j, 0, 3}] /. Subscript[c, 3, 0] -> 1] == 0)//TraditionalForm

Form an overdetermined system of equations and solve it:

Wolfram Language code: eqs = Table[N[ansatz /. z -> N[1 / 3 + 1 / k + I / 3, 250], 50], {k, 3, 24}];
Wolfram Language code: sol = Solve[eqs, Flatten[Table[Subscript[c, i, j], {i, 0, 3}, {j, 0, 3}]]]//Chop//Rationalize

This is the modular equation of order 2:

Wolfram Language code: ansatz /. First[sol]//TraditionalForm

Solution of the Chazy equation :

Wolfram Language code: w[z_] = Simplify[((4 - 7 KleinInvariantJ[z])KleinInvariantJ'[z] ^ 2 + 6(KleinInvariantJ[z] - 1)KleinInvariantJ[z] KleinInvariantJ''[z]) / (2(KleinInvariantJ[z] - 1)KleinInvariantJ[z]KleinInvariantJ'[z])];

Plot the solution:

Wolfram Language code: Plot[Re[w[x + 1.1I ]], {x, 0, 1}]

Plot the absolute value in the complex plane:

Wolfram Language code: Plot3D[Abs[KleinInvariantJ[x + I y]], {x, -1, 1}, {y, 0.2, 1}]

Plot the imaginary part in the complex plane:

Wolfram Language code: ContourPlot[Im[KleinInvariantJ[x + I y]], {x, -1, 1}, {y, 0.2, 1.5}, AspectRatio -> Automatic]

Define the discriminant of the Weierstrass elliptic curve:

Wolfram Language code: disc[g2_, g3_] = Block[{x}, Discriminant[4x ^ 3 - g2 x - g3, x] / 16]

It can be computed as the ratio of a power of invariant and the discriminant:

Wolfram Language code: j[τ_] := WeierstrassInvariantG2[{1, τ}] ^ 3 / disc[WeierstrassInvariantG2[{1, τ}], WeierstrassInvariantG3[{1, τ}]]
Wolfram Language code: j[0.5 I]

Compare with the built‐in function value:

Wolfram Language code: KleinInvariantJ[0.5 I]

Properties & Relations  (2)

Find derivatives:

Wolfram Language code: D[KleinInvariantJ[τ], τ]

Find a numerical root:

Wolfram Language code: FindRoot[KleinInvariantJ[z] + KleinInvariantJ[z ^ 2] + z == 2, {z, 1 + I}]

Possible Issues  (2)

Machine-precision input may be insufficient to give the correct answer:

Wolfram Language code: KleinInvariantJ[10. ^ 22 Pi + I]

With exact input, the answer is correct:

Wolfram Language code: N[KleinInvariantJ[10 ^ 22 Pi + I], 20]

KleinInvariantJ remains unevaluated outside of its domain of analyticity:

Wolfram Language code: KleinInvariantJ[Pi]
Wolfram Language code: N[%]
Wolfram Research (1996), KleinInvariantJ, Wolfram Language function, https://reference.wolfram.com/language/ref/KleinInvariantJ.html (updated 2021).

Text

Wolfram Research (1996), KleinInvariantJ, Wolfram Language function, https://reference.wolfram.com/language/ref/KleinInvariantJ.html (updated 2021).

CMS

Wolfram Language. 1996. "KleinInvariantJ." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/KleinInvariantJ.html.

APA

Wolfram Language. (1996). KleinInvariantJ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/KleinInvariantJ.html

BibTeX

@misc{reference.wolfram_2026_kleininvariantj, author="Wolfram Research", title="{KleinInvariantJ}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/KleinInvariantJ.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_kleininvariantj, organization={Wolfram Research}, title={KleinInvariantJ}, year={2021}, url={https://reference.wolfram.com/language/ref/KleinInvariantJ.html}, note=[Accessed: 12-June-2026]}