WOLFRAM

Wolfram Language & System Documentation Center

LiouvilleLambda[n]

gives the Liouville function .

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Symbolic Manipulation  
Options  
GaussianIntegers  
Applications  
Basic Applications  
Number Theory  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

LiouvilleLambda

LiouvilleLambda[n]

gives the Liouville function .

Details and Options

  • LiouvilleLambda is also known as Liouville function.
  • Integer mathematical function, suitable for both symbolic and numerical manipulation.
  • LiouvilleLambda[n] gives 1 whenever the number of prime factors counting multiplicity of n is even and -1 otherwise.
  • For a number n=u p1k1⋯ pmkm with u a unit and pi primes, LiouvilleLambda[n] returns (-1)k1+⋯+km.
  • With the setting GaussianIntegers->True, LiouvilleLambda is defined using factorization over Gaussian integers.
  • LiouvilleLambda[m+In] automatically works over Gaussian integers.

Examples

open all close all

Basic Examples  (2)

Compute the Liouville function at and :

Wolfram Language code: LiouvilleLambda[8]
Wolfram Language code: LiouvilleLambda[9]

Plot the LiouvilleLambda sequence for the first 20 numbers:

Wolfram Language code: DiscretePlot[LiouvilleLambda[n], {n, 20}, AxesOrigin -> {0, 0}]

Scope  (8)

Numerical Evaluation  (4)

LiouvilleLambda works over integers:

Wolfram Language code: LiouvilleLambda[8]

Gaussian integers:

Wolfram Language code: LiouvilleLambda[2 + I]
Wolfram Language code: LiouvilleLambda[8, GaussianIntegers -> True]

Compute for large integers:

Wolfram Language code: LiouvilleLambda[10 ^ 30 + 1]

LiouvilleLambda threads over lists:

Wolfram Language code: LiouvilleLambda[{1, 2, 3, 4, 5, 6}]

Symbolic Manipulation  (4)

TraditionalForm formatting:

Wolfram Language code: LiouvilleLambda[n]//TraditionalForm

Reduce expressions:

Wolfram Language code: Reduce[LiouvilleLambda[n] == 1 && 0 < n < 10, n, Integers]

Solve equations:

Wolfram Language code: Solve[LiouvilleLambda[a ^ 2 + 2b ^ 2] == LiouvilleLambda[2a + 3b ^ 2] && 10 < a < b < 15, {a, b}, Integers]

DirichletTransform of LiouvilleLambda:

Wolfram Language code: DirichletTransform[LiouvilleLambda[n], n, s]

Equivalently:

Wolfram Language code: Sum[LiouvilleLambda[k] / k ^ s, {k, 1, Infinity}]

Options  (1)

GaussianIntegers  (1)

Compute LiouvilleLambda over integers:

Wolfram Language code: LiouvilleLambda[2, GaussianIntegers -> True]

Gaussian integers:

Wolfram Language code: LiouvilleLambda[2, GaussianIntegers -> False]

Applications  (5)

Basic Applications  (2)

Highlight numbers for which Liouville's function is in blue and for which it is in red:

Wolfram Language code: Multicolumn[If[LiouvilleLambda[#] == -1, Style[#, Blue, Bold], Style[#, Red, Bold]]& /@ Range[100], 10, ...]

Histogram of the cumulative values of LiouvilleLambda:

Wolfram Language code: L[n_] := Total[LiouvilleLambda[Range[n]]];
Wolfram Language code: Histogram[Table[L[n], {n, 10 ^ 3}]]

Number Theory  (3)

LiouvilleLambda and MoebiusMu are related by the equation :

Wolfram Language code: Table[DivisorSum[n, MoebiusMu[n / # ^ 2]&, Divisible[n, # ^ 2]&] == LiouvilleLambda[n], {n, 10}]

Use LiouvilleLambda to compute MoebiusMu:

Wolfram Language code: μ[n_] := KroneckerDelta[PrimeNu[n], PrimeOmega[n]]LiouvilleLambda[n];
Wolfram Language code: Table[μ[n], {n, 1, 10}]
Wolfram Language code: Table[MoebiusMu[n], {n, 1, 10}]

Plot the summatory function :

Wolfram Language code: L[n_] := Total[LiouvilleLambda[Range[n]]];
Wolfram Language code: DiscretePlot[L[n], {n, 1, 1000}]

Properties & Relations  (5)

LiouvilleLambda is a completely multiplicative function:

Wolfram Language code: LiouvilleLambda[6 27] == LiouvilleLambda[6] LiouvilleLambda[27]

LiouvilleLambda gives when the argument is a product of an even number of primes:

Wolfram Language code: LiouvilleLambda[2 2 3 5]

Otherwise, it gives :

Wolfram Language code: LiouvilleLambda[2 3 5]

Use FactorInteger to compute LiouvilleLambda:

Wolfram Language code: (-1) ^ Total[FactorInteger[120][[All, -1]]]
Wolfram Language code: LiouvilleLambda[120]

Use PrimeOmega to compute LiouvilleLambda:

Wolfram Language code: (-1) ^ PrimeOmega[25]
Wolfram Language code: LiouvilleLambda[25]

gives for a perfect square n and otherwise:

Wolfram Language code: DivisorSum[64, LiouvilleLambda[#]&]
Wolfram Language code: DivisorSum[7, LiouvilleLambda[#]&]

Neat Examples  (3)

Plot LiouvilleLambda for the sum of two squares:

Wolfram Language code: ArrayPlot[Table[LiouvilleLambda[a ^ 2 + b ^ 2], {a, 50}, {b, 50}], ColorFunction -> "BlueGreenYellow"]

Plot the arguments of the Fourier transform of LiouvilleLambda:

Wolfram Language code: ArrayPlot[Arg[Fourier[Table[LiouvilleLambda[m + n], {m, 200}, {n, 200}]]], ColorFunction -> Hue]

Plot the Ulam spiral of LiouvilleLambda:

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[LiouvilleLambda[ulam[101]], ColorFunction -> "Rainbow"]
Wolfram Research (2008), LiouvilleLambda, Wolfram Language function, https://reference.wolfram.com/language/ref/LiouvilleLambda.html.

Text

Wolfram Research (2008), LiouvilleLambda, Wolfram Language function, https://reference.wolfram.com/language/ref/LiouvilleLambda.html.

CMS

Wolfram Language. 2008. "LiouvilleLambda." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/LiouvilleLambda.html.

APA

Wolfram Language. (2008). LiouvilleLambda. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LiouvilleLambda.html

BibTeX

@misc{reference.wolfram_2026_liouvillelambda, author="Wolfram Research", title="{LiouvilleLambda}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/LiouvilleLambda.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_liouvillelambda, organization={Wolfram Research}, title={LiouvilleLambda}, year={2008}, url={https://reference.wolfram.com/language/ref/LiouvilleLambda.html}, note=[Accessed: 13-June-2026]}