MarchenkoPasturDistribution[λ,σ]
represents a Marchenko–Pastur distribution with asymptotic ratio 
and scale parameter 
.
MarchenkoPasturDistribution
MarchenkoPasturDistribution[λ,σ]
represents a Marchenko–Pastur distribution with asymptotic ratio 
and scale parameter 
.
MarchenkoPasturDistribution[λ]
represents a Marchenko–Pastur distribution with unit scale parameter.
Details
- MarchenkoPasturDistribution is the limiting spectral density of random matrices from WishartMatrixDistribution.
- The derivative of cumulative distribution function at
in a Marchenko–Pastur distribution is proportional to 
with 
for 
between 
and 
. - Marchenko–Pastur distribution has a point mass at
with probability 
when 
. - MarchenkoPasturDistribution allows
and 
to be any positive real numbers. - MarchenkoPasturDistribution allows σ to be a quantity of any unit dimension, and λ to be a dimensionless quantity. »
- MarchenkoPasturDistribution can be used with such functions as Mean, CDF, and RandomVariate.
Examples
open all close allBasic Examples (3)
Plot[Table[PDF[MarchenkoPasturDistribution[λ], x], {λ, {0.2, 0.5, 0.8}}]//Evaluate, {x, 0, 4}, Exclusions -> None, Filling -> Axis]Plot[Table[PDF[MarchenkoPasturDistribution[0.5, σ], x], {σ, {0.9, 1.0, 1.1}}]//Evaluate, {x, 0, 4}, Exclusions -> None, Filling -> Axis]Cumulative distribution function:
Plot[Table[CDF[MarchenkoPasturDistribution[λ], x], {λ, {0.5, 1.0, 1.5}}]//Evaluate, {x, 0, 5}, Filling -> Axis, Exclusions -> None]cdf = CDF[MarchenkoPasturDistribution[λ], x];Simplify[cdf, 0 < λ < 1]Simplify[cdf, λ > 1]Plot[Table[CDF[MarchenkoPasturDistribution[1 / 2, σ], x], {σ, {0.9, 1.0, 1.1}}]//Evaluate, {x, 0, 4}, Exclusions -> None, Filling -> Axis]CDF[MarchenkoPasturDistribution[1 / 2, σ], x]Mean[MarchenkoPasturDistribution[λ, σ]]Variance[MarchenkoPasturDistribution[λ, σ]]Scope (7)
Generate a sample of pseudorandom numbers from a Marchenko–Pastur distribution with 
:
data = RandomVariate[MarchenkoPasturDistribution[1 / 2], 10 ^ 4];Compare its histogram to the PDF:
Show[
Histogram[data, {3 / 2 - Sqrt[2], 3 / 2 + Sqrt[2], Automatic}, PDF],
Plot[PDF[MarchenkoPasturDistribution[1 / 2], x], {x, 0, 4}, PlotStyle -> Thick, Exclusions -> None]]Generate a sample of pseudorandom numbers from a Marchenko–Pastur distribution with 
:
data = RandomVariate[MarchenkoPasturDistribution[4], 10 ^ 4];Compare its cumulative histogram to the CDF:
Show[
Histogram[data, Automatic, CDF],
Plot[CDF[MarchenkoPasturDistribution[4], x], {x, 0, 9}, PlotStyle -> Thick]]Distribution parameters estimation:
sample = RandomVariate[MarchenkoPasturDistribution[2, 1], 10 ^ 3];Estimate the distribution parameters from sample data:
edist = EstimatedDistribution[sample, MarchenkoPasturDistribution[λ, σ]]Compare the cumulative histogram of the sample with the CDF of the estimated distribution:
Show[Histogram[sample, 20, CDF], Plot[CDF[edist, x], {x, 0, 6}, PlotStyle -> Thick]]Skewness and kurtosis depend only on 
:
Skewness[MarchenkoPasturDistribution[λ, σ]]Kurtosis[MarchenkoPasturDistribution[λ, σ]]Different moments with closed forms as functions of parameters:
FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[MarchenkoPasturDistribution[λ, σ], k]//Expand, {k, 3}], M]Closed form for symbolic order:
Moment[MarchenkoPasturDistribution[λ, σ], k]FormulaGrid[Table[CentralMoment[MarchenkoPasturDistribution[λ, σ], k], {k, 3}], CM]Closed form for symbolic order:
CentralMoment[MarchenkoPasturDistribution[λ, σ], k]FormulaGrid[Table[FactorialMoment[MarchenkoPasturDistribution[λ, σ], k], {k, 3}], FM]FormulaGrid[Table[Cumulant[MarchenkoPasturDistribution[λ, σ], k], {k, 3}], C]Plot[HazardFunction[MarchenkoPasturDistribution[1 / 2], x], {x, (1 - Sqrt[1 / 2]) ^ 2, (1 + Sqrt[1 / 2]) ^ 2}, Filling -> Axis]HazardFunction[MarchenkoPasturDistribution[1 / 2], x]Plot[Table[Quantile[MarchenkoPasturDistribution[λ], q], {λ, {0.5, 1.0, 2.0}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Plot[Table[Quantile[MarchenkoPasturDistribution[0.5, σ], q], {σ, {0.5, 1.0, 1.5}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Consistent use of Quantity in parameters yields QuantityDistribution:
a𝒟 = MarchenkoPasturDistribution[0.5, Quantity[1.2, "Meters"]]Median[a𝒟]Applications (1)
Use MatrixPropertyDistribution to represent the eigenvalues of a Wishart random matrix with identity covariance:
λ𝒟[n_, p_] := MatrixPropertyDistribution[Eigenvalues[𝓂], 𝓂WishartMatrixDistribution[n, IdentityMatrix[p] / n]]{n, p} = {10 ^ 4, 10 ^ 3};
data = RandomVariate[λ𝒟[n, p]];The spectral density converges to the pdf of MarchenkoPasturDistribution[λ] in the limit of large 
and 
with the finite ratio 
:
Show[Histogram[data, 20, PDF], Plot[PDF[MarchenkoPasturDistribution[p / n], x], {x, 0, 1.8}, PlotStyle -> Thick, Exclusions -> None]]Properties & Relations (3)
MarchenkoPasturDistribution is closed under scaling by a positive factor:
TransformedDistribution[k u, uMarchenkoPasturDistribution[λ, σ], Assumptions -> k > 0]MarchenkoPasturDistribution has an atomic weight at 0 when 
:
Probability[x == 0, xMarchenkoPasturDistribution[λ, σ]]MarchenkoPasturDistribution is the limiting distribution of eigenvalues of Wishart matrices. The atomic weight at 
occurs when the Wishart matrix is singular. Generate a singular Wishart matrix with identity covariance and compute the scaled eigenvalues:
matrix = Transpose[#].#&[RandomVariate[NormalDistribution[], {500, 1000}]];
eigvs = Chop[Eigenvalues[matrix] / 500];Fit MarchenkoPasturDistribution to the eigenvalues:
edist = EstimatedDistribution[eigvs, MarchenkoPasturDistribution[lambda, 1]]Compare the cumulative histogram of the eigenvalues with the CDF:
Show[Histogram[eigvs, 20, CDF], Plot[CDF[edist, x], {x, 0, 6}, PlotStyle -> Thick]]Possible Issues (1)
Marchenko–Pastur distribution with 
is a mixed type distribution, which is neither continuous nor discrete:
𝒟 = MarchenkoPasturDistribution[9 / 4];The CDF for such Marchenko–Pastur distributions is discontinuous at 
:
cdf = CDF[𝒟, x]//SimplifyPlot[cdf, {x, -0.5, 7}, Exclusions -> x == 0, PlotTheme -> "Detailed", ExclusionsStyle -> {Dashed, PointSize[Medium]}]The probability density function for Marchenko–Pastur distribution with 
is not defined, and PDF returns unevaluated:
PDF[𝒟, x]Differentiation of the CDF results in a function that does not integrate to one:
D[cdf, x]//SimplifyIntegrate[D[cdf, x], {x, -∞, ∞}]Computations with mixed type distributions are fully supported. Compute special moments:
{Mean[𝒟], Variance[𝒟], Skewness[𝒟], Kurtosis[𝒟]}Estimate parameters of Marchenko-Pastur distribution:
sample = RandomVariate[𝒟, 10 ^ 4];EstimatedDistribution[sample, MarchenkoPasturDistribution[λ]]Text
Wolfram Research (2015), MarchenkoPasturDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/MarchenkoPasturDistribution.html (updated 2016).
CMS
Wolfram Language. 2015. "MarchenkoPasturDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/MarchenkoPasturDistribution.html.
APA
Wolfram Language. (2015). MarchenkoPasturDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MarchenkoPasturDistribution.html