WOLFRAM

Wolfram Language & System Documentation Center

ModularLambda[τ]

gives the modular lambda elliptic function TemplateBox[{tau}, ModularLambda].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

ModularLambda

ModularLambda[τ]

gives the modular lambda elliptic function TemplateBox[{tau}, ModularLambda].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • ModularLambda is defined only in the upper half of the complex plane. It is not defined for real .
  • The argument is the ratio of Weierstrass half‐periods .
  • ModularLambda gives the parameter for elliptic functions in terms of according to m=TemplateBox[{tau}, ModularLambda].
  • ModularLambda is related to EllipticTheta by TemplateBox[{tau}, ModularLambda]=TemplateBox[{2, 0, q}, EllipticTheta]^4/TemplateBox[{3, 0, q}, EllipticTheta]^4 where the nome is given by .
  • is invariant under any combination of the modular transformations and . »
  • For certain special arguments, ModularLambda automatically evaluates to exact values.
  • ModularLambda can be evaluated to arbitrary numerical precision.
  • ModularLambda can be used with CenteredInterval objects. »
  • ModularLambda automatically threads over lists. »

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: ModularLambda[1 + 3.I]

Plot over a subset of the reals:

Wolfram Language code: Plot[Re[ModularLambda[x + I]], {x, -2, 2}]

Series expansion at the origin:

Wolfram Language code: Series[ModularLambda[x + I], {x, 0, 3}]//Normal//FullSimplify

Scope  (23)

Numerical Evaluation  (5)

Evaluate numerically:

Wolfram Language code: ModularLambda[14.3 + I]
Wolfram Language code: ModularLambda[1.5 + I]

Evaluate to high precision:

Wolfram Language code: N[ModularLambda[1 / 7 + I], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: ModularLambda[0.2000000000000000000 + I]

Evaluate efficiently at high precision:

Wolfram Language code: ModularLambda[I + 12`100]//Timing
Wolfram Language code: ModularLambda[I + 8`100000];//Timing

Compute the elementwise values of an array using automatic threading:

Wolfram Language code: ModularLambda[{{I, 0}, {0, I}}]

Or compute the matrix ModularLambda function using MatrixFunction:

Wolfram Language code: MatrixFunction[ModularLambda, {{I, 0}, {0, I}}]

ModularLambda can be used with CenteredInterval objects:

Wolfram Language code: ModularLambda[CenteredInterval[8 + 2I, .2]]

Specific Values  (2)

Value at a fixed point:

Wolfram Language code: ModularLambda[I ]

Find the first positive minimum of ModularLambda[x+I]:

Wolfram Language code: xmin = x /. FindRoot[Re[D[ModularLambda[x + I], x]] == 0, {x, 1}]
Wolfram Language code: Plot[Re[ModularLambda[x + I]], {x, -1, 4}, Epilog -> Style[Point[{xmin, Re[ModularLambda[xmin + I]]}], PointSize[Large], Red]]

Visualization  (3)

Plot the real part of ModularLambda:

Wolfram Language code: Plot[Re[ModularLambda[t + I]], {t, -5, 5}]

Plot the absolute value of ModularLambda:

Wolfram Language code: Plot[Abs[ModularLambda[t + I]], {t, -5, 5}]

Plot the real part of ModularLambda function:

Wolfram Language code: ComplexContourPlot[Re[ModularLambda[z]], {z, -4 - 0.1 I, 4 + 3 I}, Contours -> 20]

Plot the imaginary part of ModularLambda function:

Wolfram Language code: ComplexContourPlot[Im[ModularLambda[z]], {z, -4 - 0.1 I, 4 + 3 I}, Contours -> 20]

Function Properties  (9)

ModularLambda is defined in the upper half-plane:

Wolfram Language code: FunctionDomain[ModularLambda[x], x, Complexes]

ModularLambda is a periodic function:

Wolfram Language code: FunctionPeriod[ModularLambda[x + I], x]

ModularLambda threads elementwise over lists:

Wolfram Language code: ModularLambda[{0.2 + 2I, 0.3 + 2I, 0.4 + 2I}]

ModularLambda is an analytic function on its domain:

Wolfram Language code: FunctionAnalytic[{ModularLambda[x], Im[x] > 0}, x, Complexes]

Therefore it has neither singularities nor discontinuities there:

Wolfram Language code: Simplify[FunctionSingularities[ModularLambda[x], x, Complexes], Im[x] > 0]
Wolfram Language code: Simplify[FunctionDiscontinuities[ModularLambda[x], x, Complexes], Im[x] > 0]

Re(TemplateBox[{{x, +, ⅈ}}, ModularLambda]) is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[Re[ModularLambda[x + I]], x]

Re(TemplateBox[{{x, +, ⅈ}}, ModularLambda]) is not surjective:

Wolfram Language code: FunctionSurjective[Re[ModularLambda[x + I]], x]
Wolfram Language code: Plot[{Re[ModularLambda[x + I]], 2}, {x, -6, 6}]

Re(TemplateBox[{{x, +, ⅈ}}, ModularLambda]) is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[Re[ModularLambda[x + I]], x]

Re(TemplateBox[{{x, +, ⅈ}}, ModularLambda]) is neither convex nor concave:

Wolfram Language code: FunctionConvexity[Re[ModularLambda[x + I]], x]

TraditionalForm formatting:

Wolfram Language code: ModularLambda[τ]//TraditionalForm

Differentiation  (2)

First derivative with respect to z:

Wolfram Language code: D[ModularLambda[z], z]

Higher derivatives with respect to z:

Wolfram Language code: Table[D[ModularLambda[z + I], {z, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to z:

Wolfram Language code: Plot[Evaluate[Re[%]], {z, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[ModularLambda[x + I], {x, 0, 3}]//Normal//FullSimplify

Plots of the first three approximations around :

Wolfram Language code: terms = Re@Normal[Table[Series[ModularLambda[x + I], {x, 0, m}], {m, 1, 5, 2}]]; Plot[terms, {x, -2, 2}, PlotRange -> {-1, 1}]

Taylor expansion at a generic point:

Wolfram Language code: Series[ModularLambda[x + I], {x, x0, 2}]// Normal//FullSimplify

Applications  (4)

Some modular properties of ModularLambda are automatically applied:

Wolfram Language code: ModularLambda[τ + 2]

Verify a more complicated identity numerically:

Wolfram Language code: ModularLambda[τ / (1 - 2 τ)] == ModularLambda[τ] /. τ -> RandomComplex[{-3 + I / 10, 3 + 10 I}, {100}, WorkingPrecision -> 20]

ModularLambda is a modular function. Make an ansatz for a modular equation:

Wolfram Language code: (ansatz = With[{u = ModularLambda[z], v = ModularLambda[2z]}, Sum[Subscript[c, i, j]u ^ i v ^ j, {i, 0, 2}, {j, 0, 2}] /. Subscript[c, 2, 0] -> 1] == 0)//TraditionalForm

Form an overdetermined system of equations and solve it:

Wolfram Language code: eqs = Table[N[ansatz /. z -> N[1 / 3 + 1 / k + I / 3, 250], 50], {k, 3, 24}];
Wolfram Language code: sol = Solve[eqs, Flatten[Table[Subscript[c, i, j], {i, 0, 2}, {j, 0, 2}]]]//Chop//Rationalize

This is the modular equation of order 2:

Wolfram Language code: ansatz /. First[sol]//TraditionalForm

Solution of the Darboux–Halphen system:

Wolfram Language code: w1[τ_] = 1 / 2 D[Log[ModularLambda'[τ] / ModularLambda[τ]], τ]; w2[τ_] = 1 / 2 D[Log[ModularLambda'[τ] / (ModularLambda[τ] - 1)], τ]; w3[τ_] = 1 / 2D[Log[ModularLambda'[τ] / (ModularLambda[τ](ModularLambda[τ] - 1))], τ];

Check:

Wolfram Language code: {D[w1[τ], τ] - (w1[τ](w2[τ] + w3[τ]) - w2[τ] w3[τ]), D[w2[τ], τ] - (w2[τ](w1[τ] + w3[τ]) - w1[τ] w3[τ]), D[w3[τ], τ] - (w3[τ](w1[τ] + w2[τ]) - w1[τ] w2[τ])}//FullSimplify

Plot the real part in the complex plane:

Wolfram Language code: ContourPlot[Re[ModularLambda[x + I y]], {x, -1, 1}, {y, 0.2, 1.5}, AspectRatio -> Automatic]

Properties & Relations  (2)

Find derivatives:

Wolfram Language code: D[ModularLambda[τ], τ]

Find a numerical root:

Wolfram Language code: FindRoot[ModularLambda[z] + ModularLambda[z ^ 2] + z == 1, {z, 1 + I}]

Possible Issues  (2)

Machine-precision input is insufficient to give a correct answer:

Wolfram Language code: ModularLambda[10. ^ 22 Pi + I]

With exact input, the answer is correct:

Wolfram Language code: N[ModularLambda[10 ^ 22 Pi + I], 20]

ModularLambda remains unevaluated outside of its domain of analyticity:

Wolfram Language code: ModularLambda[1]
Wolfram Language code: N[%]
Wolfram Research (1996), ModularLambda, Wolfram Language function, https://reference.wolfram.com/language/ref/ModularLambda.html (updated 2021).

Text

Wolfram Research (1996), ModularLambda, Wolfram Language function, https://reference.wolfram.com/language/ref/ModularLambda.html (updated 2021).

CMS

Wolfram Language. 1996. "ModularLambda." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ModularLambda.html.

APA

Wolfram Language. (1996). ModularLambda. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ModularLambda.html

BibTeX

@misc{reference.wolfram_2026_modularlambda, author="Wolfram Research", title="{ModularLambda}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ModularLambda.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_modularlambda, organization={Wolfram Research}, title={ModularLambda}, year={2021}, url={https://reference.wolfram.com/language/ref/ModularLambda.html}, note=[Accessed: 13-June-2026]}