WOLFRAM

Wolfram Language & System Documentation Center

Labeled[expr,lbl]

displays expr labeled with lbl.

Labeled[expr,lbl,pos]

places lbl at a position specified by pos.

Labeled[expr,{lbl1,lbl2,…},{pos1,…}]

places the lbli at positions posi.

Labeled[expr,{lbl1,lbl2,lbl3,lbl4},All]

places the lbli at the bottom, left, top, and right, respectively.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Alignment  
Background  
BaselinePosition  
Show More Show More
ContentSize  
Editable  
Frame  
FrameMargins  
FrameStyle  
ImageMargins  
LabelStyle  
RotateLabel  
RoundingRadius  
Spacings  
Applications  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Labeled

Labeled[expr,lbl]

displays expr labeled with lbl.

Labeled[expr,lbl,pos]

places lbl at a position specified by pos.

Labeled[expr,{lbl1,lbl2,…},{pos1,…}]

places the lbli at positions posi.

Labeled[expr,{lbl1,lbl2,lbl3,lbl4},All]

places the lbli at the bottom, left, top, and right, respectively.

Details and Options

Examples

open all close all

Basic Examples  (2)

Create a label:

Wolfram Language code: Labeled[{a, b, c, d}, lbl]
Wolfram Language code: Labeled[Framed[{a, b, c, d}], lbl]

Label on the left:

Wolfram Language code: Labeled[Framed[{a, b, c, d}], lbl, Left]

Label on the left and top:

Wolfram Language code: Labeled[Framed[{a, b, c, d}], {xxx, yyy}, {Left, Top}]

Scope  (5)

Label a graphic:

Wolfram Language code: Labeled[Graphics[Circle[]], Text["a circle"]]

Label a slider:

Wolfram Language code: Labeled[Slider[], "slider"]
Wolfram Language code: Labeled[Slider[], "slider", Left]

Use a checkbox as a label:

Wolfram Language code: Labeled[Framed[{a, b, c}], Checkbox[]]

Control the placement of labels:

Wolfram Language code: g = Graphics[Circle[], ImageSize -> 50];
Wolfram Language code: Labeled[g, lbl]

Put the label at the bottom, aligned left:

Wolfram Language code: Labeled[g, lbl, {{Bottom, Left}}]

Put the label on the right, aligned at the top:

Wolfram Language code: Labeled[g, lbl, {{Right, Top}}]

Use graphics as labels:

Wolfram Language code: d = Graphics[Circle[], ImageSize -> 20];
Wolfram Language code: Labeled[30!, {d, d, d}, {Top, Bottom, Left}]

Options  (18)

Alignment  (1)

Adjust the alignment of the labeled expression:

Wolfram Language code: Grid[Table[Labeled[Range[4], "lbl", ContentSize -> {150, 50}, Alignment -> {i, j}], {j, {Top, Center, Bottom}}, {i, {Left, Center, Right}}], Frame -> All]

Background  (1)

Change the overall background color:

Wolfram Language code: Labeled[{1, 2, 3, 4}, lbl, Background -> StandardGray]

BaselinePosition  (1)

Align with surrounding text:

Wolfram Language code: Row[Table[Labeled[{1, 2, 3, 4}, lbl, BaselinePosition -> p], {p, {Top, Center, Bottom}}], " xxx "]

ContentSize  (1)

Specify a fixed content size:

Wolfram Language code: Table[Labeled[{1, 2, 3, 4}, lbl, ContentSize -> {80, s}], {s, {10, 20, 40}}]

Editable  (2)

By default, editing of labels and expressions is allowed:

Wolfram Language code: Labeled[123456, "number"]

Disallow editing:

Wolfram Language code: Labeled[123456, "number", Editable -> False]

Frame  (1)

Frame only the expression, not the label:

Wolfram Language code: Labeled[{1, 2, 3, 4}, lbl, Frame -> True]

FrameMargins  (2)

Add space within the frame:

Wolfram Language code: Table[Labeled[{1, 2, 3, 4}, lbl, Frame -> True, FrameMargins -> m], {m, {0, 10, 20}}]

FrameMargins also increases the area to which Background applies:

Wolfram Language code: Table[Labeled[{1, 2, 3, 4}, lbl, Frame -> True, Background -> StandardBlue, FrameMargins -> m], {m, {0, 10, 20}}]

FrameStyle  (1)

Change the color of the frame:

Wolfram Language code: Table[Labeled[{1, 2, 3, 4}, lbl, Frame -> True, FrameStyle -> c], {c, {Red, Green, Blue}}]

ImageMargins  (1)

Add margins around the labeled expression:

Wolfram Language code: Table[Framed@ Labeled[{1, 2, 3, 4}, lbl, ImageMargins -> m], {m, {0, 10, 20}}]

Specify different margins for each side:

Wolfram Language code: Framed@Labeled[{1, 2, 3, 4}, lbl, ImageMargins -> {{5, 10}, {20, 30}}]

LabelStyle  (2)

Style the label:

Wolfram Language code: Labeled[{1, 2, 3, 4}, "label", LabelStyle -> Red]

Use Directive to specify compound styles:

Wolfram Language code: Labeled[{1, 2, 3, 4}, "label", LabelStyle -> Directive[Bold, FontFamily -> "Helvetica"]]

RotateLabel  (1)

Rotate vertical labels:

Wolfram Language code: Labeled[Grid[Partition[Range[9], 3]], "label", Left, RotateLabel -> True]

RoundingRadius  (1)

Round the corners of the frame:

Wolfram Language code: Table[Labeled[{1, 2, 3, 4}, lbl, Frame -> True, RoundingRadius -> r], {r, 0, 9, 3}]

Spacings  (3)

Add horizontal spacing between the expression and the label:

Wolfram Language code: Column@Table[Framed@Labeled[{1, 2, 3, 4}, "label", Right, Spacings -> s], {s, {0, 5, 10}}]

Specify vertical spacing:

Wolfram Language code: Table[Framed@Labeled[{1, 2, 3, 4}, "label", Spacings -> {Automatic, s}], {s, {0, 5, 10}}]

Use both vertical and horizontal spacing:

Wolfram Language code: Labeled[Framed[{a, b, c, d}], {x, y}, {Right, Bottom}, Spacings -> {7, 3}]

Applications  (2)

Label images with checkboxes, potentially for later processing:

Wolfram Language code: Table[Labeled[ArrayPlot[CellularAutomaton[i, {{1}, 0}, {30, All}], ImageSize -> Small], Checkbox[]], {i, 20, 23}]

Create an active label:

Wolfram Language code: DynamicModule[{c}, Labeled[Graphics[{Dynamic[c], Disk[]}, ImageSize -> Tiny], Toggler[Dynamic[c], Reverse /@ ColorData["HTML", "ColorRules"], ImageSize -> Automatic]]]

Neat Examples  (2)

Wolfram Language code: NestList[Labeled[#, {a, b}, {Top, Left}]&, x, 5]
Wolfram Language code: NestList[Labeled[#, {a, b, c}, {Top, Left, Right}]&, x, 5]
Wolfram Language code: NestList[Labeled[#, {#, #, #, #}, All]&, x, 2]
Wolfram Language code: NestList[Labeled[#, {#, #}, All]&, x, 3]
Wolfram Language code: NestList[Labeled[#, {#, #}, All]&, Checkbox[], 3]
Wolfram Research (2007), Labeled, Wolfram Language function, https://reference.wolfram.com/language/ref/Labeled.html (updated 2019).

Text

Wolfram Research (2007), Labeled, Wolfram Language function, https://reference.wolfram.com/language/ref/Labeled.html (updated 2019).

CMS

Wolfram Language. 2007. "Labeled." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Labeled.html.

APA

Wolfram Language. (2007). Labeled. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Labeled.html

BibTeX

@misc{reference.wolfram_2026_labeled, author="Wolfram Research", title="{Labeled}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Labeled.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_labeled, organization={Wolfram Research}, title={Labeled}, year={2019}, url={https://reference.wolfram.com/language/ref/Labeled.html}, note=[Accessed: 13-June-2026]}