WOLFRAM

Wolfram Language & System Documentation Center

PlotLabel

is an option for graphics functions that specifies an overall label for a plot.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Workflows
History
Cite this Page

PlotLabel

PlotLabel

is an option for graphics functions that specifies an overall label for a plot.

Details

  • PlotLabel->None specifies that no label should be given.
  • PlotLabel->label specifies a label to give.
  • Any expression can be used as a label. It will be given by default in TraditionalForm. Arbitrary strings of text can be given as "text". »
  • PlotLabel->StandardForm[expr] will give a label in standard Wolfram Language form. »

Examples

open all close all

Basic Examples  (3)

Use any Wolfram Language notation for labels:

Wolfram Language code: Plot[BesselJ[1, x], {x, 0, 10}, PlotLabel -> BesselJ[1, x]]
Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 == z ^ 2, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}, PlotLabel -> x ^ 2 + y ^ 2 == z ^ 2]

Use Style and other typesetting functions to modify how the label appears:

Wolfram Language code: RegionPlot[y ^ 3 < x ^ 2 + x, {x, -2, 2}, {y, -2, 2}, PlotLabel -> Style[Framed[y ^ 3 < x ^ 2 + x], 16, Blue, Background -> Lighter[Yellow]]]

Overall style of all the label-like elements can be specified by LabelStyle:

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, PlotLabel -> 2Sin[x], LabelStyle -> Directive[Bold, Orange]]

Scope  (2)

Labels use TraditionalForm by default:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, PlotLabel -> Sin[x]]

Use StandardForm instead:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, PlotLabel -> StandardForm[Sin[x]]]

An individually styled label can be used with LabelStyle, and has higher priority:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, PlotLabel -> Style[Sin[x], Blue, 20], LabelStyle -> Directive[Orange, Italic]]

Applications  (1)

Automatically label different cases:

Wolfram Language code: Table[SphericalPlot3D[1 + Sin[5ϕ] / 10, {θ, 0, Pi}, {ϕ, 0, 2Pi}, RegionFunction -> Function[{x, y, z, θ, ϕ, r}, Evaluate[f]], PlotLabel -> f, Mesh -> None, BoundaryStyle -> Black, PlotRange -> 1.1, Axes -> None], {f, {0 < x < 1, 0 < y < 1, 0 < z < 1, 0 < θ < 1, 0 < ϕ < Pi / 2, 1 / 2 < r < 1}}]
Wolfram Language code: Table[Plot[Evaluate[f[x]], {x, -5, 5}, PlotLabel -> f[x]], {f, {Sin, Cos, Csc, Sec, Tan, Cot}}]

Properties & Relations  (1)

The overall output format can be specified using FormatType:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, PlotLabel -> Sin[x], FormatType -> StandardForm]

Possible Issues  (1)

When different format types are combined, the result is likely to be unpredictable:

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, PlotLabel -> TraditionalForm@Sin[x], FormatType -> StandardForm]

This is equivalent to:

Wolfram Language code: StandardForm[TraditionalForm[Sin[x]]]

Neat Examples  (1)

Interactively choose a function to plot:

Wolfram Language code: Dynamic[Plot[f[x], {x, 0, 10}, PlotLabel -> Row[{Style["f", Italic], "=", PopupMenu[Dynamic[f], {Sin, Cos, Tan, Sinc}]}]]]
Wolfram Research (1988), PlotLabel, Wolfram Language function, https://reference.wolfram.com/language/ref/PlotLabel.html (updated 2007).

Text

Wolfram Research (1988), PlotLabel, Wolfram Language function, https://reference.wolfram.com/language/ref/PlotLabel.html (updated 2007).

CMS

Wolfram Language. 1988. "PlotLabel." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/PlotLabel.html.

APA

Wolfram Language. (1988). PlotLabel. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PlotLabel.html

BibTeX

@misc{reference.wolfram_2026_plotlabel, author="Wolfram Research", title="{PlotLabel}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/PlotLabel.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_plotlabel, organization={Wolfram Research}, title={PlotLabel}, year={2007}, url={https://reference.wolfram.com/language/ref/PlotLabel.html}, note=[Accessed: 13-June-2026]}